Question

我正在运行Fortran代码（使用英特尔Fortran编译），该代码具有OpenMp并行区域，在该区域中我希望能够访问存储在派生类型向量中的数据（具有不同类型的可分配字段）。

每个线程只能使用此向量中的一个位置，因此我希望向量具有“共享”属性。

运行代码时我遇到了一些奇怪的错误，因此我想知道是否可以这样使用派生类型向量？

Answer 1

当然，使用派生类型没有问题：

program derivedtype
   use omp_lib
   implicit none

   integer, parameter :: sz=20

   type mytype1
       integer, dimension(sz) :: a
       real   , dimension(sz) :: b
   end type mytype1

   type mytype2
       integer :: a
       real    :: b
   end type mytype2

   type(mytype1) :: var1
   type(mytype2), dimension(sz) :: var2
   integer:: i
   integer:: isum
   real   :: rsum

   var1%a = 2
   var1%b = 1.
   forall (i=1:sz)
       var2(i)%a = 3
       var2(i)%b = 4.
   endforall

   isum = 0
   rsum = 0.
   print *, var1%a
   print *, var1%b
   print *, [(var2(i)%a, i=1,sz)]
   print *, [(var2(i)%b, i=1,sz)]

!$omp parallel do default(none) shared(var1,var2), reduction(+:rsum), reduction(+:isum)
   do i=1,sz
      isum = isum + var1%a(i) + var2(i)%a
      rsum = rsum + var1%b(i) + var2(i)%b
   enddo

   print *,'isum = ', isum
   print *,'rsum = ', rsum
end program derivedtype

这个问题可能与可分配的部分有关，而且有点微妙; OpenMP3.0并没有真正处理具有可分配组件的派生类型，而且我不清楚3.1关于此事的说法。但即便如此，在OpenMP中你可以解决分配问题的方法 - C和指针也会出现同样的问题。你能给我们一个确切失败的例子吗？

是否可以在OpenMP并行区域内使用带有共享属性的派生类型变量？

1 个答案: