Question

当我获取tcl文件的源代码时，运行未知命令将报告错误。

Tcl> source run.tcl
$inside tcl file$$> setup_desgin
    Design setup...
    Done
$inside tcl file$$> my_prove
    Info: proving started
    Info: ....
    Info: ....
$inside tcl file$$> ::unknown my_pro
    invalid command name "my_pro"

有没有办法如下显示tcl文件中错误行的行号？

Tcl> source run.tcl
$inside tcl file$$> setup_desgin
    Design setup...
    Done
$inside tcl file$$> my_prove
    Info: proving started
    Info: ....
    Info: ....
$inside tcl file$$> ::unknown my_pro
    invalid command name "my_pro" (run.tcl:5)

我们之所以这样，是因为我们可能会有一个很大的run.tcl，其中包含许多行。

Answer 1

通常很难获得此信息。仅当代码在执行堆栈上时，当前才提供准确的行号信息。幸运的是，您可以找出离开步长跟踪的情况（拦截unknown仅适用于未知命令；通过跟踪可以捕获所有所有错误）。在下面的代码中，我将其放置在eval上，但是在更实际的示例中，您将其放置在source或类似的东西上。

set errorlineSet 0
proc LEAVESTEP {cmd code result op args} {
    global errorline errorlineSet
    if {$code == 1} {
        if {!$errorlineSet} {
            set errorline [dict get [info frame -4] line]
        }
        set errorlineSet 1
    } else {
        set errorlineSet 0
    }
}

try {
    trace add execution eval leavestep LEAVESTEP
    eval {
        sdfgsldfjg;   # This is line 17
    }
} on error {msg opt} {
    puts "ERROR: $msg (line: $errorline) (local line: [dict get $opt -errorline])"
} finally {
    trace remove execution eval leavestep LEAVESTEP
}

当我将所有内容保存到文件并运行时，它会打印以下内容：

ERROR: invalid command name "sdfgsldfjg" (line: 17) (local line: 3)

如您所见，结果选项字典中还有一个-errorline键，但是在这种情况下，它映射到3上，这很容易引起误解！由于向后兼容，它使用了该值，但是我不相信它是否有帮助。

Answer 2

您可以重新定义unknown命令并在其中使用info frame命令来获取位置。像这样：

# Save the default unknown if you want
rename ::unknown ::original_unknown

proc ::unknown {name args} {
    set caller [info frame -1]
    dict with caller {
        switch $type {
            source {
                puts stderr "invalid command name \"$name\" (in file $file:$line)"
            }
            proc {
                if {[info exists lambda]} {
                    puts stderr "invalid command name \"$name\" (in lambda $lambda:$line)"
                } else {
                    puts stderr "invalid command name \"$name\" (in proc $proc:$line)"
                }
            }
            eval {
                puts stderr "invalid command name \"$name\" (in eval {$cmd}:$line)"
            }
            precompiled {
                puts stderr "Invalid command name \"$name\""
            }
        }
    }
}

用法示例：

% source my_unknown.tcl
% source bad.tcl
invalid command name "put" (in file /home/shawn/src/bad.tcl:3)

Tcl：有没有办法显示tcl中的哪一行引发错误？

2 个答案: