Question

我有一个VBscript，在我的工作站上工作得非常好。它查询SCCM以找出计算机所在的域。当我将其作为任务序列的一部分运行时，它会失败。请注意，这几乎是任务序列中的最后一步，在Windows 7下，而不是Windows PE。

Option Explicit

Const wbemFlagReturnImmediately = &H10
Const wbemFlagForwardOnly = &H20

Dim computerName, userName, userPassword, server
Dim swbemLocator, swbemServices, providerLoc
Dim location, connection
Dim query, found, resource, resources

'--- Settings ---
userName = "domain\username"
userPassword = "password"
server = "domain.com"  

'--- Get computer name ---
computerName = CreateObject("WScript.Network").ComputerName
WScript.Echo"Computer name: " & computerName

'--- Connect ----
Set swbemLocator = CreateObject("WbemScripting.SWbemLocator")
swbemLocator.Security_.AuthenticationLevel = 6
Set swbemServices = swbemLocator.ConnectServer(server, "root\sms",userName,userPassword)
Set providerLoc = swbemServices.InstancesOf("SMS_ProviderLocation")
For Each location In providerLoc
    If location.ProviderForLocalSite = True Then
        WScript.Echo "SiteCode: " & location.SiteCode       
        Set connection = swbemLocator.ConnectServer(server, "root\sms\site_" + location.SiteCode)
    Else
        WScript.Echo "Not provider for local site."
    End If
Next

'--- Query & output ---
query = "SELECT * FROM SMS_FullCollectionMembership WHERE name = '" & computerName & "'"
Set resources = connection.ExecQuery(query, , wbemFlagForwardOnly Or wbemFlagReturnImmediately)
found = False
For Each resource In resources
    WScript.Echo "Domain: " & resource.Domain & " (" & resource.CollectionID & ")"
    found = True
    Exit For
Next
If Not found Then WScript.Echo "Computer not found!"

如果我打开命令提示符（在Windows 7下使用F8而不是Windows PE）并运行脚本，我会得到：

SWbemLocator：访问被拒绝

就行：

Set connection = swbemLocator.ConnectServer(server, "root\sms\site_" + location.SiteCode)

有什么想法？或者，关于如何在上次构建计算机时找出计算机域的任何其他建议？

Answer 1

您的任务序列在本地系统帐户的上下文中运行，默认情况下，此帐户在SCCM中没有权限。

如果您在SCCM管理控制台，安全权限，用户中定义“yourdomain \ domain computers”，并授予他们对Collection的读取和读取资源权限，您应该能够连接到SCCM服务器。

请注意，您必须在要连接的所有站点服务器上执行此操作，这些定义不会在站点之间复制。

Answer 2

我意识到这是一个非常古老的帖子，但我自己就是这个问题。您已在脚本中拥有用户名和密码，并在此处使用

Set swbemServices = swbemLocator.ConnectServer(server, "root\sms",userName,userPassword)

然而，在没有用户名和密码的情况下，您正在连接到该网站。

Set connection = swbemLocator.ConnectServer(server, "root\sms\site_" + location.SiteCode)

试试这个：

Set connection = swbemLocator.ConnectServer(server, "root\sms\site_" + location.SiteCode, userName, userPassword)

希望这有助于某人！

从任务序列查询SCCM - 是否可能？

2 个答案: