Question

选择所有与列匹配的数据库表，然后使用循环将表名传递给下一个查询。如果列名和列值匹配，则返回true并使用存储过程存在于循环中：

CREATE OR REPLACE PROCEDURE TEST 
(
NAME IN VARCHAR2 ,
ID IN NUMBER,
RE OUT SYS_REFCURSOR 
) AS

BEGIN
OPEN  RE FOR SELECT A.TABLE_NAME FROM
user_tables A JOIN user_tab_columns C
ON C.TABLE_NAME = A.TABLE_NAME
WHERE C.COLUMN_NAME = NAME;

FOR RE IN LOOP

v_Sql := 'SELECT COUNT(*) FROM '|| LOOP.TABLE_NAME || 'WHERE COLUMN_NAME = 
ID';
EXECUTE IMMEDIATE v_Sql
IF v_Sql%ROWCOUNT > 0 THEN
return true; 
EXIT

END LOOP;

END TEST;

更多了解问题

//Get all the tables of database where campus_id is exist in any table of 
 database
 Campus, Class, Section (3 tables found)
 Apply forloop on the records
 Select count(campus_id) as total from (table name using loop) where campus_id = 1(value 
 pass)
 if(total > 0){

 Exist for loop and return true
 }
 else{
 Again iterate the loop to next value
 }

Answer 1

您描述的内容没有多大意义。如果有几张表包含要检查的列，并且找到第一个表就退出循环，其余的又如何呢？

这就是我要做的，看看是否有帮助。我将创建一个函数（不是过程），该函数返回一个表。为此，我将首先创建类型：

SQL> create or replace type t_record as object (tn varchar2(30), cnt number);
  2  /

Type created.

SQL> create or replace type t_table as table of t_record;
  2  /

Type created.

SQL>

功能：

在游标FOR循环中，我正在选择包含该列的表
L_STR用于撰写SELECT语句
DBMS_OUTPUT.PUT_LINE用于首先显示它，以便我可以直观地检查它是否正确设置。
如果是，我正在使用EXECUTE IMMEDIATE
结果存储到表类型中，并返回给调用方

SQL> create or replace function f_colname
  2    (par_column_name  in varchar2,
  3     par_column_value in varchar2
  4    )
  5    return t_table
  6  is
  7    retval t_table := t_table();
  8    l_str  varchar2(200);
  9    l_cnt  number;
 10  begin
 11    for cur_r in (select table_name
 12                  from user_tab_columns
 13                  where column_name = par_column_name
 14                 )
 15    loop
 16      l_str := 'select count(*) from ' || cur_r.table_name ||
 17               ' where ' || par_column_name || ' = ' ||
 18               chr(39) || par_column_value || chr(39);
 19      -- Display l_str first, to make sure that it is OK:
 20      -- dbms_output.put_line(l_str);
 21      execute immediate l_str into l_cnt;
 22      retval.extend;
 23      retval(retval.count) := t_record(cur_r.table_name, l_cnt);
 24    end loop;
 25    return retval;
 26  end;
 27  /

Function created.

测试：

SQL> select * from table (f_colname('DEPTNO', '10'));

TN                                    CNT
------------------------------ ----------
TEST_201812                             1
DEPT                                    1
EMP                                     3

SQL> select * from table (f_colname('ENAME', 'KING'));

TN                                    CNT
------------------------------ ----------
EMP                                     1
BONUS                                   1

SQL>

对于某些数据类型（例如DATE），该方法将无法正常工作，并且在必要时必须进行调整。

[编辑：编辑问题后]

那么，那更简单。它仍然应该是一个函数（返回一个布尔值，正如您所说的-如果发现了某些东西，您想返回TRUE）。代码与以前的功能非常相似。

SQL> create or replace function f_colname
  2    (par_column_name  in varchar2,
  3     par_column_value in varchar2
  4    )
  5    return boolean
  6  is
  7    l_str  varchar2(200);
  8    l_cnt  number;
  9    retval boolean := false;
 10  begin
 11    for cur_r in (select table_name
 12                  from user_tab_columns
 13                  where column_name = par_column_name
 14                 )
 15    loop
 16      l_str := 'select count(*) from ' || cur_r.table_name ||
 17               ' where ' || par_column_name || ' = ' ||
 18               chr(39) || par_column_value || chr(39);
 19      -- Display l_str first, to make sure that it is OK:
 20      -- dbms_output.put_line(l_str);
 21      execute immediate l_str into l_cnt;
 22      if l_cnt > 0 then
 23         retval := true;
 24         exit;
 25      end if;
 26    end loop;
 27    return retval;
 28  end;
 29  /

Function created.

测试：由于无法在SQL层返回布尔值，因此必须使用匿名PL / SQL块，如下所示：

SQL> declare
  2    l_ret boolean;
  3  begin
  4    if f_colname('DEPTNO', '15') then
  5       dbms_output.put_line('It exists');
  6    else
  7       dbms_output.put_line('It does not exist');
  8    end if;
  9  end;
 10  /
It does not exist

PL/SQL procedure successfully completed.

SQL>

在Oracle中的存储过程中动态运行查询

1 个答案: