Question

我是cmake的新手，尝试创建一个需要一些第三方库的小项目。我希望libs作为git repos始终保持最新。一些库只是.cpp和.hpp文件（glad，imgui），而其他则是cmake项目（glfw，glm）。

这个想法是要有一个包含所有库的第三方项目作为子项目，以及一个使用库和包含等的沙箱项目。而且我想使用现代的cmake代码，该代码不会在框架结构之外安装任何东西。

文件夹结构：

Framework
|--3rd_party
|  |--glad
|  |  |--include
|  |  |--src
|  |--glfw-master
|  |  |--...
|  |  |--CMakeLists.txt
|  |--glm-master
|  |  |--..
|  |  |--CMakeLists.txt
|  |--imgui-master
|  |  |--*.cpp
|  |  |--*.hpp
|  |  |--examples
|  |  |  |--*.cpp
|  |  |  |--*.hpp
|  |--CMakeLists.txt
|--sandbox
|  |--main.cpp
|  |--CMakeLists.txt
|--CMakeLists.txt

所以我创建了此文件夹结构以及一些CMakeList：

CMakeLists.txt（框架）

cmake_minimum_required(VERSION 3.10)

project(Framework)

add_subdirectory("3rd_party")
add_subdirectory("sandbox")

CMakeLists.txt（第三方）

#GLFW
set(GLFW_BUILD_DOCS OFF CACHE BOOL "" FORCE)
set(GLFW_BUILD_TESTS OFF CACHE BOOL "" FORCE)
set(GLFW_BUILD_EXAMPLES OFF CACHE BOOL "" FORCE)
add_subdirectory(glfw-master)

# GLM
set(GLM_TEST_ENABLE OFF CACHE BOOL "" FORCE)
add_subdirectory(glm-master)

# Glad
add_library(
    Glad STATIC
    "glad/src/glad.c"
)

target_include_directories(Glad PUBLIC "glad/include")

# ImGui
add_compile_definitions(IMGUI_IMPL_OPENGL_LOADER_GLAD=1)

set(IMGUI_SOURCES
    "imgui-master/imgui.cpp"
    "imgui-master/imgui_demo.cpp"
    "imgui-master/imgui_draw.cpp"
    "imgui-master/imgui_widgets.cpp"
    "imgui-master/examples/imgui_impl_glfw.cpp"
    "imgui-master/examples/imgui_impl_opengl3.cpp"
)

set(IMGUI_HEADERS
    "imgui-master/imconfig.h"
    "imgui-master/imgui.h"
    "imgui-master/imgui_internal.h"
    "imgui-master/imstb_rectpack.h"
    "imgui-master/imstb_textedit.h"
    "imgui-master/imstb_truetype.h"
    "imgui-master/examples/imgui_impl_glfw.h"
    "imgui-master/examples/imgui_impl_opengl3.h"
)

add_library(
    ImGui STATIC
    ${IMGUI_SOURCES}
    ${IMGUI_HEADERS}
)

target_include_directories(ImGui PUBLIC "imgui-master" "glfw-master/include" "glad/include")

CMakeLists.txt（沙盒）

project(Sandbox)

find_package(OpenGL REQUIRED)

add_executable(sandbox main.cpp)

# OpenGL
target_include_directories(Sandbox PUBLIC ${OPENGL_INCLUDE_DIR})
target_include_directories(Sandbox PUBLIC external)

# Glfw
target_include_directories(Sandbox PUBLIC "../3rd_party/glfw-master/include")

# Link libs
target_link_libraries(Sandbox PUBLIC
           ${OPENGL_LIBRARIES}
           "../3rd_party/glfw-master/src/Debug/glfw3"
           Glad
           ImGui
           glm_static
)

该代码有效，但未达到我的预期。起初，我知道这有点难看，也许有更好的方法来处理包含和来源的路径，但更大的问题是项目结构。例如，当我为ms vs studio构建它时，我有三种解决方案

./framework.sln
./sandbox/sandbox.sln
./3rd_party/glfw-master/glfw.sln

很高兴，glm和imgui是sandbox.sln的一部分

我想要的是一个具有两个子解决方案沙箱和3rd_party的解决方案，该解决方案还具有所有库的子解决方案或项目。

那么有可能吗？如果是的话，如何用cmake创建这样的结构？

Answer 1

经过进一步的调查以及对CMake的多次尝试和错误，我想我开始时有错误的期望和一些误解。

不可能从CMake文件中获得有用的Visual Studio解决方案/项目结构，因为所有CMake项目都将产生VS解决方案，而所有add_library或add_executable都将成为VS项目。如果我想为我的框架创建一个CMake项目并添加GLFW作为第三方，这也创建了一个CMake项目，它将以两个不同的VS解决方案结束，并且 bang 结构消失了。我认为这就是Microsoft在Visual Studio中为CMake文件引入特殊的开放上下文的原因。

如果使用此上下文打开了一个项目，则“解决方案”查看器将显示该项目的文件夹结构。那或多或少是我一开始所期望的。

还有一个选项可以切换视图以查看所有CMake目标（exec，lib，...）。

我也“升级”了我的CMakeLists。我使用不同的方法来添加第三方库：

具有CMakeLists（例如GLFW）的库的
add_subdirectory
add_library和INTERFACE用于仅头文件的库，例如glm
add_library静态文件，例如ImGui（在我的情况下）

Sandbox的包含内容由库的公共接口提供，而构建/依赖关系的顺序由target_link_libraries中的顺序给出。

我希望那是帮助，将为您节省很多时间;）

干杯！ boss0r

CMakeLists.txt（框架）

cmake_minimum_required(VERSION 3.10)

project(OpenGL_Framework
    VERSION 0.0.1
    LANGUAGES CXX C    # C for GLFW
)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_CXX_EXTENSIONS OFF)

add_subdirectory(ThirdParty)
add_subdirectory(Sandbox)

CMakeLists.txt（第三方）

# GLFW
set(GLFW_LIB_NAME "GLFW")
set(GLFW_INC_PATH ${GLFW_LIB_NAME}/include)

set(GLFW_BUILD_DOCS     OFF CACHE BOOL "" FORCE)
set(GLFW_BUILD_TESTS    OFF CACHE BOOL "" FORCE)
set(GLFW_BUILD_EXAMPLES OFF CACHE BOOL "" FORCE)
#set(GLFW_VULKAN_STATIC  OFF CACHE BOOL "" FORCE)    # OFF by default
#set(BUILD_SHARED_LIBS   OFF CACHE BOOL "" FORCE)    # OFF by default
set(GLFW_INSTALL        OFF CACHE BOOL "" FORCE)

add_subdirectory(${GLFW_LIB_NAME})

# spdlog
set(SPDLOG_LIB_NAME "spdlog")

set(SPDLOG_MASTER_PROJECT OFF CACHE BOOL "" FORCE)

add_subdirectory(${SPDLOG_LIB_NAME})

# OR
#set(SPDLOG_LIB_NAME "spdlog")
#set(SPDLOG_SRC_PATH ${SPDLOG_LIB_NAME}/src)
#set(SPDLOG_INC_PATH ${SPDLOG_LIB_NAME}/include)

#add_library(${SPDLOG_LIB_NAME}
#    STATIC
#        ${SPDLOG_SRC_PATH}/spdlog.cpp
#)

#target_include_directories(${SPDLOG_LIB_NAME}
#    PUBLIC
#        ${SPDLOG_INC_PATH})

# glm
set(GLM_LIB_NAME "glm")
set(GLM_INC_PATH ${GLM_LIB_NAME}/glm)

add_library(${GLM_LIB_NAME} INTERFACE)

target_include_directories(${GLM_LIB_NAME}
    INTERFACE
        ${GLM_INC_PATH}
)

# OR
#set(GLM_LIB_NAME "glm")
#set(GLM_INC_PATH ${GLM_LIB_NAME}/glm)

#set(GLM_TEST_ENABLE OFF CACHE BOOL "" FORCE)

#add_subdirectory(${GLM_LIB_NAME})

#target_include_directories(${GLM_LIB_NAME}
#    PUBLIC
#        $(GLM_INC_PATH)
#)

# Glad
set(GLAD_LIB_NAME "Glad")
set(GLAD_SRC_PATH "${GLAD_LIB_NAME}/src")
set(GLAD_INC_PATH "${GLAD_LIB_NAME}/include")

add_library( ${GLAD_LIB_NAME}
    STATIC
        "${GLAD_SRC_PATH}/glad.c"
)

target_include_directories(${GLAD_LIB_NAME}
    PUBLIC
        "${GLAD_INC_PATH}"
)

# ImGui
set(IMGUI_LIB_NAME "ImGui")

set(IMGUI_SOURCES
    "${IMGUI_LIB_NAME}/imgui.cpp"
    "${IMGUI_LIB_NAME}/imgui_demo.cpp"
    "${IMGUI_LIB_NAME}/imgui_draw.cpp"
    "${IMGUI_LIB_NAME}/imgui_widgets.cpp"
    "${IMGUI_LIB_NAME}/examples/imgui_impl_glfw.cpp"
    "${IMGUI_LIB_NAME}/examples/imgui_impl_opengl3.cpp"
)

set(IMGUI_HEADERS
    "${IMGUI_LIB_NAME}/imconfig.h"
    "${IMGUI_LIB_NAME}/imgui.h"
    "${IMGUI_LIB_NAME}/imgui_internal.h"
    "${IMGUI_LIB_NAME}/imstb_rectpack.h"
    "${IMGUI_LIB_NAME}/imstb_textedit.h"
    "${IMGUI_LIB_NAME}/imstb_truetype.h"
    "${IMGUI_LIB_NAME}/examples/imgui_impl_glfw.h"
    "${IMGUI_LIB_NAME}/examples/imgui_impl_opengl3.h"
)

set(IMGUI_INC_PATH "${IMGUI_LIB_NAME}/")

add_library(${IMGUI_LIB_NAME}
    STATIC
        ${IMGUI_SOURCES}
        ${IMGUI_HEADERS}
)

target_compile_definitions(${IMGUI_LIB_NAME}
    PRIVATE
        IMGUI_IMPL_OPENGL_LOADER_GLAD=1
)

target_include_directories(${IMGUI_LIB_NAME}
    PUBLIC
        "${IMGUI_INC_PATH}"
        "${GLFW_INC_PATH}"
        "${GLAD_INC_PATH}"
)

CMakeLists.txt（沙盒）

project(Sandbox)

find_package(OpenGL REQUIRED)

add_executable(${PROJECT_NAME} Sandbox.cpp)

target_include_directories(${PROJECT_NAME}
    PUBLIC
        external
        ${OPENGL_INCLUDE_DIR}
)

target_link_libraries(${PROJECT_NAME}
    PUBLIC
        ${OPENGL_gl_LIBRARY}
        glfw
        Glad
        ImGui
        glm
        #glm_static    # if build with add_subdirectory
        spdlog::spdlog
)

如何使用不同的第三方库构建cmake项目

1 个答案: