Question

由于axis2没有任何Gradle插件（一个wsdl代码生成器），因此我在自定义Gradle任务中调用了Ant任务。

到目前为止，./gradlew build会生成代码，而./gradlew clean将其删除。另外，仅当检测到输入文件或输出目录中的更改时，才会生成代码。

我唯一的问题是，将项目导入IDE时不会自动生成代码。

如何更改下面的build.gradle.kts才能使IDE（当前为IntelliJ，但我也希望支持Eclipse）在导入时生成代码？

plugins {
    id("base") // needed for delete
}

val axis2 by configurations.creating

dependencies {
    axis2("org.apache.axis2:axis2-ant-plugin:$axis2Version")
    axis2("org.apache.axis2:axis2-xmlbeans:$axis2Version")
}


val wsdl2Java by tasks.registering {
    group = "build"
    description = "Creates Java classes and resources from WSDL schema."

    inputs.files(fileTree("$projectDir/src/main/resources/wsdl"))
    outputs.dir("$projectDir/generated/")

    doLast {
        ant.withGroovyBuilder {
            "echo"("message" to "Generating Classes from WSDL!")
            "taskdef"("name" to "codegen", "classname" to "org.apache.axis2.tool.ant.AntCodegenTask", "classpath" to axis2.asPath)
            "codegen"(
                    "wsdlfilename" to "$projectDir/src/main/resources/wsdl/MP12N-H-HOST-WEB-SOAP.wsdl",
                    "output" to "$projectDir/generated/",
                    "targetSourceFolderLocation" to "src/main/java",
                    "targetResourcesFolderLocation" to "src/main/resources",
                    "packageName" to "de.hanel.com.jws.main",
                    "databindingName" to "xmlbeans")
        }
    }
}


val deleteGenerated by tasks.registering(Delete::class) {
    delete("$projectDir/generated/")
}

tasks {
    compileJava {
        dependsOn(wsdl2Java)
    }

    clean {
        dependsOn(deleteGenerated)
    }
}

java {
    sourceSets["main"].java {
        srcDir("generated/src/main/java")
    }

    sourceSets["main"].resources {
        srcDir("generated/src/main/resources")
    }
}

Answer 1

您可以在Gradle导入或IDE制作之前/之后mark any task or run configuration to be activated：

Answer 2

我现在有一个可行的解决方案。 Eclipse和IntelliJ都在导入时生成源代码。

首先，我们添加特定于IDE的插件。

apply {
    plugin("idea")
    plugin("eclipse")
}

然后，我们获得相应的IDE任务，并添加自己在val wsdl2Java中定义的任务作为依赖项

// find by name (in tasks container), since a module is also called 'idea'
project.tasks.findByName("idea")?.dependsOn(wsdl2Java)
project.tasks.findByName("eclipse")?.dependsOn(wsdl2Java)

唯一的问题是，显然Eclipse无法处理

java {
    sourceSets["main"].java {
        srcDir("generated/src/main/java")
    }

    sourceSets["main"].resources {
        srcDir("generated/src/main/resources")
    }
}

但这是一个不同的问题。

更新

下面的代码块告诉Eclipse包括生成的源代码

eclipse {
    classpath {
        plusConfigurations.add(configurations.findByName("compile"))
    }
}

这会告诉IntelliJ将生成的并且已经包含的源标记为生成的

idea {
    module {
        generatedSourceDirs.add(file("generated/src/main/java"))
    }
}

使自定义Gradle任务生成代码，在IDE导入上运行

2 个答案: