Question

我正在尝试以低功耗模式并符合欧洲法规从一个ESP32 LoRa节点传输到另一个节点。

ESP32板：TTGO LoRa32 OLED板V1.0（here和here）。

在我写的LoRa发件人草图下方：

/*
 * LoRa (low-power) sender for IoT projects
 *  
 * Tested on a TTGO LoRa32 OLED Board V1.0 
 * 
 * Based on the LoRa examples and the board 
 * documentation
 * 
 * More on the deep sleep with timer wake up: 
 *  
 *    Examples > ESP32 > Deep Sleep > TimerWakeUp sketch
 *    
 *    
 * ERC Recommendation
 * h1.4 frequency band requires <= 1% duty cycle and 25mW (14 db) maximum power
 * => 36 seconds every hour (so: 1 sec transmitting, 99 secs idle) 
 * 
 * 
 * Created 11 June 2019
 * by DP 
 *    
 */

#include <SPI.h>   // allows communication with SPI devices 
#include <LoRa.h>
#include <SSD1306.h>   // provides API to work with OLED displays

// defines the pins used by the transceiver module
#define SS 18   // GPIO18 - SX1278's CS   - LoRa radio chip select
#define RST 14   // GPIO14 - SX1278's RESET   - LoRa radio reset
#define DI0 26   // GPIO26 - SX1278's IRQ   - IRQ pin

#define BAND 868E6   // EU   - Italy

// deep sleep 
#define uS_TO_S_FACTOR 1000000  // conversion factor for micro seconds to seconds 
#define TIME_TO_SLEEP  5        // time ESP32 will go to sleep (in seconds)   - 99 for (about) 1% duty cycle  


// an object of class SSD1306 
// first parameter: the I2C address of the display
// second parameter: the number of the SDA
// third parameter: the SCL pin
SSD1306 display(0x3c, 4, 15);

// stores the data on the RTC memory so that it will not be deleted during the deep sleep
RTC_DATA_ATTR int bootCount = 0; 
RTC_DATA_ATTR int pckCounter = 0;   // sending packet number...


void setup() {   
  Serial.begin(115200);   // initializes serial data transmission  
  while(!Serial);   // waits for serial port to connect 

  Serial.println("LoRa low-power Sender");

  pinMode(16, OUTPUT);
  digitalWrite(16, LOW);   // sets GPIO16 low to reset the OLED
  delay(50);
  digitalWrite(16, HIGH);   // while the OLED is running, GPIO16 must go to high  
  pinMode(2, OUTPUT);
  digitalWrite(2, LOW);   // sets the onboard LED low 

  // LoRa transceiver module setup 
  LoRa.setPins(SS, RST, DI0);   // overrides the default CS, reset, and IRQ pins used by the library

  // initializes the transceiver module with a specified frequency
  while (!LoRa.begin(BAND)) {   // LoRa.begin returns 1 on success, 0 on failure
    Serial.println(".");
  }

  // changes the spreading factor to 12 -> slower speed but better noise immunity
  LoRa.setSpreadingFactor(12);   // ranges from 6-12, default is 7 

  // changes the sync word (0xF3) to match the receiver
  // the sync word assures you don't get LoRa messages from other LoRa transceivers  
  LoRa.setSyncWord(0xF3);   // ranges from 0-0xFF     

  // LoRa.setTxPower(txPower);   // defaults to 17

  // initializes the display by calling the init method of the display object 
  display.init();   // receives no arguments and returns void

  // display.flipScreenVertically();   // LCD is broken!
  display.setFont(ArialMT_Plain_16);   // sets the current font
  display.drawString(0, 0, "Initialization");   // x, y, message to show
  display.drawString(0, 16, "completed");
  display.display();
  delay(1500);   // small delay so that the user can read it  

  Serial.println("LoRa init completed");    

  //Increments boot number and prints it every reboot
  bootCount++;
  Serial.println("Boot number: " + String(bootCount));

  sendData();   // sends the data...

  // deep sleep
  esp_sleep_enable_timer_wakeup(TIME_TO_SLEEP * uS_TO_S_FACTOR);
  Serial.println("Setup ESP32 to sleep for every " + String(TIME_TO_SLEEP) + " Seconds");
  Serial.println("Going to sleep now");
  Serial.flush();   // waits for the transmission of outgoing serial data to complete 
  esp_deep_sleep_start();   // enters deep sleep with the configured wakeup options
}

void loop(){
  // this is not going to be called
}

// sends the data to the receiver
void sendData() {

  Serial.print("Sending packet: ");
  Serial.println(pckCounter);

  display.clear();   // clears the display
  display.setTextAlignment(TEXT_ALIGN_LEFT);
  display.drawString(0, 0, "Sending ");
  display.drawString(0, 16, "packet: " + String(pckCounter, DEC));
  display.display();

  digitalWrite(2, HIGH);   // LED is ON during transmission

  // sends the LoRa packet to the receiver
  LoRa.beginPacket();
  LoRa.print("hello ");
  LoRa.print(pckCounter);
  LoRa.endPacket();

  digitalWrite(2, LOW);   // turns the LED off after transmission

  pckCounter++;
}

该草图运行时没有错误（商店页面上的代码包含一些错误，因此我建议您仅使用此代码进行操作）。我的问题：

我忘了初始化SPI通信：

SPI.begin (SCK, MISO, MOSI, SS);

但无论如何，它仍然有效。没想到我的第一个问题是：我想念什么？

我住在欧洲。 ERC建议文件称，h1.4频段（我以868 Mhz的频率进行传输）需要小于= 1％的占空比和25mW（14db）的最大功率。这意味着我每小时可以传输36秒（假设我传输1秒钟，然后ESP32“睡眠” 99秒钟）。我可以完成写作（这不是更准确的方法，但是应该可以）：

#define TIME_TO_SLEEP 99

erp呢？假设天线增益为2db，所以我可以将发射功率设置为12db（12db + 2db-> 14db，太好了。没关系！）：

LoRa.setTxPower(12);

我的第二个问题：我是否正确（关于这两种设置）？我想念什么吗？

最后一个问题：请随时给我任何（如果您有）反馈/建议以改进此草图！

谢谢大家的帮助。

Answer 1

这看起来不错，您是否在深度睡眠期间测试了功耗？我使用的是同一块板（带OLED的TTGO ESP32 LORA），清醒时获得约38-50mA的电流，睡眠时获得10mA的电流。发送完毕后，您可以尝试LoRa.end()和LoRa.sleep()来使芯片进入睡眠状态，但是我不确定这可以节省多少电量。

有一些讨论going on here，涉及进一步降低功率的方法，但是对于TTGO，我无法将其降低到10mA以下。

Answer 2

总的来说，我对 LilyGo 产品和低电流的体验很差。我测试了其中的几个（不是 LoRa 的），通常它们至少消耗 1mA。我认为真正节能的传感器可以由 Atmel LoRa 节点制成，例如 this。

Answer 3

非常好，看起来与我的草图非常相似。我认为电池连接器正在使用低压降稳压器，但这仍将消耗毫安。正如我目前正在评估的替代测试方案：您是否曾经尝试使用GNV / 3V3连接器直接为电路板供电？使用标准的3.7V LiPo电池和一些合适的肖特基二极管来产生大约0.2V的电压降，即使在充满电池的情况下也可以保持在3.6V以下，这可以很好地工作。

具有深度睡眠模式的低功耗ESP32 + LoRa（TTGO LoRa32 OLED板V1.0）

3 个答案: