Question

要在给定的基数中将数字拆分为数字，Julia具有digits()函数：

julia> digits(36, base = 4)
3-element Array{Int64,1}:
 0
 1
 2

什么是反向操作？如果您有一个由数字和基数组成的数组，是否有内置方式将其转换为数字？我可以将数组打印为字符串并使用parse()，但这听起来效率低下，并且对于大于10的碱基也不起作用。

Answer 1

先前的答案是正确的，但也存在效率问题：

sum([x[k]*base^(k-1) for k=1:length(x)])

在求和之前将数字收集到数组中，这将导致不必要的分配。跳过括号以获得更好的性能：

sum(x[k]*base^(k-1) for k in 1:length(x))

这还会在求和之前分配一个数组：sum(d.*4 .^(0:(length(d)-1)))

但是，如果您确实想要良好的性能，请编写一个循环并避免重复取幂：

function undigit(d; base=10)
    s = zero(eltype(d))
    mult = one(eltype(d))
    for val in d
        s += val * mult
        mult *= base
    end
    return s
end

这有一个额外的不必要的乘法，您可以尝试找出跳过它的某种方法。但是性能比我的测试中的其他方法好10-15倍，并且分配为零。</ p>

编辑：上面的类型处理实际上存在一些风险。如果输入向量和base具有不同的整数类型，则可能会导致类型不稳定。这段代码应该表现得更好：

function undigits(d; base=10)
    (s, b) = promote(zero(eltype(d)), base)
    mult = one(s)
    for val in d
        s += val * mult
        mult *= b
    end
    return s
end

Answer 2

答案似乎直接写在digits的文档中：


help?> digits
search: digits digits! ndigits isdigit isxdigit disable_sigint

  digits([T<:Integer], n::Integer; base::T = 10, pad::Integer = 1)

  Return an array with element type T (default Int) of the digits of n in the given base,
  optionally padded with zeros to a specified size. More significant digits are at higher
  indices, such that n == sum([digits[k]*base^(k-1) for k=1:length(digits)]).

对于您的情况，这将起作用：

julia> d = digits(36, base = 4);

julia> sum([d[k]*4^(k-1) for k=1:length(d)])
36

上面的代码可以使用点运算符来缩短：

julia> sum(d.*4 .^(0:(length(d)-1)))
36

Answer 3

使用 foldr 和 muladd 以获得最大的简洁性和效率

undigits(d; base = 10) = foldr((a, b) -> muladd(base, b, a), d, init=0)

Answer 4

让：

In[1]: x = digits(36, base = 4)
In[2]: base = 4

然后：

In[3]: sum([x[k]*base^(k-1) for k=1:length(x)])
Out[4]: 36

从数字数组中获取数字

4 个答案: