Question

我在VS 2010（.Net 4.0）中使用EF 4.3.1从数据库加载大量参考表，以便将它们绑定到WinForms应用程序中的控件。

在表单加载时，我预先获取数据以便它存储在本地，我正在创建一个BindingSource对象的字典，我可以使用它来将本地数据绑定到控件。目的是尽量减少EF自我验证对冷查询的影响，以便更快地加载表单并提高UI响应能力。

我编写了代码来为给定的DbSet集合创建和获取BindingSource对象，如下所示：

Private _dictBindings As New Dictionary(Of String, BindingSource)

Private Sub ValidateBinding(Of T As Class)(ByRef DbCollection As DbSet(Of T))
   Dim strClassName As String = DbCollection.[GetType]().GetGenericArguments(0).Name
   If Not _dictBindings.ContainsKey(strClassName) Then
      _dictBindings.Add(strClassName, New BindingSource With {.DataSource = DbCollection.Local.ToBindingList})
   End If
End Sub

Public Function GetBinding(Of T As Class)(ByRef DbCollection As DbSet(Of T)) As BindingSource
   ValidateBinding(Of T)(DbCollection)
   Return _dictBindings(DbCollection.[GetType]().GetGenericArguments(0).Name)
End Function

此代码有效，我可以调用

ValidateBinding(Db.ProvinceStates)

或

ComboBox1.DataSource = GetBinding(Db.Cities)

但是，我想在启动时在模型中的所有DbSet集合上调用ValidateBinding，并且我想使用反射来迭代上下文中的可用集合，因为我们当前正在加载66个表并且可以添加更晚些。

我写了以下代码：

For Each propSet As PropertyInfo In Db.GetType.GetProperties(BindingFlags.Instance Or BindingFlags.Public).Where(Function(P) P.PropertyType.IsGenericType)
    ValidateBinding(propSet.GetValue(Db, Nothing))
Next

...但它不会起作用，因为propSet.GetValue（）返回一个Object而不是DbSet（T）。我也无法将对象强制转换为适当类型的DbSet，即使我通过反射知道了类型。

我无法访问C＃Dynamic类型，我知道将泛型与反射混合是一种痛苦，但有没有一种解决方案可以将反射的DbSet传递给我的函数？也许使用Method.Invoke？

Answer 1

我想我已经解决了，解决方案是使用Method.Invoke。

首先，我将我的函数转换为扩展方法。虽然这不是必需的，但它允许我写：

db.ProvinceStates.ValidateBinding

和

ComboBox1.DataSource = db.Cities.GetBinding

其次，我使用GetMethod，MakeGenericMethod和Invoke来编写以下内容：

Dim methodLoad = GetType(DbExtensions).GetMethod("Load", BindingFlags.Static Or BindingFlags.Public)

For Each propSet As PropertyInfo In Db.GetType.GetProperties(BindingFlags.Instance Or BindingFlags.Public).Where(Function(P) P.PropertyType.IsGenericType)
   Dim oSet As Object = propSet.GetValue(Db, Nothing)
   methodLoad.Invoke(Nothing, {oSet})

   Dim methodValidateBinding = GetType(DbSetExtender).GetMethod("ValidateBinding", BindingFlags.Static Or BindingFlags.Public).MakeGenericMethod(propSet.PropertyType.GetGenericArguments(0))
   If methodValidateBinding IsNot Nothing Then
      methodValidateBinding.Invoke(Nothing, {oSet})
   End If
Next

这会一举两得，并为所有66个表加载数据，并创建绑定控件的BindingSource对象。（DbSetExtender是我自己的扩展方法模块，而DbExtensions是.Net框架的一部分。）

强烈反射.GetValue（）对象到通用DbSet

1 个答案: