Question

编辑：在我找到了我真正想要的东西之后，我编辑了我的初步问题，以便更好地描述我最终想要做的事情。

我正在使用UserControl，我希望在其DesignerVerb控件上添加TreeView个属性。我怎样才能做到这一点？有可能吗？

Answer 1

嗯，这是一个简单的例子......

1。如果我们尚未完成，我们应该将参考添加到 System.Design 。转到Reference Manager > Assemblies > Framework并找到System.Design。选中它，然后点击确定。

2。在我们的UserControl代码中，我们确保已经有Imports System.ComponentModel和Imports System.ComponentModel.Design个引用。

3。在我们的UserControl课程中，我们添加Designer属性，为此ControlDesigner指定UserControl。

Imports System.ComponentModel
Imports System.ComponentModel.Design

<Designer(GetType(MyControlDesigner))>
Public Class UserControl1
    'Our UserControl code in here...
End Class

4. 在我们的UserControl课程中，我们创建一个名为“MyControlDesigner”的新课程，该课程将是我们的ControlDesigner。

Public Class MyControlDesigner

End Class

5。现在，让我们创建一个Verb Dock和Undock UserControl ParentForm

Public Class MyControlDesigner
    Inherits System.Windows.Forms.Design.ControlDesigner 'Inherit from ControlDesigner class.

    Private MyVerbs As DesignerVerbCollection

    Public Sub New()

    End Sub

    Public Overrides ReadOnly Property Verbs() As DesignerVerbCollection
        Get
            If MyVerbs Is Nothing Then
                MyVerbs = New DesignerVerbCollection 'A new DesignerVerbCollection to use for our DesignerVerbs.
                MyVerbs.Add(New DesignerVerb("Dock In ParentForm", New EventHandler(AddressOf OnMyCommandLinkClicked))) 'An Event Handler for Docking our UserControl.
                MyVerbs.Add(New DesignerVerb("Undock in ParentForm", New EventHandler(AddressOf OnMyCommandLinkClicked))) 'An Event Handler for Undocking our UserControl.
                MyVerbs(1).Visible = False 'We hide second Verd by default.
            End If
            Return MyVerbs
        End Get
    End Property

    Private Sub OnMyCommandLinkClicked(ByVal sender As Object, ByVal args As EventArgs)
        Dim _UserControl As UserControl1 = CType(Me.Control, UserControl1) 'Reference to our UserControl1 Class, so we can access it's Properties and Methods.
        If _UserControl.Dock = DockStyle.None Then 'If UserControl is Undocked then...
            _UserControl.Dock = DockStyle.Fill 'Dock UserControl in ParentForm.
            MyVerbs(0).Visible = False 'Hide "Dock In ParentForm" DesignerVerb.
            MyVerbs(1).Visible = True 'Show "Undock in ParentForm" DesignerVerb.
        Else
            _UserControl.Dock = DockStyle.None 'Undock UserControl.
            MyVerbs(1).Visible = False 'Hide "Undock in ParentForm" DesignerVerb.
            MyVerbs(0).Visible = True 'Show "Dock in ParentForm" DesignerVerb.
        End If
    End Sub
End Class

6。然后我们构建我们的项目，我们将UserControl添加到我们的测试表单中。

Answer 2

您不一定需要创建自定义设计器来访问WinForm设计环境公开的各种设计器服务。您只需要一个IServiceProvider Interface的实例。所有在其祖先中都有System.ComponentModel.Component的类会公开Site Property。 Site属性是ISite类型的实例，它本身继承自IServiceProvider。

大多数设计服务都是由System.ComponentModel.Design Namespace中记录的接口定义的。像BehaviorService Class这样的其他人被埋没在文档中，必须特别寻找。

使用适当的设计器类的优点在于它可以自动集成到设计模型中并封装该功能。下面显示的技术具有需要知道服务可访问的适当时间的缺点。第一个时间标准是主机设计者已完成加载。这是通过使用主机的IsLoaded属性和LoadComplete事件的组合来实现的。第二个是知道主机何时完成将组件添加到设计图面。网站属性的设置是设计交易的一部分。完成此事务后，可以访问组件的设计器。为此，您使用主持人的TransactionClosed事件。

如上所述，入口点是覆盖继承的Site Property，以便您可以访问服务提供者。此示例获得对设计器主机，其选择服务和控件默认设计器的引用。默认设计器允许您向其Verb集合添加DesignerVerb。

Imports System.ComponentModel
Imports System.ComponentModel.Design

Public Class DemoControl : Inherits Control
    Public Sub New()
        MyBase.New()
        BackColor = Color.Red ' just so we can see it
    End Sub

#Region "Designer Services"
    Private designerHost As Design.IDesignerHost
    Private myDesigner As Design.IDesigner
    Private designerSelectionService As Design.ISelectionService
    Private Shared customDesignerVerb1 As Design.DesignerVerb

    Public Overrides Property Site As ISite
        Get
            Return MyBase.Site
        End Get
        Set(value As ISite)
            MyBase.Site = value
            If value Is Nothing Then ' being removed from the design surface
                DetachDesignerServices()
            Else ' being added to the design surface
                designerHost = CType(value.GetService(GetType(Design.IDesignerHost)), Design.IDesignerHost)
                If designerHost IsNot Nothing Then
                    If designerHost.Loading Then
                        ' the designer has not finished loading, 
                        ' postpone all other connections until it has finished loading
                        AddHandler designerHost.LoadComplete, AddressOf DesignerHostLoaded
                    Else
                        ' designerHost loaded, but is in the in the process of creating this instance
                        If designerHost.InTransaction Then
                            AddHandler designerHost.TransactionClosed, AddressOf DesignerTransactionClosed
                        Else
                            AttachDesignerServices()
                        End If
                    End If
                End If
            End If
        End Set
    End Property

    Private Sub DesignerHostLoaded(sender As Object, e As EventArgs)
        RemoveHandler designerHost.LoadComplete, AddressOf DesignerHostLoaded
        AttachDesignerServices()
    End Sub

    Private Sub DesignerTransactionClosed(sender As Object, e As DesignerTransactionCloseEventArgs)
        RemoveHandler designerHost.TransactionClosed, AddressOf DesignerTransactionClosed
        AttachDesignerServices()
    End Sub

    Private Sub AttachDesignerServices()
        myDesigner = designerHost.GetDesigner(Me)
        If customDesignerVerb1 Is Nothing Then
            customDesignerVerb1 = New Design.DesignerVerb("Verb1", AddressOf DesignerVerb1EventHandler)
        End If
        If myDesigner IsNot Nothing AndAlso
            Not myDesigner.Verbs.Contains(customDesignerVerb1) Then
            myDesigner.Verbs.Add(customDesignerVerb1)
        End If

        designerSelectionService = CType(designerHost.GetService(GetType(Design.ISelectionService)), Design.ISelectionService)
        If designerSelectionService IsNot Nothing Then
            AddHandler designerSelectionService.SelectionChanged, AddressOf DesignerSelectionChanged
        End If
    End Sub

    Private Sub DetachDesignerServices()
        If designerSelectionService IsNot Nothing Then
            RemoveHandler designerSelectionService.SelectionChanged, AddressOf DesignerSelectionChanged
            designerSelectionService = Nothing
        End If
        If designerHost IsNot Nothing Then
            RemoveHandler designerHost.LoadComplete, AddressOf DesignerHostLoaded
            designerHost = Nothing
        End If
        If myDesigner IsNot Nothing Then
            myDesigner = Nothing
        End If
    End Sub

    Private Sub DesignerSelectionChanged(sender As Object, e As EventArgs)
        Static shownCount As Int32
        If designerSelectionService.GetComponentSelected(Me) AndAlso shownCount < 2 Then
            MessageBox.Show("I've been selected." & If(shownCount = 0, "  This will show one more time on selecting.", ""))
            shownCount += 1
        End If
    End Sub

    Private Sub DesignerVerb1EventHandler(sender As Object, e As EventArgs)
        MessageBox.Show("Verb1 Cicked")
    End Sub

#End Region ' "Designer Services

End Class

在UserControl＆＃39的属性上添加DesignerVerb

2 个答案: