Question

我想将时钟频率（以Hz为单位）作为术语级别的值来访问，以便可以在计数器中使用它。

到目前为止，我能想到的一种方法是将类型级别Dom ain解压缩到其时钟周期（以ps为单位），然后将其转换为时钟速率。但是，这需要额外的KnownNat ps约束，然后该约束会感染尝试使用它的所有内容，一直到topLevel：

clkPeriod :: forall dom gated name ps. (dom ~ Dom name ps, KnownNat ps) => Clock dom gated -> Integer
clkPeriod clk = natVal (Proxy :: Proxy ps)

clkRate :: (dom ~ Dom name ps, KnownNat ps) => Clock dom gated -> Integer
clkRate clk = 10^12 `div` clkPeriod clk

另一种避免引入额外的KnownNat约束的方法是导入Clash.Signal.Internal和Clock上的模式匹配，因为它包含SNat的见证人。期间：

import Clash.Signal.Internal (Clock(..))

clkPeriod :: Clock dom gated -> Integer
clkPeriod (Clock _ period) = snatToInteger period
clkPeriod (GatedClock _ period _) = snatToInteger period

clkRate :: Clock dom gated -> Integer
clkRate clk = 10^12 `div` clkPeriod clk

但是这会使合成器崩溃（猜测我不应该导入Clash.Signal.Internal）：

*** Exception: Clash.Rewrite.Util(566): 
Can't create selector ("Clash.Normalize.Transformations(1136):doPatBndr",1,0) for:
($dKnownNat23000 :: GHC.Natural.Natural)

Additional info: TyCon has no DataCons: 
Name {nameSort = User, nameOcc = GHC.Natural.Natural3674937295934324782, nameLoc = UnhelpfulSpan "<no location info>"} GHC.Natural.Natural3674937295934324782

这里是一个完整的模块，出现了这个问题（我尝试将其与:vhdl进行合成以得到上述错误）：

module Test where

import Clash.Prelude hiding (clkPeriod)
import Data.Word
import Clash.Signal.Internal (Clock(..))

type FromHz rate = 1000000000000 `Div` rate
type Dom25 = Dom "CLK_25MHZ" (FromHz 25175000)

topEntity
    :: Clock Dom25 Source
    -> Reset Dom25 Asynchronous
    -> Signal Dom25 Bit
topEntity = exposeClockReset board
  where
    board = boolToBit <$> r

    r = regEn False (counter .==. 0) (not <$> r)
    counter = register clkrt $ mux (counter .==. 0) (pure clkrt) (pred <$> counter)
    clkrt = fromIntegral $ hideClock clkRate

clkPeriod :: Clock dom gated -> Integer
clkPeriod (Clock _ period) = snatToInteger period
clkPeriod (GatedClock _ period _) = snatToInteger period

clkRate :: Clock dom gated -> Integer
clkRate clk = 10^12 `div` clkPeriod clk

我的问题是，是否有一种方法可以在术语级别上对clkRate进行验证而不引入任何额外的KnownNat约束或导入任何Internal模块？

Answer 1

Clash的主要开发人员Christiaan Baaij认为这是Issue #348中的Clash编译器错误。引用他在该问题报告中的评论：

所以问题是我们得到的Core在类型Integer上进行模式匹配，并公开其表示的内部。编译器显然无法处理的问题。我将创建一个变通方法/ hack，以始终选择Integer适合[-2 ^ 63 .. 2 ^ 63-1]范围内的分支，因为Clash当前“错误地”翻译了{{1 }}转换为64位数字。

Answer 2

使用Clash 1.0.0，可以在没有爬行KnownNat约束或不导入任何Internal模块的情况下完成此操作。诀窍是使用knownDomain获取给定时钟域的SDomainConfiguration，该时钟域在单个时钟周期的长度（以皮秒为单位）中将包含一个SNat period。通过SNat构造函数上的模式匹配，KnownNat见证人将进入范围。

clkPeriod :: forall dom. (KnownDomain dom) => Clock dom -> Integer
clkPeriod clk = case knownDomain @dom of
    SDomainConfiguration _ rate@SNat{} _ _ _ _ -> natVal rate

clkRate :: (KnownDomain dom) => Clock dom -> Integer
clkRate clk = 1_000_000_000_000 `div` clkPeriod clk

这是更新的顶级定义：

{-# LANGUAGE NumericUnderscores #-}
module Test where

import Clash.Prelude hiding (clkPeriod)
import Data.Word

createDomain vSystem{vName="Dom25", vPeriod = hzToPeriod 25_000_000}

topEntity
    :: Clock Dom25
    -> Reset Dom25
    -> Enable Dom25
    -> Signal Dom25 Bit
topEntity = exposeClockResetEnable board
  where
    board = boolToBit <$> r

    r = regEn False (counter .==. 0) (not <$> r)
    counter = register clkrt $ mux (counter .==. 0) (pure clkrt) (pred <$> counter)
    clkrt = fromInteger @Word32 $ hideClock clkRate

我已经测试了它可以与综合一起使用，并且将周期长度转换为时钟速率的划分是在编译时完成的。

术语级对时钟速率的访问

2 个答案: