Question

问候，我有以下代码：

Private Sub makeNewReports()


Dim wkSheet As Worksheet
Set wkSheet = ActiveWorkbook.Worksheets("Grades")

Dim i As Long

Dim myMap As Dictionary
Set myMap = New Dictionary


For i = 4 To 6 'wkSheet.Range("a1").End(xlToRight).Column - 1
    Dim myVals As dateValueItem
    myVals.total_value = wkSheet.Cells(2, i)
    myVals.items = wkSheet.Cells(1, i)
    myVals.student_value = wkSheet.Cells(4, i)
    myMap.Add wkSheet.Cells(3, i), myVals
Next i
End Sub

以及以下针对dateValueItem的代码

Option Explicit

Public Type dateValueItem
      total_value As Long
      items As String
      student_value As Long
End Type

当我运行上面的代码时，我遇到了问题

“编译错误：只有在公共对象模块中定义的用户定义类型可以与变体进行强制转换，或传递给后期绑定函数”

我正在尝试将3个不同的值映射到一个特定的日期；日期位于第三行。第2行和第4行具有数字值，第1行具有字符串值。希望能够将所有这些组织在一起，以便最终将描述和值连接到日期。

Answer 1

这可能是最快的方法。创建一个类并将其命名为dateValueItem

Option Explicit

Public total_value As Long
Public items As String
Public student_value As Long

并将您的代码更改为

Option Explicit

Private Sub makeNewReports()
Dim wkSheet As Worksheet
    Set wkSheet = ActiveWorkbook.Worksheets("Grades")

    Dim i As Long

    Dim myMap As Dictionary
    Set myMap = New Dictionary

    Dim myVals As dateValueItem
    For i = 4 To 6    'wkSheet.Range("a1").End(xlToRight).Column - 1
        Set myVals = New dateValueItem
        myVals.total_value = wkSheet.Cells(2, i)
        myVals.items = wkSheet.Cells(1, i)
        myVals.student_value = wkSheet.Cells(4, i)
        myMap.Add wkSheet.Cells(3, i), myVals
    Next i
End Sub

后期绑定功能出现问题

1 个答案: