Question

如何比较两个数组的值以检查1个数组是否没有另一个数组的元素 - 例如

array1(0) = 85
array1(1) = 459
array1(2) = 90

array2(0) = 459
array2(1) = 90

我想返回第二个数组中不存在的值？我尝试使用双循环，但对我来说效果不佳。

Answer 1

此功能：

Function diffArray( aA, aB )
  ' !! http://en.wikipedia.org/wiki/Union_%28set_theory%29
  ' The union of two sets A and B is the collection of points which are in A or
  ' in B (or in both)
  Dim dicU : Set dicU = CreateObject( "Scripting.Dictionary" )
  ' !! http://en.wikipedia.org/wiki/Intersection_%28set_theory%29
  ' the intersection of two sets A and B is the set that contains all elements
  ' of A that also belong to B (or equivalently, all elements of B that also
  ' belong to A)
  Dim dicI : Set dicI = CreateObject( "Scripting.Dictionary" )
  ' !! http://en.wikipedia.org/wiki/Complement_%28set_theory%29
  ' If A and B are sets, then the relative complement of A in B, also known as
  ' the set-theoretic difference of B and A, is the set of elements in B, but
  ' not in A. The relative complement of A in B is denoted B \ A
  Dim dicAB : Set dicAB = CreateObject( "Scripting.Dictionary" )
  Dim dicBA : Set dicBA = CreateObject( "Scripting.Dictionary" )
  Dim vItem
  For Each vItem In aA
      dicU(  vItem ) = 0 ' all from A go into UNI (all from B added later)
      dicAB( vItem ) = 0 ' all from A go into A\B (all from B removed later)
  Next
  For Each vItem In aB
      dicU( vItem ) = 0 ' all from B are added to UNI
      If dicAB.Exists( vItem ) Then ' B item found in (current) A\B
         dicI( vItem ) = 0 ' goes into INT
         dicAB.Remove vItem ' and must be removed from A\B
      Else ' B item not fount in (current) A\B
         If Not dicI.Exists( vItem ) Then dicBA( vItem ) = 0 ' goes to B/A if not already in INT
'        dicBA( vItem ) = 0 ' bug: would add item previously removed from A\B to INT
      End If
  Next
  diffArray = Array( dicU.Keys, dicI.Keys, dicAB.Keys, dicBA.Keys )
End Function

避免D-Money提案的N * N循环。（顺便说一句：在VBScript中的事实通过给出它的UBound（最后一个索引）可能会令人惊讶，你指定一个数组的大小其他语言的用户，但如果数组不这样做，则无法证明代码失败有虚假的尾巴。）

用于演示该功能的代码：

  Dim aA   : aA   = Split( "85 459 90 85" )
  Dim aB   : aB   = Split( "4711 459 90 4711" )
  Dim aRes : aRes = diffArray( aA, aB )
  WScript.Echo "A  :", Join( aA )
  WScript.Echo "B  :", Join( aB )
  WScript.Echo "UNI:", Join( aRes( 0 ) ), "in A or B"
  WScript.Echo "INT:", Join( aRes( 1 ) ), "in A and B"
  WScript.Echo "A\B:", Join( aRes( 2 ) ), "in A but not in B"
  WScript.Echo "B\A:", Join( aRes( 3 ) ), "in B but not in A"

输出：

A  : 85 459 90 85
B  : 4711 459 90 4711
UNI: 85 459 90 4711 in A or B
INT: 459 90 in A and B
A\B: 85 in A but not in B
B\A: 4711 in B but not in A

有关其他示例用法，请参阅this question。

Answer 2

Dim array1(3)
Dim array2(2)

array1(0) = 85
array1(1) = 459
array1(2) = 90

array2(0) = 459
array2(1) = 90

Dim i 'As Integer
Dim j 'As Integer
Dim isFound 'As Boolean

For i = 0 To UBound(array1) - 1
    isFound = False
    For j = 0 To UBound(array2) - 1
        If array1(i) = array2(j) Then
            isFound = True
        End If
    Next 'j
    If Not isFound Then
        Response.Write array1(i) & " not found<br />"
    End If
Next 'i

Answer 3

这是一个提供多种比较方法的例子 - 也有一个很好的演示。

http://www.aspkey.net/aspkey/_articles/asp/showarticle.asp?id=110

比较两个数组的值 - 经典的asp

3 个答案: