将协数组子数组传递给函数会导致数组的错误部分

时间：2018-07-10 13:58:16

标签： fortran parameter-passing intel-fortran fortran-coarrays

我试图了解如何将多维协同数组的一部分传递给函数。我想使用这样的功能：

    function get_int_vec(vec_int_2get, rank) result(ret_val)
      implicit none
      integer,  dimension(:), codimension[*], intent(in) :: vec_int_2get
      integer, intent(in) :: rank
      integer, allocatable, dimension(:) :: ret_val 

      ret_val = vec_int_2get(:)[rank]

    end function ! get_int_vec

获取整个数组效果很好。  但是当传递一片coarray时，例如：

    vec_getA(:) = get_int_vec(matrix_A(n, :), rank)

其中matrix_A被声明为

    integer, dimension(:, :), codimension[:],  allocatable :: matrix_A

并且分配正确，我总是得到matrix_A的第一列而不是第n列。

gfortran passing conventions说：

带有-fcoarray=lib [...]的

“标记和属于不可分配的共数组伪参数的偏移量作为隐藏参数沿字符长度隐藏参数传递。令牌是标识共数组和偏移量的不透明指针是类型为C_PTRDIFF_T的按值传递的整数，表示协数组的基址与所传递的标量或所传递数组的第一个元素之间的字节偏移。”

所以我期望函数也可以在矩阵切片上正常工作，因为从矩阵开始的偏移量应该传递给函数。

我做错了什么？

如果感兴趣的话：我使用的是Intel Parallel Studio XE 2018群集版本，而不是协数组的OpenCoarrays版本。

1 个答案:

答案 0 :(得分：2)

这似乎是Intel ifort 2018中的错误。您代码的语法似乎符合Fortran 2008标准（here）。使用OpenCoarrays和GFortran编译的相同代码将产生预期的结果。这是您的问题的（不是那么少，但是）可行的实现：

module coarrayFunc
    implicit none
contains
    function get_int_vec(vec_int_2get, rank) result(ret_val)
        implicit none
        integer,  dimension(:), codimension[*], intent(in) :: vec_int_2get
        integer, intent(in) :: rank
        integer :: ret_val(3)
        !integer :: ret_val(size(vec_int_2get)) ! using this results in internal compiler error when compiled with ifort.
        !integer, allocatable :: ret_val(:) ! both ifort and OpenCoarrays (GFortran) compile with this declaration, however both ifort give wrong results.
        ret_val = vec_int_2get(:)[rank]
    end function ! get_int_vec
end module coarrayFunc

program testNoncontiguousCoarray
    use coarrayFunc
    implicit none
    integer, allocatable    :: matrix_A(:,:)[:], dummy(:)
    integer                 :: rank, n, i, j, image
    integer, parameter      :: ilower = 1, iupper = 5
    integer, parameter      :: jlower = 1, jupper = 3

    allocate( matrix_A(ilower:iupper,jlower:jupper)[*] )

    do i = ilower, iupper
        do j = jlower, jupper
            matrix_A(i,j) = this_image()*100 + i*10 + j
        end do
    end do

    ! print matrix_A on each image
    sync all
    if (this_image()==1) then
        do image = 1, num_images()
            write(*,"(*(g0))") "matrix_A on image ", image, ":"
            do i = ilower, iupper
                write(*,"(*(g8.1))") matrix_A(i,:)[image]
            end do
            write(*,"(*(g0))")
        end do
        sync images(*)
    else
        sync images(1)
    end if
    sync all

    n = iupper
    rank = this_image()
    !rank = num_images()

    sync all
    if (this_image()==1) then
        write(*,"(*(g0))")
        write(*,"(*(g0))") "On all images: "
        write(*,"(*(g0))") "n = ", n
        write(*,"(*(g0))")
    end if
    sync all

    if (this_image()==1) then
        write(*,"(*(g0,' '))") "On Image ", this_image(), ": matrix_A( n =", n, ", : )[",rank,"] = ", matrix_A(n,:)[rank]
        dummy = get_int_vec(matrix_A(n,:), rank)
        write(*,"(*(g0,' '))") "On Image ", this_image(), ": get_int_vec( matrix_A( n =", n, ", : ), rank =", rank, ") = " &
                               , dummy
    else
        sync images (this_image()-1)
        write(*,"(*(g0,' '))") "On Image ", this_image(), ": matrix_A( n =", n, ", : )[",rank,"] = ", matrix_A(n,:)[rank]
        dummy = get_int_vec(matrix_A(n,:), rank)
        write(*,"(*(g0,' '))") "On Image ", this_image(), ": get_int_vec( matrix_A( n =", n, ", : ), rank =", rank, ") = " &
                               , dummy
    end if
    call sleep(1)
    if (this_image()<num_images()) sync images (this_image()+1)

end program testNoncontiguousCoarray

使用OpenCoarrays编译并运行此代码会产生：

matrix_A on image 1:
    111     112     113
    121     122     123
    131     132     133
    141     142     143
    151     152     153

matrix_A on image 2:
    211     212     213
    221     222     223
    231     232     233
    241     242     243
    251     252     253

matrix_A on image 3:
    311     312     313
    321     322     323
    331     332     333
    341     342     343
    351     352     353

matrix_A on image 4:
    411     412     413
    421     422     423
    431     432     433
    441     442     443
    451     452     453


On all images: 
n = 5

On Image  1 : matrix_A( n = 5 , : )[ 1 ] =  151 152 153 
On Image  1 : get_int_vec( matrix_A( n = 5 , : ), rank = 1 ) =  151 152 153 
On Image  2 : matrix_A( n = 5 , : )[ 2 ] =  251 252 253 
On Image  2 : get_int_vec( matrix_A( n = 5 , : ), rank = 2 ) =  251 252 253 
On Image  3 : matrix_A( n = 5 , : )[ 3 ] =  351 352 353 
On Image  3 : get_int_vec( matrix_A( n = 5 , : ), rank = 3 ) =  351 352 353 
On Image  4 : matrix_A( n = 5 , : )[ 4 ] =  451 452 453 
On Image  4 : get_int_vec( matrix_A( n = 5 , : ), rank = 4 ) =  451 452 453

输出希望得到的结果。请注意，我已经调整了原始函数，以便函数的结果将是一个自动数组，而不是可分配的数组（这似乎是OpenCoarrays中的另一个错误，即可分配的输出返回错误的结果）。使用ifort 2018 Windows运行相同的代码将重现您在自己的实现中观察到的错误：

>set FOR_COARRAY_NUM_IMAGES=4

>ifort /Qcoarray=shared testNoncontiguousCoarray.f90 -o run.exe
Intel(R) Visual Fortran Intel(R) 64 Compiler for applications running on Intel(R) 64, Version 18.0.2.185 Build 20180210
Copyright (C) 1985-2018 Intel Corporation.  All rights reserved.

Microsoft (R) Incremental Linker Version 14.13.26129.0
Copyright (C) Microsoft Corporation.  All rights reserved.

-out:run.exe
-subsystem:console
testNoncontiguousCoarray.obj

>run.exe
matrix_A on image 1:
     111     112     113
     121     122     123
     131     132     133
     141     142     143
     151     152     153

matrix_A on image 2:
     211     212     213
     221     222     223
     231     232     233
     241     242     243
     251     252     253

matrix_A on image 3:
     311     312     313
     321     322     323
     331     332     333
     341     342     343
     351     352     353

matrix_A on image 4:
     411     412     413
     421     422     423
     431     432     433
     441     442     443
     451     452     453


On all images:
n = 5

On Image  1 : matrix_A( n = 5 , : )[ 1 ] =  151 152 153
On Image  1 : get_int_vec( matrix_A( n = 5 , : ), rank = 1 ) =  111 112 113
On Image  2 : matrix_A( n = 5 , : )[ 2 ] =  251 252 253
On Image  2 : get_int_vec( matrix_A( n = 5 , : ), rank = 2 ) =  211 212 213
On Image  3 : matrix_A( n = 5 , : )[ 3 ] =  351 352 353
On Image  3 : get_int_vec( matrix_A( n = 5 , : ), rank = 3 ) =  311 312 313
On Image  4 : matrix_A( n = 5 , : )[ 4 ] =  451 452 453
On Image  4 : get_int_vec( matrix_A( n = 5 , : ), rank = 4 ) =  411 412 413

如您对问题的评论中所述，请考虑编写一个最小的可重现您所得到的错误的代码示例，并向英特尔的ifort编译器团队提交票证，以寻求可能的解决方案。

相关问题
最新问题