Question

我正在编写一个读yacc规范文件的antlr语法。 Yacc规范文件的格式为

declarations 
%%
rules 
%%
programs

但是，我只对yacc spec文件的声明和规则部分感兴趣。我已经定义了与声明和规则完全匹配的规则，但是我试图使用通配符（。*？）来匹配第二个'%%'之后的所有内容。这失败了。这是
Link to my anltr grammar for yacc grammars

如何匹配第二个'%%'之后的内容。

我还尝试使用

匹配EOF以外的任何内容

<some_rule> : ~(EOF)* ;

Here's an example of the file that fails

Answer 1

您可以做的是创建一个单独的词法分析器语法，以便可以使用lexical modes。

这样，您将从默认的声明模式开始，并且第一次遇到%%时，您将推入RULE_MODE。当您遇到另一个%%时，您将推入SUBROUTINE_MODE。在最后一种模式下，您只需skip遇到的所有字符。

快速演示：

// File: YaccLexer.g4
lexer grammar YaccLexer;

DECLARATION_TOKEN
 : [a-zA-Z]+
 ;

SPACES
 : [ \t\r\n]+ -> skip
 ;

DECLARATION_END
 : '%%' -> skip, pushMode(RULE_MODE)
 ;

mode RULE_MODE;

  RULE_TOKEN
   : [a-zA-Z]+
   ;

  SPACES_RULE_TOKEN
   : [ \t\r\n]+ -> skip
   ;

  RULE_END
   : '%%' -> skip, pushMode(SUBROUTINE_MODE)
   ;

mode SUBROUTINE_MODE;

  ANY
   : . -> skip
   ;

如果您根据上述语法生成了词法分析器，并标记了输入内容：

foo
bar

%%

baz

%%

ignore
me

将创建以下令牌：

DECLARATION_TOKEN         'foo'
DECLARATION_TOKEN         'bar'
RULE_TOKEN                'baz'

您可以像下面这样在解析器语法中使用YaccLexer：

// File: YaccParser.g4
parser grammar YaccParser;

options {
  tokenVocab= YaccLexer;
}

// your parser rules here

ANTLR通配符运算符不使用预期的输入

1 个答案: