Question

TclOO object equals实施的惯用模式是什么？

Scala case classes是否有类似物？

Answer 1

TclOO通过设计为您定义没有平等系统;由于对象通常是可修改的，因此没有自动概念可以应用于对象标识以外的其他概念，并且您可以只比较对象的名称以获得该对象（或info object namespace $theObj的结果，如果您非常偏执;我认为Tcl 8.7将提供更多选项，但尚未被接受）。

如果你想定义一个你所提议的平等系统，你可以这样做：

oo::class create PropertyEquals {
    method equals {other} {
        try {
            set myProps [my properties]
            set otherProps [$other properties]
        } on error {} {
            # One object didn't support properties method
            return 0
        }
        if {[lsort [dict keys $myProps]] ne [lsort [dict keys $otherProps]]} {
            return 0
        }
        dict for {key val} $myProps {
            if {[dict get $otherProps $key] ne $val} {
                 return 0
            }
        }
        return 1
    }
}

然后你只需要在你可能要比较的类上定义一个properties方法，然后混合上面的equals方法。

oo::class create Example {
    mixin PropertyEquals
    variable _x _y _z
    constructor {x y z} {
        set _x $x; set _y $y; set _z $z
    }
    method properties {} {
        dict create x $_x y $_y z $_z
    }
}

set a [Example new 1 2 3]
set b [Example new 2 3 4]
set c [Example new 1 2 3]
puts [$a equals $b],[$b equals $c],[$c equals $a]; # 0,0,1

请注意，Tcl不提供像其他语言一样的复杂集合类（因为它具有类似数组和类似映射的开放值），因此不需要对象相等（或内容散列）框架来支持它。

TclOO：对象等于

1 个答案: