Question

我正在尝试使用 XML::Twig 提取XML文档的子集，以便我可以将其转换为CSV。

这是我的数据样本

<?xml version="1.0" encoding="UTF-8" standalone="no"?>
<Actions>
  <Click>
    <Field1>Data1</Field1>
    <Field2>Data2</Field2>
  </Click>
  <Click>
    <Field1>Data3</Field1>
    <Field2>Data4</Field2>
  </Click>
</Actions>

这是编码所需结果的尝试

#!/usr/bin/env perl

use strict;
use warnings;

use XML::Twig;
use Text::CSV; # later
use Data::Dumper;

my $file = shift @ARGV or die "Need a file to process: $!";

my $twig = XML::Twig->new();
$twig->parsefile($file);
my $root = $twig->root;

my @data;

for my $node ( $twig->findnodes( '//Click/*' ) ) {
  my $key = $node->name;
  my $val = $node->text;
  push @data, { $key => $val }
}

print Dumper \@data;

给出

$VAR1 = [
          {
            'Field1' => 'Data1'
          },
          {
            'Field2' => 'Data2'
          },
          {
            'Field1' => 'Data3'
          },
          {
            'Field2' => 'Data4'
          }
        ];

我想创建的是最好的散列数组

my @AoH = (
    { Field1 => 'Data1', Field2 => 'Data2' },
    { Field1 => 'Data3', Field2 => 'Data4' },
)

我不确定如何遍历数据以提取出来。

Answer 1

您的结构有两个级别，因此需要两个级别的循环。

my @data;
for my $click_node ( $twig->findnodes( '/Actions/Click' ) ) {
   my %click_data;
   for my $child_node ( $click_node->findnodes( '*' ) ) {
      my $key = $child_node->name;
      my $val = $child_node->text;
      $click_data{$key} = $val;
   }

   push @data, \%click_data;
}

local $Data::Dumper::Sortkeys = 1;
print(Dumper(\@data));

输出：

$VAR1 = [
          {
            'Field1' => 'Data1',
            'Field2' => 'Data2'
          },
          {
            'Field1' => 'Data3',
            'Field2' => 'Data4'
          }
        ];

使用XML :: Twig提取XML的子集

1 个答案: