Question

我下载了总是具有不同行数的数据集。我将两列存储为变量，即导入和月份。然后，我需要运行一个Sumif公式，以月为单位对进口值进行求和。我正在编写一个Sumif公式，该公式使用两个变量并将单元格引用到其左侧。

但是，单元的位置根据数据集大小的变化而变化。因此，我编写了代码以选择列上的最后一个活动单元格，然后选择3行向下的单元格。

使用变量和单元格编写公式时，会给我一个错误。请您为任何错别字的时间而感到抱歉。

我选择范围D中的所有活动单元，并将它们存储为月，对导入也是如此。然后使用范围，我在M列上找到了最后一个活动单元格，并使用向下选择3行的单元格，我希望在其中写出公式。

请查看我的代码，看看我在做什么错，我是新手编码员。

Sub Importaciones()
'
' Importaciones Macro
'




    Dim LastRow As Long

        LastRow = Range("L" & Rows.Count).End(xlUp).Row 

    Dim Months As Long

        Months = Range("D2", Range("D2").End(xlDown)).Select

    Dim Imports As Long

        Imports = Range("M2", Range("M2").End(xlDown)).Select

     Dim LastRowM As Long

      LastRowM = Range("M" & Rows.Count).End(xlUp).Row

      Range("M" & LastRowM + 3).Formula = "=sumif(" & Months & ", " & 
      Range("L" & LastRow + 3) & ", " & Imports & ")"

End Sub

要使公式生效，我要选择的月份总数就会出现

Answer 1

根据所有评论：

Sub Importaciones()

    With Worksheets("Sheet1") 'Change to your sheet
        Dim LastRow As Long
            LastRow = .Range("L" & .Rows.Count).End(xlUp).Row

        Dim Months As Range
            Set Months = .Range("D2", .Range("D2").End(xlDown))

        Dim Imports As Range
            Set Imports = .Range("M2", .Range("M2").End(xlDown))

         Dim LastRowM As Long
            LastRowM = .Range("M" & .Rows.Count).End(xlUp).Row

            .Range("M" & LastRowM + 3).Formula = "=sumif(" & Months.Address(0, 0) & ", " & .Range("L" & LastRow + 3).Address(0, 0) & ", " & Imports.Address(0, 0) & ")"
    End With
End Sub

如何使用sumif函数在VBA代码中使用变量

1 个答案: