Question

预先感谢所有建议。

我第一次使用SAS来完成（理论上）简单的任务。我在Windows目录中有一个父文件夹，其中包含几个子文件夹。子文件夹没有系统地命名。例如，如果父文件夹名为“ W：/ Documents / ParentFolder /”，则子文件夹可能为“ W：/ Documents / ParentFolder / ABC1D26 /”和“ W：/ Documents / ParentFolder / HG34A /”。

每个子文件夹包含几个SAS数据集。在任何特定的子文件夹中，某些SAS数据集的扩展名为.sas7bdat，而其他数据集的扩展名为.sd2。此外，没有两个子文件夹必须具有相同数量的数据集，并且数据集也没有系统地命名。

我想用SAS编写一个程序，该程序在每个子文件夹内查找，加载找到的任何.sas7bdat或.sd2数据集，并将该数据集作为.dta文件导出到另一个文件夹中。

每个子文件夹中的SAS数据集太多，无法为每个数据集手动执行此任务，但是子文件夹不多，我无法将子文件夹名称手动输入到SAS。下面是我尝试完成该任务的程序的评论版本。不幸的是，毫无疑问，由于我对SAS的经验不足，我遇到了很多错误。

例如，SAS给出以下错误：“ ERROR：无效的逻辑名称；” “错误：FILENAME语句中的错误；”和“错误：无效的DO回路控制信息”；

有人可以提供任何建议吗？

%macro sas_file_converter();

/* List the sub-folders containing SAS files in the parent folder */
%let folder1 = W:\Documents\ParentFolder\ABC1D26;
%let folder2 = W:\Documents\ParentFolder\HG34A;

/* Start loop over the sub-folders. In each sub-folder, identify all the files, extract the file names, import the files, and export the files. */
%do folder_iter = 1 %to 2;

    /* Define the sub-folder that is the focus of this iteration of the loop */
    filename workingFolder "&&folder&folder_iter..";
    
    /* Extract a list of datasets in this sub-folder */
    data datasetlist;
        length Line 8 dataset_name $300;
        List = dopen('workingFolder');
        do Line = 1 to dnum(List);
            dataset_name = tranwrd(tranwrd(lowcase(trim(dread(List,Line))),".sas7bdat",""),".sd2","");
            output;
        end;
        drop List Line;
    run;

    /* Get number of datasets in this sub-folder */
    proc sql nprint;
        select count(*)
        into :datasetCount
        from WORK.datasetlist;
    quit;

    /* Loop over datasets in the sub-folder. In each iteration of the loop, load the dataset and export the dataset. */
    %do dataset_iter = 1 %to &datasetCount.;

        /* Get the name of the dataset which is the focus of this iteration */
        data _NULL_;
            set WORK.DATASETLIST (firstobs=&dataset_iter. obs=&dataset_iter.);
            call symput("inMember",strip(dataset_name));
        end;

        /* Set the libname */
        LIBNAME library '&folder&folder_iter..';

        /* Load the dataset */
        data new;
            set library.&inMember.;
        run;

        /* Export the dataset */
        proc export data=library.&inMember.
            file = "W:\Documents\OutputFolder\&inMember..dta"
            dbms = stata replace;
        run;
    %end;
%end;
%mend;

Answer 1

非常感谢您的有用建议。我使用以下程序执行此任务。它很大程度上是基于理查德的例子。我将其发布在这里是为了将来的读者。 Richard的示例包括其他代码，可以帮助您了解该程序的功能。

可以通过将其他文件/文件夹添加到“％let folder”行中来容纳它们。（我在这里写了许多文件/文件夹名称。）

请注意，我用三个破折号（“ ---”）分隔了子文件夹，因为某些文件和子子文件夹的名称中有空格。还请注意，对于.sd2文件，我能够简单地将“ sas7bdat”的实例替换为“ sd2”，并且程序运行正常。

再次感谢。

%let inputfolder = W:\Documents\ParentFolder;
%let folders = ABC1D26---HG34A---Sub Folder\ZH323;
%let exportfolder = W:\Documents\ExportFolder;

data _null_;
    do findex = 1 to countw("&folders.","---");
        folder = scan("&folders", findex, "---");

        path = catx("/", "&dataroot.", folder);
        call execute ('libname user ' || quote(trim(path)) || ';');

        length fileref $8;
        call missing(fileref);
        rc = filename(fileref, path);

        did = dopen(fileref);
        do dindex = 1 to dnum(did);
            filename = lowcase(dread(did,dindex));
            if scan(filename,-1) ne 'sas7bdat' then continue;

            xptfilename = tranwrd(filename, '.sas7bdat', '.dta')
            xptfilepath = catx("\", "&exportpath", folder, xptfilename);
            
            datasetname = tranwrd(filename, '.sas7bdat', '');
       
            sascode = 'PROC EXPORT data=' || trim(datasetname) || " replace file=" || quote(trim(xptfilepath)) || " dbms=stata; run;";

            call execute (trim(sascode));
        end;
        did = dclose(did);
      
        call execute ('libname user clear;');

        rc = filename(fileref);
    end;
run;

Answer 2

您可以在DATA步骤中执行所有代码生成，并通过CALL EXECUTE提交。程序中唯一与宏相关的部分是指定sas数据根文件夹，要搜索的子文件夹的名称以及导出路径。

该程序可能是非常类似的宏编码，但可能难以调试，并且需要在函数调用周围使用%sysfunc包装器。

示例：

/* Create some sample data in some example folders */

%let workpath = %sysfunc(pathname(WORK));

%let name = %sysfunc(dcreate(ABC, &workpath));
%let name = %sysfunc(dcreate(DEF, &workpath));

libname user "&workpath./ABC";
data one two three four five;
  set sashelp.class;
run;

libname user "&workpath./DEF";
data six seven eight nine ten;
  set sashelp.class;
run;

libname user clear;

/* export all data sets in folders to liked named export files */

%let dataroot = &workpath;
%let folders = ABC DEF;
%let exportpath = c:\temp;

data _null_;
  do findex = 1 to countw("&folders");
    folder = scan("&folders", findex);

    path = catx("/", "&dataroot.", folder);
    call execute ('libname user ' || quote(trim(path)) || ';');

    length fileref $8;
    call missing(fileref);
    rc = filename(fileref, path);

    did = dopen(fileref);
    do dindex = 1 to dnum(did);
      filename = dread(did,dindex);
      if scan(filename,-1) ne 'sas7bdat' then continue;

      xptfilename = tranwrd(filename, '.sas7bdat', '.dta');
      xptfilepath = catx('/', "&exportpath", xptfilename);

      datasetname = tranwrd(filename, '.sas7bdat', '');

      sascode = 'PROC EXPORT data=' || trim(datasetname)
      || " replace file=" || quote(trim(xptfilepath))
      || " dbms=stata;"
      ;

      call execute (trim(sascode));      
    end;
    did = dclose(did);

    call execute ('run; libname user clear;');

    rc = filename(fileref);
  end;
run;

SAS：遍历文件夹以导入和导出多个文件

2 个答案: