Question

假设我在java中有一个REST API，它支持JSON或XML的响应。响应包含相同的数据，但表单不相同。例如，在json中我可能有：

{
    "persons": [
        {
            "name":"Bob",
            "age":24,
            "hometown":"New York"
        }
    ]
}

而在XML中，它看起来像这样：

<persons>
    <person name="bob" age="24">
        <hometown>New York</hometown>
    </person>
</persons>

也就是说某些值是人的属性，而其他值是子元素。在Java中，使用JAXB和Jackson，很容易通过模型对象上的注释隐藏这些差异，例如：

public class Person {
    @XmlAttribute
    String name;

    @XmlAttribute
    Integer age;

    @XmlElement 
    String hometown; 
}

JAXB读取注释，Jackson使用字段名称来确定要做什么。因此，使用单一模型，可以轻松支持多种输出格式。

所以我的问题是，如何在clojure中做同样的事情。我知道有clj-json可以很容易地将clojure地图和矢量转换为json（如果我没弄错的话，使用jackson）。我知道clojure.xml.emit和clojure.contrib.xml.prxml都可以反序列化地图＆amp;向量到XML。但除非我弄错了，否则我认为这两者不会很好地协同工作。

因为prxml要求xml节点表示为向量，而xml属性要表示为映射，这与clj-json的工作根本不同，其中向量表示数组，而map表示对象。并且clojure.core.emit期望{:tag :person :attrs {:name "Bob" :age 24} :content ...}形式的地图与clj-json想要的地图完全不同。

我唯一能想到的是在我的代码中格式化prxml的数据结构，然后编写一个函数，当响应类型为JSON时，将数据结构转换为clj-json想要的内容。但这似乎有点蹩脚。如果有一对JSON和XML库与JAXB和Jackson的兼容方式，我更愿意这样做。

想法？

Answer 1

很大程度上取决于您选择如何在代码中表示模型。

我们假设您使用记录。这是一个人为的示例，说明如何“注释”记录并为XML和JSON提供序列化。

;; Depends on cheshire and data.xml
(ns user
  (:require [cheshire.core :as json]
            [clojure.data.xml :as xml]))

(defrecord Person [name age hometown])
(defrecord Animal [name sound])

(def xml-attrs {Person [:name :age]
                Animal [:name]})

(defn record->xml-data [rec]
  (let [tag (-> rec class .getSimpleName .toLowerCase keyword)
        attrs (select-keys rec (xml-attrs (class rec)))
        content (for [[k v] rec
                      :when (not (contains? attrs k))]
                  (xml/element k nil (str v)))]
    (apply xml/element tag attrs content)))

(defn record->xml [rec]
  (xml/emit-str (record->xml-data rec)))

(defn record->json [rec]
  (json/generate-string rec))

用法：

> (def bob (Person. "Bob" 24 "New York"))
#'user/bob

> (println (record->xml bob))
<?xml version="1.0" encoding="UTF-8"?><person age="24" name="Bob"><hometown>New York</hometown></person>
nil

> (println (record->json bob))
{"name":"Bob","age":24,"hometown":"New York"}
nil

> (println (record->xml (Animal. "Fido" "Bark!")))
<?xml version="1.0" encoding="UTF-8"?><animal name="Fido"><sound>Bark!</sound></animal>
nil

可以创建一个宏来在单个语句中定义记录及其XML属性。如，

(defrecord-xml Person [^:xml-attr name ^:xml-attr age hometown])

在clojure中支持xml和json REST响应

1 个答案: