Question

我有一个MainForm模式显示的表格。在这种模式形式中，我像这样覆盖WM_SYSCOMMAND：

protected
  procedure WMSysCommand(var Msg: TWMSysCommand);  message WM_SYSCOMMAND;

procedure TModalDlg.WMSysCommand(var Msg: TWMSysCommand);
begin
 if (fsModal in FormState) and (Msg.CmdType and $FFF0 = SC_MINIMIZE)
  then Application.MainForm.WindowState:= wsMinimized
  else inherited;
end;

...，当我最小化模态形式时，整个应用程序最小化。一切正常，但是当我单击任务栏按钮并还原了应用程序时，聚焦的窗口是MainForm，而不是模态窗口，就像应该的那样。我应该怎么做才能以最有形式的形式来恢复应用程序？

Answer 1

在当前设计中，您有一个用于最小化窗口的任务栏按钮，该窗口由于模式形式而被禁用。我认为您无法为此设置找到一个明智的解决方案，两个表单都不会收到WM_SYSCOMMAND-模态表单，因为它没有任务栏按钮，而主表单也没有，因为它已被禁用。 / p>

最小化模式窗体时，请更改策略并切换任务栏按钮。也就是说，您将有一个用于模式窗体而不是主窗体的任务栏按钮。然后，当您收到还原命令时，您可以在同一个事件处理程序中进行拦截和反转。下面是一个有效的示例，但我要注意的是，强烈建议不要在创建窗口后更改窗口的所有者，并且实际上已经有一段时间没有记录了。

type
  TModalDlg = class(TForm)
    ...
  private
    FParentWnd: HWND;
  protected
    procedure WMSysCommand(var Msg: TWMSysCommand); message WM_SYSCOMMAND;
  end;

...

procedure TModalDlg.WMSysCommand(var Msg: TWMSysCommand);
begin
  if (fsModal in FormState) then begin
    case Msg.CmdType and $FFF0 of
      SC_MINIMIZE:
        begin
          SetWindowLong(Handle, GWL_EXSTYLE,
              (GetWindowLong(Handle, GWL_EXSTYLE) or WS_EX_APPWINDOW));

          FParentWnd := GetWindowLong(Handle, GWL_HWNDPARENT);
          if FParentWnd <> 0 then
            ShowWindow(FParentWnd, SW_HIDE);

          SetWindowLong(Handle, GWL_HWNDPARENT, 0);
        end;
      SC_RESTORE:
        begin
          SetWindowLong(Handle, GWL_EXSTYLE,
              (GetWindowLong(Handle, GWL_EXSTYLE) and not WS_EX_APPWINDOW));

          if FParentWnd <> 0 then begin
            SetWindowLong(Handle, GWL_HWNDPARENT, FParentWnd);
            ShowWindow(FParentWnd, SW_SHOW);
          end;
        end;
    end;
  end;
  inherited;
end;

如何还原最小化模态形式？

1 个答案: