Question

你好我有一个批处理文件，如下所示：

if %day%==monday, tuesday, wednesday, thursday, friday (
goto yes
) else (
goto no
)

现在我知道第一行不起作用。

我真正想要发生的事情：

它会自动检查它是哪一天。如果是周一到周五，则必须转到“是”，否则（周六/周日）转到“否”。

怎么做？

Answer 1

这是一个示例bat文件，可以执行此类操作，我相信您可以考虑使用此示例代码的其他方法。例如，任何时候你需要一个“in”列表。棘手的一点是％date：~0.3％这表示扩展％date％环境变量并从位置0开始，字符串的开头返回接下来的3个字符。你可以从“set /？”中了解更多相关信息。命令。

示例： IsWeekDay.bat

@echo off
setlocal

for %%i in (Mon,Tue,Wed,Thu,Fri) do (
    if "%date:~0,3%"=="%%i" goto YES
)

:NO
echo No
goto EOF

:YES
echo Yes

:EOF
endlocal

Answer 2

我在网上遇到了这个问题。测试，它的工作原理。以整数形式返回日期，您仍然可以使用它。

@For /F "tokens=2,3,4 delims=/ " %%A in ('Date /t') do @( 
    Set Month=%%A
    Set Day=%%B
    Set Year=%%C
)

@echo DAY = %Day%
@echo Month = %Month%
@echo Year = %Year%

Answer 3

正如Jay所提到的，使用date /t仅适用于此命令输出星期几和日期的语言环境，并且不适用于其他语言环境（例如俄语）。如果您不介意将批处理文件与某些VBScript混合使用，这里的解决方案应适用于所有语言环境。

诀窍是这个微小的VBScript脚本输出星期几作为数字（1 =星期日，2 =星期一，... 7 =星期六）：

WScript.Echo DatePart("w", Date)

您可以从批处理文件中运行此脚本，阅读其输出并应用逻辑：

for /f %%d in ('cscript dayofweek.vbs //nologo') do (
  if %%d==7 goto no   :: Saturday
  if %%d==1 goto no   :: Sunday
)
goto yes

Answer 4

IF %day% == monday GOTO YES
IF %day% == tuesday GOTO YES
IF %day% == wednesday GOTO YES
IF %day% == thursday GOTO YES
IF %day% == friday GOTO YES
GOTO NO

Answer 5

我没有批处理fu来回答问题，但是，假设这是一个Windows批处理文件，请考虑使用任务计划程序执行脚本，这将允许您设置您要求的计划类型对

Answer 6

这是一个批处理文件，以几乎与语言无关的方式提取星期几，日，月和年。

唯一的区域特定事项是星期几的拼写，其余的是区域中性。

所以在英语中，它将在星期四返回Thu，但在荷兰语中将返回do（对于donderdag）。

:: http://stackoverflow.com/questions/203090/how-to-get-current-datetime-on-windows-command-line-in-a-suitable-format-for-usi
:: Works on any NT/2k machine independent of regional date settings
::
:: 20110103 - adapted by jeroen@pluimers.com for Dutch locale
:: 20110303 - adapted by jeroen@pluimers.com for day-of-week
:: Dutch will get jj as year from echo:^|date, so the '%%c' trick does not work as it will fill 'jj', but we want 'yy'
:: luckily, all countries seem to have year at the end: http://en.wikipedia.org/wiki/Calendar_date
::            set '%%c'=%%k
::            set 'yy'=%%k
::
:: Also, in Dutch, there is a difference between %date% and date/t: the former will not include
:: the day-of-the-week, but the latter will.
:: That means the if "%date%A" LSS "A" trick does not work with %date%, we need a loop
:: to check if the day-of-the-week needs us to take tokens 2-4 in stead of 1-3:
::      if "%date%A" LSS "A" (set toks=1-3) else (set toks=2-4)
::      for /f "tokens=1" %%t in ('date/t') do (...)
::
:: Another difference between Dutch and English is that the Dutch date/t will prepend the day of the week in a lower case 2-letter form.
:: So the LSS "A" trick needs to be replaced with an LSS "a" trick
::      if "%date%A" LSS "A" (set toks=1-3) else (set toks=2-4)
::        if "%%ta" LSS "a" (set toks=1-3) else (set toks=2-4)
::
:: In addition, date will display the current date before the input prompt using dashes
:: in Dutch, but using slashes in English, so there will be two occurances of the outer loop in Dutch
:: and one occurence in English.
:: This skips the first iteration:
::        if "%%a" GEQ "A"
::
:: echo:^|date
:: Huidige datum: ma 03-01-2011
:: Voer de nieuwe datum in: (dd-mm-jj)
:: The current date is: Mon 01/03/2011
:: Enter the new date: (mm-dd-yy)
::
:: date/t
:: ma 03-01-2011
:: Mon 01/03/2011
::
:: The assumption in this batch-file is that echo:^|date will return the date format
:: using either mm and dd or dd and mm in the first two valid tokens on the second line, and the year as the last token.
::
:: The outer loop will get the right tokens, the inner loop assigns the variables depending on the tokens.
:: That will resolve the order of the tokens.
::
@ECHO off
    set v_day_of_week=
    set v_day=
    set v_month=
    set v_year=

    SETLOCAL ENABLEEXTENSIONS
      for /f "tokens=1" %%t in ('date/t') do (
        set v_day_of_week=%%t
        if "%%ta" LSS "a" (set toks=1-3) else (set toks=2-4)
      )
::DEBUG echo toks=%toks%
      for /f "tokens=2-4 delims=(-)" %%a in ('echo:^|date') do (
::DEBUG echo first token=%%a
        if "%%a" GEQ "A" (
          for /f "tokens=%toks% delims=.-/ " %%i in ('date/t') do (
            set '%%a'=%%i
            set '%%b'=%%j
            set 'yy'=%%k
          )
        )
      )
      if %'yy'% LSS 100 set 'yy'=20%'yy'%
      set Today=%'yy'%-%'mm'%-%'dd'%

    ENDLOCAL & SET day_of_week=%v_day_of_week% & SET v_year=%'yy'%& SET v_month=%'mm'%& SET v_day=%'dd'%

    ECHO Today is Year: [%V_Year%] Month: [%V_Month%] Day: [%V_Day%]
    set datestring=%V_Year%%V_Month%%V_Day%
    echo %datestring%
    echo day of week=%day_of_week%

    :EOF

玩得开心！

- jeroen

Answer 7

来自this answer，我们有

wmic path win32_localtime get dayofweek

根据this thread中的建议进行扩展，我们可以设置dayofweek变量，如下所示：

@echo off
REM Unset dayofweek in case set in a previous execution of this batch file
set dayofweek=
REM Get dayofweek into a variable.  Locale-specific:  0 is either Sunday or Monday.
for /F "skip=1 tokens=*" %%a in ('wmic path win32_localtime get dayofweek') do if not defined dayofweek set dayofweek=%%a
echo %dayofweek%

请注意，0可以是星期日或星期一，具体取决于您的语言区域。

只做日...批处理文件

7 个答案: