如何构建ANTLR Works样式解析树？

Question

我读过你需要使用'^'和'！'运算符，以便构建一个类似于ANTLR Works中显示的解析树（即使你不需要使用它们在ANTLR Works中获得一个漂亮的树）。那么我的问题是我如何建造这样一棵树？我已经在使用两个运算符和重写的树构造上看到了一些页面，但是我说我有一个输入字符串abc abc123和一个语法：

grammar test;

program : idList;
idList : id* ;
id : ID ;

ID : LETTER (LETTER | NUMBER)* ;
LETTER : 'a' .. 'z' | 'A' .. 'Z' ;
NUMBER : '0' .. '9' ;

ANTLR Works将输出：

我不明白你如何在这棵树的顶部获得'idList'节点（以及事实上的语法）。如何使用重写和那些运算符重现此树？

Answer 1

  

我不明白你如何在这棵树的顶部获得'idList'节点（以及事实上的语法）。如何使用重写和那些运算符重现此树？

您无法单独使用^和!。这些运算符仅在现有标记上运行，而您希望创建额外标记（并使这些标记成为子树的根）。您可以使用rewrite rules and defining some imaginary tokens执行此操作。

快速演示：

grammar test;

options {
  output=AST;
  ASTLabelType=CommonTree;
}

tokens {
  IdList;
  Id;
}

@parser::members {

  private static void walk(CommonTree tree, int indent) {
    if(tree == null) return;
    for(int i = 0; i < indent; i++, System.out.print("    "));
    System.out.println(tree.getText());
    for(int i = 0; i < tree.getChildCount(); i++) {
      walk((CommonTree)tree.getChild(i), indent + 1);
    }
  }

  public static void main(String[] args) throws Exception {
    testLexer lexer = new testLexer(new ANTLRStringStream("abc abc123"));
    testParser parser = new testParser(new CommonTokenStream(lexer));
    walk((CommonTree)parser.program().getTree(), 0);
  }
}

program : idList EOF -> idList;
idList  : id*        -> ^(IdList id*);
id      : ID         -> ^(Id ID);

ID    : LETTER (LETTER | DIGIT)*;
SPACE : ' ' {skip();};

fragment LETTER : 'a' .. 'z' | 'A' .. 'Z';
fragment DIGIT  : '0' .. '9';

如果您运行上面的演示，您将看到以下内容正在打印到控制台：

IdList
    Id
        abc
    Id
        abc123

正如您所看到的，虚构的标记也必须以大写字母开头，就像词法规则一样。如果你想给虚构的标记赋予与它们所代表的解析器规则相同的text，那么就这样做：

idList  : id*        -> ^(IdList["idList"] id*);
id      : ID         -> ^(Id["id"] ID);

将打印：

idList
    id
        abc
    id
        abc123