Question

我正在尝试编写一个对表达式求值的宏，然后将其与一些值进行比较。我将这个问题简化为一个较小的示例。

macro small_bad(item)
    quote
        $(use_val(esc(item)))
    end
end

function use_val(val)
    quote
        if $val == 1
            1
        elseif $val == 2
            2
        else
            -1
        end
    end
end

因为我不想多次评估expr，所以我想将其保存在变量中。所以我尝试了这个：

macro small_good(item)
    quote
        begin
            val = $(esc(item))
            $(begin
                  use_val(val)
              end)
        end
    end
end

但是我得到val的插值中未定义@small_good。

我也尝试传递use_val(:val)，但这也失败了，因为宏系统将重命名 val。

我该如何实现？

编辑：给出第一个答案后，我在实际代码中尝试了这个

macro match(item, arms)
    var = gensym(:var)
    quote
        let $var = $(esc(item))
            $(begin
                code = :nothing
                for e in reverse(filter((e) -> e isa Expr, arms.args))
                    code = make_match(var, e, code)
                end
                code
            end)
        end
    end
end

得到UndefVarError: ##var#253 not defined

gist with the full code here

免责声明：我知道@match宏已经在Match.jl包中实现，我正在将其子集重新实现为学习练习

编辑2：

我知道了。在使用了FrançoisFévotte的建议之后，我现在必须更改我实际使用的use_val的实际版本，而不是$(esc(val))。

我误会了我，因为没有包括这些细节。将更新要点以反映这一点

Answer 1

如果我了解您的需求，那应该可以：

macro small(item)
    var = gensym(:var)
    quote
        let $var = $(esc(item))
            $(use_val(var))
        end
    end
end

function use_val(val)
    quote
        if $val == 1
            1
        elseif $val == 2
            2
        else
            -1
        end
    end
end

它扩展为：

julia> using MacroTools
julia> MacroTools.@expand @small myexpr
quote
    let octopus = myexpr
        begin
            if octopus == 1
                1
            elseif octopus == 2
                2
            else
                -1
            end
        end
    end
end

并且既没有卫生问题也没有多重评估的问题：

# Testing in a local scope introduced by `let`
# is a good way to check for hygiene issues
julia> let arg = [1]
           @small pop!(arg)
       end
1

现在，我猜想您的原始问题的很多实质在MWE创建过程中已经丢失了，因为这基本上等同于：

julia> function small(val)
           if val == 1
               1
           elseif val == 2
               2
           else
               -1
           end
       end
small (generic function with 1 method)

julia> let args = [1]
           small(pop!(args))
       end
1

将宏变量传递给函数进行插值

1 个答案: