Question

我正在尝试编写一个程序，如果乌龟在其前面检测到乌龟，则会死亡。很简单，但是由于某种原因，每当发生这种情况时，我所有的海龟都会死亡，而且我不知道该如何纠正。

这是我的代码：

to setup
  ca
  ask patches
  [ set pcolor white
  ]
end

to spawn
  crt 1
  [ set color random 140
    setxy random-xcor random-ycor
  ]
end

to wiggle
  lt 100
  rt 100
  ifelse not any? turtles-on patch-ahead 1
  [ fd 1
    set pcolor color
  ]
  [ die
  ]
end

to go
  ask turtles
  [ wiggle
  ]
end

似乎ifelse not any? turtles-on patch-ahead 1一开始总是被评估为假，而我不明白为什么。

Answer 1

我认为以下示例可能会为您带来一些启示：

to setup
  clear-all
  create-turtles 1 [
    set xcor -0.5
    set ycor -0.5
    set heading 45
    show (word "patch-here:    " patch-here)
    show (word "patch-ahead 1: " patch-ahead 1)
    show (word "patch-ahead 1: " patch-ahead 1)
    show (word 
      "not any? turtles-on patch-ahead 1:       "
      not any? turtles-on patch-ahead 1
    )
    show (word 
      "not any? other turtles-on patch-ahead 1: "
      not any? other turtles-on patch-ahead 1
    )
  ]
end

它正在创建一只乌龟，将其放置在中央斑块的左下角，并使其面向东北，然后再检查几件事。如果运行代码，您将得到：

observer> setup
(turtle 0): "patch-here:    (patch 0 0)"
(turtle 0): "patch-ahead 1: (patch 0 0)"
(turtle 0): "patch-ahead 1: (patch 0 0)"
(turtle 0): "not any? turtles-on patch-ahead 1:       false"
(turtle 0): "not any? other turtles-on patch-ahead 1: true"

关键是补丁的对角线长于一个对角线（记住毕达哥拉斯定理）。这意味着patch-ahead 1仍可以是乌龟所在的补丁！在这种情况下，not any? turtles-on patch-ahead 1将为假。由于您的海龟在世界各地随机移动，所以这最终必将发生。

幸运的是，有一个简单的解决方案。只需使用other：

not any? other turtles-on patch-ahead 1

当我只问一只乌龟时，为什么所有的乌龟都死了？

1 个答案: