Question

在按合同设计时，必须在两种情况下满足类不变量：创建对象后和调用例程后。是否有任何示例或条件，我必须在调用例程之前进行评估？

Answer 1

在功能调用之前，可以违反类不变量。条件可能不同，我只提出最明显的条件：

混叠。一个对象引用一个其他对象，该对象涉及一个类不变量，另一个对象被第三方修改：

class SWITCH -- Creation procedure is ommitted for brevity.
feature
    toggle1, toggle2: TOGGLE -- Mutually exclusive toggles.
    ...
invariant
    toggle1.is_on = not toggle2.is_on
end

现在，以下代码违反了类SWITCH的不变量：

switch.toggle1.turn_on -- Make `switch.toggle1.is_on = True`
switch.toggle2.turn_on -- Make `switch.toggle2.is_on = True`
switch.operate -- Class invariant is violated before this call

外部状态。对象与外部数据耦合，外部数据在类不变量中引用，可能会意外更改：

class TABLE_CELL feature
    item: DATA
        do
            Result := cache -- Attempt to use cached value.
            if not attached Result then
                    -- Load data from the database (slow).
                Result := database.load_item (...)
                cache := Result
            end
        end
feature {NONE} -- Storage
    cache: detachable DATA
invariant
    consistent_cache: -- Cache contains up-to-date value.
        attached cache as value implies
        value ~ database.load_item (...)
end

现在，如果在应用程序之外修改了数据库，缓存可能会变得不一致，并且在以下功能调用之前会触发类不变违规：

data := table_cell.item -- Class invariant is violated before this call.

回调。对象可以以无效状态传递给另一个对象：

class HANDLER feature
    process (s: STRUCTURE)
        do
            ... -- Some code that sets `is_valid` to False.
            s.iterate_over_elements (Current)
        end
    process_element (e: ELEMENT)
        do
            ...
        end
    is_valid: BOOLEAN
        do
            ...
        end
invariant
    is_valid
end

由HADNLER类功能iterate_over_elements执行的STRUCTURE回调导致不变违规，因为handler状况不佳：

handler.process_element (...) -- Class invariant is violated before the call.

有人可能会争辩说，所有案例都是由于软件漏洞和漏洞造成的，但这正是类不变量的目的，即在函数调用之前发生违规时的情况。

在调用例程之前和之后评估不变量的位置？

1 个答案: