perl日期计算，日期格式为2012-02-03 00:00:00

Question

我需要一些关于perl日期计算的帮助，日期格式为“2012-02-03 00:00:00”。特别是有一个工具，我可以用来增加天数，它正确切换到月份和年份？感谢。

Answer 1

请参阅DateTime。

#!/usr/bin/env perl
use strict; use warnings;

use DateTime;

my $ts = '2012-02-03 00:00:00';
my ($y, $m, $d) = ($ts =~ /([0-9]{4})-([0-9]{2})-([0-9]{2})/);
my $dt = DateTime->new(year => $y, month => $m, day => $d);
$dt->add( months => 2, days => 3 );

print $dt->strftime('%Y-%m-%d %H:%M:%S'), "\n";

---

使用DateTime :: Format类实际上有点干净，你可以免费获得错误检查。

use DateTime::Format::Strptime qw( );

my $format = DateTime::Format::Strptime->new(
   pattern   => '%Y-%m-%d %H:%M:%S',
   time_zone => 'local',
   on_error  => 'croak',
);

my $ts = '2012-02-03 00:00:00';
my $dt = $format->parse_datetime($ts);
$dt->add( months => 2, days => 3 );
print $format->format_datetime($dt), "\n";

Answer 2

Time::Piece模块是Perl安装的标准部分，可能完成您所需的一切。

此程序使用您的示例日期并添加两个月和三天，然后再增加400天。显示了两种显示值的替代方法

use strict;
use warnings;

use Time::Piece;
use Time::Seconds 'ONE_DAY';

my $format = '%Y-%m-%d %H:%M:%S';

my $dt = Time::Piece->strptime('2012-02-03 00:00:00', $format);
$dt = $dt->add_months(2);
$dt += 3 * ONE_DAY;

print $dt->strftime($format), "\n";

$dt += 400 * ONE_DAY;

printf "%s %s\n", $dt->ymd, $dt->hms;

<强>输出

2012-04-06 00:00:00
2013-05-11 00:00:00

Answer 3

使用POSIX时间处理函数在核心内完全可以实现。

标准POSIX::mktime函数已经处理了非规范化值，并且可以纠正超出范围的天/月。此外，POSIX::strftime在格式化之前实际上会在给定值上调用此值，因此它会正确调整。

use POSIX qw( strftime mktime );
use POSIX::strptime qw( strptime );

my $format = "%Y-%m-%d %H:%M:%S";

my @t = strptime( "2012-02-03 00:00:00", $format );
@t = @t[0..5]; # Throw away wday and yday

$t[3] += 3; # mday
$t[4] += 2; # mon

say strftime $format, @t;

$t[3] += 400; # mday

say strftime $format, @t;

给出

2012-04-06 00:00:00
2013-05-11 00:00:00