Question

我需要获取两个日期之间的日期列表 - 例如我的开始日期是03302012，并且结束了05302012，我需要像

这样的输出

随意使用您的日期格式 - 我将自己进行转换。非常感谢你！

Answer 1

您可以使用递归模板执行此操作。这不是最好的解决方案，因为它会受到堆栈溢出或内存不足错误的影响（如果你给它的日期间隔足够大），但它可以是一个开始的地方。

下面的示例首先需要检查生成的值并确保它是一个有效的日期（您可以在线找到一些示例;我只是使用了a sample from an open source project并导入了该文件例子只是为了让它更短）。

然后，我们的想法是通过在前一个日期添加一天来生成日期，然后在当前日期添加一天，依此类推。如果这一天溢出，你可以在月份中添加一个，然后从第1天开始。如果月份溢出，你会对年份做同样的事情并从1月开始。理论上唯一一个永不溢出的是年份（但你会限制用间隔的结束值。）

您生成日期并验证它。如果它有效且尚未到达间隔的末尾，则尝试通过向其添加天数来生成另一个（这是在块X中发生的情况）。

当您获得无效值时，会出现溢出的内容。它只能是白天或月份（如上所述）。我首先检查一个月（块Y）。如果是这种情况，我会从第1个月的第1天开始，但是从明年开始。如果它是溢出的那一天（块Z），那么我从下个月的第1天开始。

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:import href="http://www.getsymphony.com/download/xslt-utilities/source-code/54294/"/>
  <xsl:output method="xml" omit-xml-declaration="yes" encoding="UTF-8" indent="yes" />

  <xsl:variable name="startDate" select="'03302012'" />  <!-- MMddyyyy format -->
  <xsl:variable name="endDate" select="'05302012'" /> <!-- MMddyyyy format -->

  <xsl:template match="/">
    <values>
      <xsl:call-template name="GenerateList">
        <xsl:with-param name="day" select="number(substring($startDate, 3, 2))" />
        <xsl:with-param name="month" select="number(substring($startDate, 1, 2))" />
        <xsl:with-param name="year" select="number(substring($startDate, 5))" />
      </xsl:call-template>
    </values>
  </xsl:template>

  <xsl:template name="GenerateList">
    <xsl:param name="day" select="1" />
    <xsl:param name="month" select="1" />
    <xsl:param name="year" select="1" />

    <!-- 1 = valid, 0 = invalid according to the imported file -->
    <xsl:variable name="validationResult">
      <xsl:call-template name="date-is-valid">
        <xsl:with-param name="day" select="$day"/>
        <xsl:with-param name="month" select="$month"/>
        <xsl:with-param name="year" select="$year"/>
      </xsl:call-template>
    </xsl:variable>

    <xsl:choose>
      <xsl:when test="$validationResult = 0">

        <xsl:choose>
          <xsl:when test="$month &gt; 12">
            <!-- block Y -->
            <xsl:call-template name="GenerateList">
              <xsl:with-param name="day" select="1" />
              <xsl:with-param name="month" select="1" />
              <xsl:with-param name="year" select="$year + 1" />
            </xsl:call-template>
          </xsl:when>
          <xsl:otherwise>
            <!-- block Z --> 
            <xsl:call-template name="GenerateList">
              <xsl:with-param name="day" select="1" />
              <xsl:with-param name="month" select="$month + 1" />
              <xsl:with-param name="year" select="$year" />
            </xsl:call-template>
          </xsl:otherwise>
        </xsl:choose>

      </xsl:when>
      <xsl:otherwise>
        <!-- block X -->
        <!-- same MMddyyyy format as the interval values -->
        <xsl:variable name="currentDate" select="concat(format-number($month, '00'), format-number($day, '00'), $year)" />
        <value>
          <xsl:value-of select="$currentDate" />
        </value>
        <xsl:if test="not($currentDate = $endDate)">
          <xsl:call-template name="GenerateList">
            <xsl:with-param name="day" select="$day + 1" />
            <xsl:with-param name="month" select="$month" />
            <xsl:with-param name="year" select="$year" />
          </xsl:call-template>
        </xsl:if>

      </xsl:otherwise>
    </xsl:choose>

  </xsl:template>
</xsl:stylesheet>

Answer 2

不幸的是，XSLT 1.0本身并不方便执行此类任务，但其环境通常如此。以下是我自己使用的一些方法：

最简单的解决方案通常是将此类列表作为输入的一部分=）
XSLT转换通常是具有特定XSLT处理器的更大应用程序的一部分，它允许使用特定方法进行扩展。您可以编写一个扩展函数（使用Java，Javascript，PHP，Python，具体取决于处理器），它返回所需的节点集。另一个但类似的选择是注册一个“流”（至少用PHP）并使用document函数获取节点集，其中包含app://Dates/listdates?start=a&end=b等网址。缺点是样式表与应用程序耦合，不能单独开发。
大多数XSTL处理器都支持EXSLT扩展。您可以使用日期扩展计算日期之间的天数，使用字符串扩展中的padding函数生成长度字符串，将字符串拆分为空字符串以获取标记列表（所需长度）和使用node-set函数迭代列表，并使用date-add将当前节点位置添加到第一个日期。
按照Bogdan的建议使用纯XSLT和递归模板。

XSLT 1.0：使用XSLT获取两个日期之间的日期列表

2 个答案: