Question

我正在像这样动态地调用类的方法，并且它的工作原理是：

CALL METHOD (gc_zcl_mapping_methods)=>(<ls_import_params>-attr_logic_method)
  EXPORTING
    iv_dats      = <lv_value>
  RECEIVING
    rv_timestamp = <ls_import_params>-attr_value.

问题是我要命名两个参数iv_dats和rv_timestamp。
并非每个方法都有这些参数名称，因此我正在寻找一种无需命名参数即可调用它们的方法。
我尝试过这种方法，但是出现很多语法错误。

<ls_import_params>-attr_value = (gc_zcl_mapping_methods)=>(<ls_import_params>-attr_logic_method)(<lv_value>).

我是否有正确的语法来省略参数名称？

Answer 1

不幸的是，您还必须命名返回参数和其他参数。

ABAP documentation

中说明了完整的动态调用

对于您的示例代码，将提供以下代码：

DATA(ptab) = VALUE abap_parmbind_tab( 
    ( name  = 'IV_DATS' 
      kind  = cl_abap_objectdescr=>exporting 
      value = REF #( <lv_value> ) )
    ( name  = 'RV_TIMESTAMP'
      kind  = cl_abap_objectdescr=>receiving
      value = REF #( <ls_import_params>-attr_value ) ) ). 

DATA(etab) = VALUE abap_excpbind_tab( ).

CALL METHOD (gc_zcl_mapping_methods)=>(<ls_import_params>-attr_logic_method) 
    PARAMETER-TABLE ptab 
    EXCEPTION-TABLE etab.

您可以使用RTTI来获取返回参数的名称（在这里，我想这个类是全局的），也可以对其进行修改以获取其他参数名称：

DATA(rtti_class) = CAST cl_abap_objectdescr( 
    cl_abap_typedescr=>describe_by_name( '\CLASS=' && gc_zcl_mapping_methods ) ).

DATA(method) = rtti_class->methods[ name = <ls_import_params>-attr_logic_method ].

DATA(returning_parameter) = method-parameters[ parm_kind = cl_abap_objectdescr=>returning ].

DATA(returning_parameter_name) = returning_parameter-name.

我让您添加对异常的处理。

附录：最小，完整且可验证的示例：

让我们说这个静态调用是动态完成的：

DATA(result) = VALUE sychar01( ).
DATA(ltxttab) = VALUE rslinltab( ( kind = 'E' numb = 1 param = 'MSGID' value = 'MESSAGEGY9' )
                                 ( kind = 'E' numb = 1 param = 'PRAGMA' value = '##DUMMY' ) ).

cl_abap_syntax_message=>long_text_exists(
  EXPORTING
    p_kind            = 'E'
    p_number          = 1
    p_ltxttab         = ltxttab
  RECEIVING
    p_result          = result
  EXCEPTIONS
    message_not_found = 1 ).

动态版本（同样，RECEIVING参数是在运行时动态确定的，但是通常不需要，因为它的名称在编译时就知道了）

DATA(rtti_class) = CAST cl_abap_objectdescr(
    cl_abap_typedescr=>describe_by_name( '\CLASS=' && 'CL_ABAP_SYNTAX_MESSAGE' ) ).
DATA(method) = rtti_class->methods[ name = 'LONG_TEXT_EXISTS' ].
DATA(returning_parameter) = method-parameters[ parm_kind = cl_abap_objectdescr=>returning ].
DATA(returning_parameter_name) = returning_parameter-name.
ASSERT returning_parameter_name = 'P_RESULT'. " <=== just for the demo

DATA(ptab) = VALUE abap_parmbind_tab(
    ( name  = 'P_KIND'
      kind  = cl_abap_objectdescr=>exporting
      value = REF #( 'E' ) )
    ( name  = 'P_NUMBER'
      kind  = cl_abap_objectdescr=>exporting
      value = REF #( 1 ) )
    ( name  = 'P_LTXTTAB'
      kind  = cl_abap_objectdescr=>exporting
      value = REF #( ltxttab ) )
    ( name  = returning_parameter_name
      kind  = cl_abap_objectdescr=>receiving
      value = REF #( result ) ) ).

DATA(etab) = VALUE abap_excpbind_tab(
    ( name = 'MESSAGE_NOT_FOUND' value = 1 ) ).

CALL METHOD ('CL_ABAP_SYNTAX_MESSAGE')=>('LONG_TEXT_EXISTS')
  PARAMETER-TABLE ptab
  EXCEPTION-TABLE etab.

调用动态方法而不命名参数

1 个答案: