Question

我想通过分段函数的处理程序扩展Maple CodeGeneration [C]（不知道为什么它不包括在内）。为此我做了：

with(CodeGeneration):
with(LanguageDefinition):

LanguageDefinition:-Define("NewC", extend="C",
    AddFunction("piecewise", anything::numeric,
        proc()
            local i;
            Printer:-Print("if(",_passed[1],"){",_passed[2],"}");
            for i from 3 to _npassed-2 by 2 do
                Printer:-Print("else if(",_passed[i],"){",_passed[i+1],"}");
            end do;
            Printer:-Print("else{",_passed[_npassed],"}");
        end proc,
    numeric=double)
);

请注意，我正在使用if else语句来支持关于puropose的case语句。以下是要翻译的示例代码：

myp:=proc(x::numeric)
    piecewise(x>1,1*x,x>2,2*x,x>3,3*x,0);
end proc:
Translate(myp, language="NewC");

输出

void myp (double x)
{
    if(0.1e1 < x){x}else if(0.2e1 < x){0.2e1 * x}else if(0.3e1 < x){0.3e1 * x}else{0};
    ;
}

对于有效的C例程，我显然需要替换像

这样的大括号

{x}

类似

{result=x;}

与其他人类似。我可以通过修改上面的AddFunction语句中的字符串来手动执行此操作。但是代码生成器不知道变量名称结果，因此不会有任何声明，也不会根据需要返回结果值以匹配例程myp或任何更复杂的过程，其中可以分配分段结果一些其他变量或用于计算。那么我如何在CodeGeneration例程中正确处理这个问题呢？即如何获得有效的变量名称等。

Answer 1

这样的事情怎么样？

restart:

with(CodeGeneration):
with(LanguageDefinition):

LanguageDefinition:-Define("NewC", extend="C",
    AddFunction("piecewise", anything::numeric,
        proc()
            local i;
            Printer:-Print("( (",_passed[1],") ? ",_passed[2]);
            for i from 3 to _npassed-2 by 2 do
                Printer:-Print(" : (",_passed[i],") ? ",_passed[i+1]);
            end do;
            Printer:-Print(" : ",_passed[_npassed]," ) ");
        end proc,
    numeric=double)
);

myp:=proc(x::numeric) local result::numeric;
    result := piecewise(x>3,3*x,x>2,2*x,x>1,1*x,0);
end proc:

Translate(myp, language="NewC");

double myp (double x)
{
  double result;
  result = ( (0.3e1 < x) ? 0.3e1 * x : (0.2e1 < x) ? 0.2e1 * x : (0.1e1 < x) ? x : 0 ) ;
  return(result);
}

[编辑，添加以下材料]

事实证明，CodeGeneration [C]确实处理piecewise，但前提是optimize选项已提供。（我将提交一份错误报告，默认情况下应该处理它。）

restart:

with(CodeGeneration):
with(LanguageDefinition):
myp:=proc(x::numeric) local result::numeric;
     result:=piecewise(x>3,3*x,x>2,2*x,x>1,1*x,0);
end proc;

         myp := proc(x::numeric)
         local result::numeric;
           result := piecewise(3 < x, 3*x, 2 < x, 2*x, 1 < x, x, 0)
         end proc;

Translate(myp, language="C", optimize);

double myp (double x)
{
  double result;
  double s1;
  if (0.3e1 < x)
    s1 = 0.3e1 * x;
  else if (0.2e1 < x)
    s1 = 0.2e1 * x;
  else if (0.1e1 < x)
    s1 = x;
  else
    s1 = 0.0e0;
  result = s1;
  return(result);
}

正如您所看到的，piecewise通过转换为单独的if(){..}块来处理，并分配给引入的临时变量。随后在Maple过程中存在piecewise调用的任何地方使用该临时值。并宣布临时。不错，自动化。这样就足以使用piecewise。

您还问过如何在自己的扩展中引入和声明这些临时变量（如果我理解正确的话）。从上面继续在同一个Maple会话中，这里有一些想法。生成未分配的全局名称。 myp过程被置于惰性形式，新的局部变量被添加到该过程中。然后，改变的惰性形式又变回实际程序。作为示例，我使用原始扩展程序的修改版本来处理piecewise。这一切都产生了接近可接受的东西。唯一的障碍是赋值语句

result = temporary_variable;

不合适！它位于piecewise翻译块之前。我还没有看到如何在方法中修复它。

LanguageDefinition:-Define("NewC", extend="C",
    AddFunction("piecewise", anything::numeric,
        proc()
            global T;
            local i, t;
            t:=convert(T,string);
            Printer:-Print(t,";\n");
            Printer:-Print("  if (",_passed[1],
                           ")\n    { ",t," = ",_passed[2],"; }\n");
            for i from 3 to _npassed-2 by 2 do
                Printer:-Print("  else if (",_passed[i],")\n    { ",
                               t," = ",_passed[i+1],"; }\n");
            end do;
            Printer:-Print("  else { ",t," = ",_passed[_npassed],"; }");
        end proc,
    numeric=double)
):

T:=`tools/genglobal`('s'):

newmyp := FromInert(subsindets(ToInert(eval(myp)),'specfunc(anything,_Inert_LOCALSEQ)',
           z->_Inert_LOCALSEQ(op(z),
                              _Inert_DCOLON(_Inert_NAME(convert(T,string)),
                                            _Inert_NAME("numeric",
                                               _Inert_ATTRIBUTE(_Inert_NAME("protected",
                                               _Inert_ATTRIBUTE(_Inert_NAME("protected")
          ))))))));

             newmyp := proc(x::numeric)
             local result::numeric, s::numeric;
               result := piecewise(3 < x, 3*x, 2 < x, 2*x, 1 < x, x, 0)
             end proc;

Translate(newmyp, language="NewC");

double newmyp (double x)
{
  double result;
  double s;
  result = s;
  if (0.3e1 < x)
    { s = 0.3e1 * x; }
  else if (0.2e1 < x)
    { s = 0.2e1 * x; }
  else if (0.1e1 < x)
    { s = x; }
  else { s = 0; };
  return(result);
}

如果你重新运行上面的最后三个语句（从赋值到T，再到Translate调用），那么你应该看到一个新的临时变量，比如s0。然后s1如果再次重复。等等。

也许这会给你更多的想法。欢呼声。

扩展Maple代码生成中的变量名

1 个答案: