Question

输入是一个称为b的字典

puts $b
h1 {tP 20} h2 {tP 30} h3 {tP 40} h4 {tP 50}

目标-按tP值对该字典进行排序。

我到目前为止拥有的功能是

proc sortValue {dict args} {
    set l {}
    dict for {k v} $dict {
        lappend l [list $k $v]
    }
    return [concat {*}[lsort -real -decreasing -index 1 {*}$args $l]]
}

我该如何修改才能进入dict另一个级别？

预期输出

h4 {tP 50} h3 {tP 40} h2 {tP 30} h1 {tP 20}

Answer 1

将字典作为具有偶数个元素的列表（是）处理

lsort -integer -decreasing -stride 2 -index {end end} $b

h4 {tP 50} h3 {tP 40} h2 {tP 30} h1 {tP 20}

第一个“ end”用于访问跨度的最后一个元素，第二个“ end”用于访问该索引的最后一个元素。

您可以在8.5版中完成

set temp [list]
set sorted [dict create]

dict for {key value} $b {
    lappend temp [list $key $value]
}
foreach pair [lsort -integer -decreasing -index {end end} $temp] {
    dict set sorted {*}$pair
}

刚刚看到了您编辑的评论：是的，它当然会改变。这是施瓦兹变换的一部分：

% set b {h1 {tP 20 lp 1} h2 {tP 30 lp 2} h3 {tP 40 lp 3} h4 {tP 50 lp 4} }
h1 {tP 20 lp 1} h2 {tP 30 lp 2} h3 {tP 40 lp 3} h4 {tP 50 lp 4}
% set temp [list]
% dict for {key subdict} $b {lappend temp [list [dict get $subdict tP] $key $subdict]}
% set sorted [dict create]
% foreach tuple [lsort -int -decr -index 0 $temp] {dict set sorted {*}[lrange $tuple 1 end]}
% set sorted
h4 {tP 50 lp 4} h3 {tP 40 lp 3} h2 {tP 30 lp 2} h1 {tP 20 lp 1}

TCL如何按值对嵌套字典进行排序

1 个答案: