Question

我们有一个项目，其中包含两个Xtext语法，其内容如下：https://www.eclipse.org/forums/index.php/t/1079008/

我们的语言生成模块具有一个XtextGenerator块和两个语言块。一种语言块通过'referencedResource'属性引用另一种语言块。

将语法放在一个项目中是有意义的，因为它们紧密相关，而一个语法又依赖于另一个。

但是，当运行Langauge生成模块时，所依赖的语言似乎是在依赖语言之后生成的，从而导致所依赖语言的.genmodel出现FileNotFoundException。

为什么依赖语言是在依赖语言之后生成的？是否可以指定语言生成的顺序？

我已经尝试过：

将GenerateBxLang模块分为两个模块，每个模块针对一种语言生成。但是，清除是在运行模块之前执行的。这导致运行第二个模块会删除运行第一个模块的结果。
更改模块中语言块的顺序，但这没什么区别。

语言生成模块代码如下：

module com.a.b.GenerateLang

import org.eclipse.xtext.xtext.generator.*
import org.eclipse.emf.mwe.utils.StandaloneSetup
import org.eclipse.xtext.xtext.generator.model.project.*

var rootPath = ".."

Workflow {

    component = XtextGenerator {
        configuration = {
            project = StandardProjectConfig {
                baseName = "com.a.b"
                rootPath = rootPath
                runtimeTest = {
                    enabled = true
                }
                genericIde = {
                    enabled = true
                }
                mavenLayout = true
            }
            code = {
                encoding = "UTF-8"
                lineDelimiter = "\n"
                fileHeader = "/*\n * generated by Xtext \${version}\n */"
            }
        }
        language = StandardLanguage {
            name = "com.a.b.BxLang"
            fileExtensions = "bxlang"
            referencedResource =
            "platform:/resource/com.a.b/model/generated/BxLangSubjectScope.genmodel" 
            serializer = {
                generateStub = false
            }
            validator = {
                generateDeprecationValidation = true
            }
            junitSupport = {
                junitVersion = "5"
            }
        }
        language = StandardLanguage {
            name = "com.a.b.BxLangSubjectScope"
            fileExtensions = "bxscope"
            serializer = {
                generateStub = false
            }
            validator = {
                generateDeprecationValidation = true
            }
            junitSupport = {
                junitVersion = "5"
            }
        }
    }
}

运行上述语言生成模块会导致以下错误：

359  [main] ERROR mf.mwe2.launch.runtime.Mwe2Launcher  - Problems running workflow com.a.b.GenerateBxLang: java.io.FileNotFoundException: /model/generated/BxLangSubjectScope.genmodel (No such file or directory)
java.lang.RuntimeException: Problems running workflow com.a.b.GenerateBxLang: java.io.FileNotFoundException: /model/generated/BxLangSubjectScope.genmodel (No such file or directory)

Answer 1

解决方案就像克里斯蒂安·迪特里希（Christian Dietrich）对原始问题的评论：

referencedResource应该是语法文件，而不是genmodel。正确的参考如下所示：

referencedResource =
          "platform:/resource/com.a.b/src/main/java/com/a/b/BxLangSubjectScope.xtext"

如何为XtextGenerator指定Xtext语言生成的顺序？

1 个答案: