Question

我正在QBasic中编写一个程序，要求人们无限次输入姓名和年龄，直到按 xxx ，然后打印该程序所有输入的姓名和年龄：

我一直得到 0 ，而不是姓名和年龄，无论我怎么努力，我都完全陷入困境，下面是我的代码：

DIM i AS INTEGER
CLS
i = 1
WHILE nam$ <> "xxx"
   Input "Enter name: ", nam$
   Input "Enter age: ", age$
   Sum$ = nam$ + age$ (i)
   i = i + 1
WEND
FOR x = 1 to i
    PRINT Sum(i)
NEXT x

Answer 1

代码很简单：

REM how to enter data and add to array
DIM i AS INTEGER
CLS
DIM Sum(16384) AS STRING
PRINT "enter xxx to quit."
DO
    INPUT "Enter name: ", nam$
    INPUT "Enter age: ", age$
    IF nam$ = "xxx" THEN EXIT DO
    i = i + 1
    Sum(i) = nam$ + " " + age$
LOOP
FOR x = 1 TO i
    PRINT Sum(x)
NEXT x

Answer 2

仅在while时使用相同的代码

REM how to enter data and add to array using only while
DIM i AS INTEGER
CLS
DIM Sum(16384) AS STRING
PRINT "enter xxx to quit."
WHILE z = 0
    INPUT "Enter name: ", nam$
    INPUT "Enter age: ", age$
    IF nam$ = "xxx" THEN
        z = -1
    ELSE
        i = i + 1
        Sum(i) = nam$ + " " + age$
    END IF
WEND
FOR x = 1 TO i
    PRINT Sum(x)
NEXT x

Answer 3

两个数组的示例代码：

REM how to enter data and add to two arrays using only while
DIM Sum1(8192) AS STRING, Sum2(8192) AS INTEGER ' adjusted for qb45
CLS
PRINT "Press Enter to quit."
WHILE z = 0
    INPUT "Enter name?", nam$
    IF nam$ = "" THEN
        z = -1
    ELSE
        INPUT "Enter age?", age%
        i = i + 1
        Sum1(i) = nam$
        Sum2(i) = age%
    END IF
WEND
FOR x = 1 TO i
    PRINT "Name: "; Sum1(x); " Age:"; Sum2(x)
NEXT x

如何使用While和For循环解决此问题？

3 个答案: