如何将xslt 1.0键与计算值而不是静态节点值一起使用？

时间：2019-02-14 09:15:33

标签： xml xslt-1.0

通过这个小的XSL转换，我可以给“扁平”的xml结构一些层次结构：

<?xml version="1.0"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
    <xsl:strip-space elements="*"/>
    <xsl:key name="child1" match="item[meta/para/level]" use="generate-id(preceding-sibling::item[meta/para/level &lt; current()/meta/para/level][1])"/>
    <xsl:key name="child2" match="item[meta/text]" use="generate-id(preceding-sibling::item[meta/para/level][1])"/>
    <xsl:template match="/doc">
        <xsl:variable name="min"> <!-- xslt2.0 min() -->
            <xsl:for-each select="item/meta/para/level">
                <xsl:sort select="." data-type="number"/>
                <xsl:if test="position() = 1">
                    <xsl:value-of select="."/>
                </xsl:if>
            </xsl:for-each>
        </xsl:variable>
        <root>
            <xsl:apply-templates select="item[meta/para/level = $min] | key('child2', '')"/>
        </root>
    </xsl:template>
    <xsl:template match="item[meta/para/level]">
        <test title="{meta/para/title}">
            <xsl:apply-templates select="key('child1', generate-id()) | key('child2', generate-id())"/>
        </test>
    </xsl:template>
    <xsl:template match="item[meta/text]">
        <text>
            <xsl:value-of select="meta/text"/>
        </text>
    </xsl:template>
</xsl:stylesheet>

应用于具有扁平结构的XML示例

<?xml version="1.0" encoding="UTF-8"?>
<doc>
    <item>
        <meta>
            <text>abc</text>
        </meta>
    </item>
    <item>
        <meta>
            <para>
                <level>1</level>
                <title>a</title>
            </para>
        </meta>
    </item>
    <item>
        <meta>
            <para>
                <level>2</level>
                <title>b</title>
            </para>
        </meta>
    </item>
    <item>
        <meta>
            <para>
                <level>3</level>
                <title>c</title>
            </para>
        </meta>
    </item>
    <item>
        <meta>
            <para>
                <level>4</level>
                <title>d</title>
            </para>
        </meta>
    </item>
    <item>
        <meta>
            <para>
                <level>4</level>
                <title>e</title>
            </para>
        </meta>
    </item>
    <item>
        <meta>
            <para>
                <level>5</level>
                <title>f</title>
            </para>
        </meta>
    </item>
    <item>
        <meta>
            <para>
                <level>2</level>
                <title>g</title>
            </para>
        </meta>
    </item>
    <item>
        <meta>
            <text>def</text>
        </meta>
    </item>
    <item>
        <meta>
            <text>ghi</text>
        </meta>
    </item>
    <item>
        <meta>
            <para>
                <level>4</level>
                <title>h</title>
            </para>
        </meta>
    </item>
</doc>

（期望的）层次结构结果如下：

<?xml version="1.0" encoding="UTF-8"?>
<root>
   <text>abc</text>
   <test title="a">
      <test title="b">
         <test title="c">
            <test title="d"/>
            <test title="e">
               <test title="f"/>
            </test>
         </test>
      </test>
      <test title="g">
         <text>def</text>
         <text>ghi</text>
         <test title="h"/>
      </test>
   </test>
</root>

如果“级别”信息不是由整数确定，而是由字符串的长度确定，则转换不会成功。

<?xml version="1.0" encoding="UTF-8"?>
<doc>
    <item>
        <meta>
            <text>abc</text>
        </meta>
    </item>
    <item>
        <meta>
            <para>
                <level>a</level>
                <title>a</title>
            </para>
        </meta>
    </item>
    <item>
        <meta>
            <para>
                <level>bc</level>
                <title>b</title>
            </para>
        </meta>
    </item>
    <item>
        <meta>
            <para>
                <level>def</level>
                <title>c</title>
            </para>
        </meta>
    </item>
    <item>
        <meta>
            <para>
                <level>ghij</level>
                <title>d</title>
            </para>
        </meta>
    </item>
    <item>
        <meta>
            <para>
                <level>klmn</level>
                <title>e</title>
            </para>
        </meta>
    </item>
    <item>
        <meta>
            <para>
                <level>opqrs</level>
                <title>f</title>
            </para>
        </meta>
    </item>
    <item>
        <meta>
            <para>
                <level>tu</level>
                <title>g</title>
            </para>
        </meta>
    </item>
    <item>
        <meta>
            <text>def</text>
        </meta>
    </item>
    <item>
        <meta>
            <text>ghi</text>
        </meta>
    </item>
    <item>
        <meta>
            <para>
                <level>vwxy</level>
                <title>h</title>
            </para>
        </meta>
    </item>
</doc>

通过调用“字符串长度”来查找最小值的函数：

<xsl:sort select="string-length(.)" data-type="number"/>

应如何使用键，以便将字符串的长度评估为级别信息？

2 个答案:

答案 0 :(得分：1)

在比较child1的键meta/para/level中，您需要为案例计算string-length

<level>的字符串值而不是数字。如下所示：

<?xml version="1.0"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:key name="child1" match="item[meta/para/level]" 
use="generate-id(preceding-sibling::item[string-length(meta/para/level) &lt; string-length(current()/meta/para/level)][1])"/>

<xsl:key name="child2" match="item[meta/text]" 
use="generate-id(preceding-sibling::item[meta/para/level][1])"/>

<xsl:template match="/doc">
    <xsl:variable name="min"> <!-- xslt2.0 min() -->
        <xsl:for-each select="item/meta/para/level">

            <xsl:sort select="string-length(.)" data-type="number"/>
            <xsl:if test="position() = 1">
                <xsl:value-of select="."/>
            </xsl:if>
        </xsl:for-each>
    </xsl:variable>
    <root>
        <xsl:apply-templates select="item[meta/para/level = $min] | key('child2', '')"/>
    </root>
</xsl:template>
<xsl:template match="item[meta/para/level]">
    <test title="{meta/para/title}">
        <xsl:apply-templates select="key('child1', generate-id()) | key('child2', generate-id())"/>
    </test>
</xsl:template>
<xsl:template match="item[meta/text]">
    <text>
        <xsl:value-of select="meta/text"/>
    </text>
</xsl:template>
</xsl:stylesheet>

请参考相同的here

答案 1 :(得分：1)

@Vebbie几乎正确（谢谢！）。 生成密钥时，重要的是要排除不适当的节点：<xsl:key name="child1" match="item[meta/para]" use="generate-id(preceding-sibling::item[meta/para and (string-length(meta/para/level) &lt; string-length(current()/meta/para/level))][1])"/>，因此完整的答案是

<?xml version="1.0"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
    <xsl:strip-space elements="*"/>
    <xsl:key name="child1" match="item[meta/para]"
use="generate-id(preceding-sibling::item[meta/para and (string-length(meta/para/level) &lt; string-length(current()/meta/para/level))][1])"/>
    <xsl:key name="child2" match="item[meta/text]"
use="generate-id(preceding-sibling::item[meta/para][1])"/>
    <xsl:template match="/doc">
        <xsl:variable name="min">
            <!-- xslt2.0 min() -->
            <xsl:for-each select="item/meta/para/level">
                <xsl:sort select="string-length(.)" data-type="number"/>
                <xsl:if test="position() = 1">
                    <xsl:value-of select="string-length(.)"/>
                </xsl:if>
            </xsl:for-each>
        </xsl:variable>
        <root>
            <xsl:apply-templates select="item[string-length(meta/para/level) = $min] | key('child2', '')"/>
        </root>
    </xsl:template>
    <xsl:template match="item[meta/para]">
        <test title="{meta/para/title}">
            <xsl:apply-templates select="key('child1', generate-id()) | key('child2', generate-id())"/>
        </test>
    </xsl:template>
    <xsl:template match="item[meta/text]">
        <text>
            <xsl:value-of select="meta/text"/>
        </text>
    </xsl:template>
</xsl:stylesheet>
相关问题
最新问题