Question

我正在尝试调用通过RTTI获得的构造函数（运行D2010版本14.0.3593.25826）。构造函数将字符串和对象混合为参数，所有这些都应初始化为''或nil。（免责声明：我知道所需的构造函数将是具有最大参数数量的构造函数，因此看起来很奇怪，但设计不理想。）

代码如下：

program sb_rtti;
{$APPTYPE CONSOLE}
uses RTTI, TypInfo, SysUtils;

type

TMyClass = class (TObject)
  FField1:  string;
  FObject1: TObject;
public
  constructor Create(Field1: string = ''; Object1: TObject = nil);
end;

constructor TMyClass.Create(Field1: string; Object1: TObject);
begin
  FField1 := Field1;
  FObject1 := Object1;
end;

function GetConstructor(rType: TRttiType) : TRttiMethod;
var
  MaxParams:  integer;
  Methods:    TArray<TRttiMethod>;
  Method:     TRttiMethod;
  Params:     TArray<TRttiParameter>;
begin
  Methods := rType.GetMethods('Create');
  MaxParams := 0;
  for Method in Methods do begin
    Params := Method.GetParameters();
    if (Length(Params) > MaxParams) then begin
      Result := Method;
      MaxParams := Length(Params);
    end;
  end;
end;

procedure InitializeParam(Param: TRttiParameter; ActualParam: TValue);
begin
  if (Param.ParamType.TypeKind = TTypeKind.tkClass) then begin
    ActualParam := TValue.From<TObject>(nil);
  end else if (Param.ParamType.TypeKind = TTypeKind.tkString) then begin
    ActualParam := TValue.From<string>('');
  end else if (Param.ParamType.TypeKind = TTypeKind.tkUString) then begin
    ActualParam := TValue.From<UnicodeString>('');
  end else begin
    // Other types goes here
  end;
end;

var
  Context:      TRttiContext;
  Constr:       TRttiMethod;
  Params:       TArray<TRttiParameter>;
  ResultValue:  TValue;
  rType:        TRttiType;
  ActualParams: array of TValue;
  i:            integer;
  CurrentParam: TRttiParameter;
begin
  Context := TRttiContext.Create();
  rType := Context.GetType(TypeInfo(TMyClass));
  Constr := GetConstructor(rType);
  try
    if (Constr <> nil) then begin
      Params := Constr.GetParameters();
      SetLength(ActualParams, Length(Params));
      for i := 0 to Length(Params) - 1 do begin
        CurrentParam := Params[i] as TRttiParameter;
        InitializeParam(CurrentParam, ActualParams[i]);
      end;
      ResultValue := Constr.Invoke(rType.AsInstance.MetaclassType, ActualParams);
    end;
  except
    on E : Exception do
      WriteLn(E.ToString);
  end;
  ReadLn;
end.

现在，当执行行ResultValue := Constr.Invoke(rType.AsInstance.MetaclassType, ActualParams);时，会引发EInvalidCast异常。该异常可以追溯到第1336行的TValue.Cast - 方法。

然而，问题的关键似乎是在调用堆栈的前一点，更准确地说是在rtti.pas（argList[currArg] := Args[i].Cast(parList[i].ParamType.Handle);）的第4093行。

我的赌注是我以不应该的方式使用rtti，但是，我找不到任何地方描述的“正确方法”。任何人都可以指出我正确的方向吗？谢谢！

Answer 1

InitializeParam程序中存在问题，因为在ActualParam参数的赋值中，您要设置该参数的本地副本的值 - 请记住TValue（类型ActualParam）是一个记录。因此，要解决此问题，您必须将ActualParam作为var参数传递。

procedure InitializeParam(Param: TRttiParameter; var ActualParam: TValue);

Answer 2

我刚刚想到通过替换

对参数初始化进行硬编码

for i := 0 to Length(Params) - 1 do begin
  CurrentParam := Params[i] as TRttiParameter;
  InitializeParam(CurrentParam, ActualParams[i]);
end;

与

ActualParams[0] := TValue.From<string>('');
ActualParams[1] := TValue.From<TObject>(nil);

解决了这个问题。

Delphi：invoke构造函数引发EInvalidCast

2 个答案: