Question

完整查询：

{[tier;company;ccy; startdate; enddate] select Deal_Time, Deal_Date from DEALONLINE_REMOVED where ?[company = `All; 1b; COMPANY = company], ?[tier = `All;; TIER = tier], Deal_Date within(startdate;enddate), Status = `Completed, ?[ccy = `All;1b;CCY_Pair = ccy]}

特殊查询：

where ?[company = `All; 1b; COMPANY = company], ?[tier = `All; 1b; TIER = tier],

此查询要执行的操作是获取下拉菜单的viewstate。

如果下拉选择为“全部”，则其中的子句即company或tier无效，并显示所有公司或层级。

我不确定上面的查询是否正确，因为在KDB仪表板上显示它们时我得到了奇怪的图表。

Answer 1

我建议您使用functional qSQL通过使用where子句来重组函数。

在您的情况下，您需要能够基于某些输入进行过滤，如果其“全部”，则不要过滤该输入上的其他过滤器。这样的事情可能会起作用。

/Define sample table
DEALONLINE_REMOVED:([]Deal_time:10#.z.p;Deal_Date:10?.z.d;Company:10?`MSFT`AAPL`GOOGL;TIER:10?`1`2`3)

/New function which joins to where clause 
{[company;tier]
  wc:();
  if[not company=`All;wc:wc,enlist (=;`Company;enlist company)];
  if[not tier=`All;wc:wc,enlist (=;`TIER;enlist tier)];
  ?[DEALONLINE_REMOVED;wc;0b;()]
}[`MSFT;`2]

如果您将输入替换为`All，您将看到返回的所有内容。

Answer 2

用于查询的全部功能如下：

whcl:{[tier;company;ccy;startdate;enddate]
 wc:(enlist (within;`Deal_Date;(enlist;startdate;enddate))),(enlist (=;`Status;enlist `Completed)),
 $[tier=`All;();enlist (=;`TIER;enlist tier)],
 $[company=`All;()enlist (=;`COMPANY;enlist company)],
 $[ccy=`All;();enlist (=;`CCY_Pair;enlist ccy)];
 ?[`DEALONLINE_REMOVED;wc;0b;`Deal_Time`Deal_Date!`Deal_Time`Deal_Date]
}

第一部分在where子句中指定日期范围和status = `Completed

wc:(enlist (within;`Deal_Date;(enlist;startdate;enddate))),(enlist (=;`Status;enlist `Completed)),

接下来，每个这些条件检查都会为TIER，COMPANY和CCY_Pair列过滤检查所有内容。然后，当指定了特定的TIER，COMPANY或CCY_Pair时，它们会将它们连接到where子句。（否则将加入一个空列表）：

 $[tier=`All;();enlist (=;`TIER;enlist tier)],
 $[company=`All;();enlist (=;`COMPANY;enlist company)],
 $[ccy=`All;();enlist (=;`CCY_Pair;enlist ccy)];

最后，以如下功能形式调用select语句，其中wc作为where子句：

?[`DEALONLINE_REMOVED;wc;0b;`Deal_Time`Deal_Date!`Deal_Time`Deal_Date]

KDB中的条件WHERE子句？

2 个答案: