HDB表比较

Question

在 Q＆amp; A-style 中发布此问题。

为什么两个相同的表（其中一个从HDB中选择）之间的布尔匹配生成0b而不是1b？

q)trade:trade2:`sym`time xasc ([] sym:5?`apple`google;time:5?.z.t;price:100+5?1.)

q).Q.dpft[`:tmp;.z.d-1;`sym;`trade]
`trade

加载HDB

\l tmp/
q)hist:select from trade where date=.z.d-1
q)hist
date       sym    time         price   
---------------------------------------
2018.04.23 apple  02:31:39.330 100.2392
2018.04.23 apple  04:25:17.604 100.1508
2018.04.23 apple  07:57:14.764 100.2782
2018.04.23 google 02:59:16.636 100.1567
2018.04.23 google 14:35:31.860 100.9785

q)(`date xcols update date:.z.d-1 from trade2)
date       sym    time         price   
---------------------------------------
2018.04.23 apple  02:31:39.330 100.2392
2018.04.23 apple  04:25:17.604 100.1508
2018.04.23 apple  07:57:14.764 100.2782
2018.04.23 google 02:59:16.636 100.1567
2018.04.23 google 14:35:31.860 100.9785

表格比较生成错误（0b）

q)(`date xcols update date:.z.d-1 from trade2)~hist
0b

Answer 1

不匹配是由从HDB中选择的表的sym列（20h）的类型引起的。

\l tmp/
q)hist:select from trade where date=.z.d-1
q)type exec sym from hist
20h
q)type exec sym from trade2
11h
q)type exec value sym from hist
11h

虽然它看起来与符号完全相同，但却有新类型20h，类似于以下(from Kx wiki)

q)type `city$10?city:`london`paris`rome
21h

将value与sym一起使用以获得所需的结果：

q)(`date xcols update date:.z.d-1 from trade2)~update value sym from hist
1b