如何通过在delphi 7中使用API​​来获取Netstat信息

Question

我的任务是查找信息abt n / w或Windows中的netstat命令给出的信息。现在，我被告知要使用一些API来提取这些信息。任何可用于此任务的delphi 7的API都会有所帮助。 我遇到过这个API，IP帮助程序API，但我在我的PC中找不到。我只能在C：\ Windows \ System32中找到DLL“iphlpapi.dll”。此外，关于如何使用此特定API的信息似乎非常少。请帮忙。

提前致谢

P.S。之前我通过执行Netstat命令，将输出写入文本文件，然后解析相同的显示来做同样的事情，对我来说，这是一个非常好的方法。然而，我的先生并不好。是什么原因，我无法理解。

Answer 1

检查这些窗口函数GetTcpTable，GetUdpTable，GetExtendedTcpTable，GetExtendedUdpTable。

更新

{$APPTYPE CONSOLE}

uses
  WinSock,
  Windows,
  SysUtils;

const
   ANY_SIZE = 1;
   iphlpapi = 'iphlpapi.dll';
   TCP_TABLE_OWNER_PID_ALL = 5;

   MIB_TCP_STATE:
   array[1..12] of string = ('CLOSED', 'LISTEN', 'SYN-SENT ','SYN-RECEIVED', 'ESTABLISHED', 'FIN-WAIT-1',
                             'FIN-WAIT-2', 'CLOSE-WAIT', 'CLOSING','LAST-ACK', 'TIME-WAIT', 'delete TCB');

type
  TCP_TABLE_CLASS = Integer;

  PMibTcpRowOwnerPid = ^TMibTcpRowOwnerPid;
  TMibTcpRowOwnerPid  = packed record
    dwState     : DWORD;
    dwLocalAddr : DWORD;
    dwLocalPort : DWORD;
    dwRemoteAddr: DWORD;
    dwRemotePort: DWORD;
    dwOwningPid : DWORD;
    end;

  PMIB_TCPTABLE_OWNER_PID  = ^MIB_TCPTABLE_OWNER_PID;
  MIB_TCPTABLE_OWNER_PID = packed record
   dwNumEntries: DWORD;
   table: Array [0..ANY_SIZE - 1] of TMibTcpRowOwnerPid;
  end;

var
   GetExtendedTcpTable:function  (pTcpTable: Pointer; dwSize: PDWORD; bOrder: BOOL; lAf: ULONG; TableClass: TCP_TABLE_CLASS; Reserved: ULONG): DWord; stdcall;

procedure ShowCurrentTCPConnections;
var
   Error      : DWORD;
   TableSize  : DWORD;
   i          : integer;
   IpAddress  : in_addr;
   RemoteIp   : string;
   LocalIp    : string;
   pTcpTable  : PMIB_TCPTABLE_OWNER_PID;
begin
  TableSize := 0;
  //Get the size o the tcp table
  Error := GetExtendedTcpTable(nil, @TableSize, False, AF_INET, TCP_TABLE_OWNER_PID_ALL, 0);
  if Error <> ERROR_INSUFFICIENT_BUFFER then exit;

  //alocate the buffer
  GetMem(pTcpTable, TableSize);
  try
   Writeln(Format('%-16s %-6s %-16s %-6s %s',['Local IP','Port','Remote IP','Port','Status']));
   //get the tcp table data
   if GetExtendedTcpTable(pTcpTable, @TableSize, TRUE, AF_INET, TCP_TABLE_OWNER_PID_ALL, 0) = NO_ERROR then
      for i := 0 to pTcpTable.dwNumEntries - 1 do
      begin
         IpAddress.s_addr := pTcpTable.Table[i].dwRemoteAddr;
         RemoteIp         := string(inet_ntoa(IpAddress));
         IpAddress.s_addr := pTcpTable.Table[i].dwLocalAddr;
         LocalIp          := string(inet_ntoa(IpAddress));
         Writeln(Format('%-16s %-6d %-16s %-6d %s',[LocalIp,pTcpTable.Table[i].dwLocalPort,RemoteIp,pTcpTable.Table[i].dwRemotePort,MIB_TCP_STATE[pTcpTable.Table[i].dwState]]));
      end;
  finally
     FreeMem(pTcpTable);
  end;
end;

var
   hModule : THandle;
begin
  try
    hModule             := LoadLibrary(iphlpapi);
    GetExtendedTcpTable := GetProcAddress(hModule, 'GetExtendedTcpTable');
    ShowCurrentTCPConnections;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
  Readln;
end.