Question

我正在构建一个仪表板以汇总购买数据。我有一个用于购买数据的工作表，还有一个参考表工作表，其中包含财政月的开始和结束日期，相关的财政年度和财政月（总结如下）以及仪表板工作表。

表格：oetFiscalMonths

Start Date | End Date | Month    | Year  
10/1/17    | 10/30/17 | October  | 2018  
10/31/17   | 11/1/17  | November | 2018

仪表板上有一个格式如下的数据表

         | Beginning Budget | Total Purchases | Remaining Budget |  
October  | $XXXXXXXXX.00    | $XXXXXX.00      | $XXXXXXXXXX.00   |  
November | $XXXXXXXXX.00    | $XXXXXX.00      | $XXXXXXXXXX.00   |  
December | $XXXXXXXXX.00    | $XXXXXX.00      | $XXXXXXXXXX.00   |  
January  | $XXXXXXXXX.00    | $XXXXXX.00      | $XXXXXXXXXX.00   |

我要输入的公式将出现在“购买总额”中，并将根据右边的财政月表汇总右边一个财政月中的所有购买，同时满足其他条件以完成SUMIFS公式。我只是不确定如何处理日期范围部分，因为它们甚至大部分时间都不会跟随日历月，而且日期表的格式也是如此，因为其他几个部分都使用了当前格式。

非常感谢您的帮助！

Answer 1

您也可以按sumproduct公式进行尝试，它的好处是无需打开工作表公式即可进行计算。

=SUMPRODUCT(--(B:B>=H3)*(B:B<=I3),(C:C))

C：C =总和范围

B：B =日期搜索范围

H3 =开始日期的值

I3 =结束日期的值

Answer 2

您可以像下面显示的那样使用SUMIFS。请原谅随机行和单元格的使用情况。我将尝试在下面解释。

=SUMIFS(C:C,A:A,">="&G1,A:A,"<="&H1)

C：C =总和范围
A：A =日期搜索范围
G1 =开始日期的值
H1 =结束日期的值

编辑： 我建议将“月份”列移到最前面，然后将日期更改为如下所示。这样，您可以使用vlookup查找日期，然后将vlookup合并到摘要中。

  Month  | Start Date | End Date | Year  
October  | 10/1/17    | 10/30/17 | 2018  
November | 10/31/17   | 11/1/17  | 2018

=SUMIFS(G:G,F:F,">="&VLOOKUP(J6,M:O,2,0),F:F,"<="&VLOOKUP(J6,M:O,3,0))

M：O是您的会计年度表
J6是您要输入搜索月份的地方
第一个VLOOKUP中的第2列将为您提供开始日期
第二个VLOOKUP中的第3列将为您提供结束日期

让我知道您是否有任何疑问，因为我使用的是随机的行和列，所以可能会造成混淆。

Answer 3

假设sheet1是您的信息中心，sheet2包含您的oetFiscalMonths表，而sheet3包含您想要SUM的购买及其对应的购买日期，您可以结合使用SUMIFS和INDEX + MATCH来设置您当前的文件结构：

=SUMIFS(sheet3!C:C,sheet3!B:B,">="&INDEX(sheet2!A:A,MATCH(sheet1!A2,sheet2!C:C,0)),sheet3!B:B,"<="&INDEX(sheet2!B:B,MATCH(sheet1!A2,sheet2!C:C,0)))

传说如下：

sheet3!C:C包含您要SUM

的购买价值

sheet3!B:B包含购买日期

sheet2!A:A包含您月份的开始日期

sheet2!B:B包含您月份的结束日期

sheet2!C:C包含您的月份

sheet1!A2包含您要购买的SUM的第一个月。

SUMIFS对自定义日期范围之间的数据求和

3 个答案: