Question

我必须在PL / SQL中比较两个Varchar2，但以3个字符为块。例如，以下两个字符串：“ Synch ron ize”和“ f ron t”将匹配，因为它们都包含子字符串“ ron”。

要解决此问题，我可以获取第一个字符串的三个连续字符的所有块，然后在第二个字符串中查找其中的任何一个。

我的问题：是否有更简单/优化的解决方案在PL / SQL中获得相同的结果？

谢谢。

下面，您可以找到一个代码示例，其中如果存在匹配项，则v_found的值将大于0：

DECLARE  
    v_string1   VARCHAR2(30) := '1234567';  
    v_string2    VARCHAR2(30) := 'abcd345efg';  
    v_substring    VARCHAR2 (100);  
  v_len          PLS_INTEGER;  
  v_found        PLS_INTEGER;  
BEGIN  
  v_len := LENGTH(v_string1);  
  IF (v_len > 2 ) THEN  
    FOR i IN 1 .. v_len - 2  
    LOOP  
      v_substring := SUBSTR( v_string1, i, 3 );  
      dbms_output.put_line( v_substring );  
      v_found := INSTR( v_string2, v_substring );  
      dbms_output.put_line( 'v_string2<' || v_string2 || '>, v_substring<' || v_substring || '>, v_found <' || v_found || '>' );  
    END LOOP;  
  END IF;  
END;

Answer 1

假设您有一个字符串，并且需要获取所有3个字符的子字符串；这可能是一种方式：

select substr(string1, level, 3)
from (select '1234567' string1 from dual)
connect by level +2 <= length(string1);

SUBSTR(STRING1,LEVEL,3)         
--------------------------------
123                             
234                             
345                             
456                             
567

您可以使用它从两个字符串中获取所有子字符串，然后使用JOIN进行检查：

DECLARE  
    v_string1   VARCHAR2(30) := '1234567';  
    v_string2   VARCHAR2(30) := 'abcd345efg'; 
    v_check     number;
BEGIN    
    select count(*)
    into v_check
    from (
            select substr(v_string1, level, 3) token
            from dual
            connect by level +2 <= length(v_string1)
         ) tokens_1
         inner join 
         (
            select substr(v_string2, level, 3) token
            from dual
            connect by level +2 <= length(v_string2)
         ) tokens_2
         on (tokens_1.token = tokens_2.token);
    if v_check = 1 then
        dbms_output.put_line('MATCH');
    else
        dbms_output.put_line('NO MATCH');
    end if;
END;

更紧凑的方法可能是：

select case when max(instr(string2, substr(string1, level, 3))) = 0
        then 'NO MATCH'
        else 'MATCH'
       end 
from (select '1234567' string1, 'abcd345efg' string2 from dual)
connect by level +2 <= length(string1)

部分比较两个varchar2

1 个答案: