Question

我想通过将一些数据写入文本文件并将其保存到USB-Stick来从我的PLC中导出一些数据。我设法创建了文本文件，但我不能写任何东西。

我在以下代码中使用TwinCAT标准库中的函数：

PROGRAM P_WriteFile
VAR
    nStateP         :   INT :=  1;
    fbOpenFile      :   FB_FileOpen;    // open or create file
    fbWriteFile     :   FB_FilePuts;    // write to file
    fbCloseFile     :   FB_FileClose;   // Close file

    sPath           :   STRING  :=  '\Hard Disk2\foobar.txt';    // target path
    sAmsNetID       :   STRING  := '1.23.34.456.1.1';
    sOutput         :   STRING  :=  'foo';

    bDone           :   BOOL;
END_VAR

CASE nStateP OF
1:
// open/create file
    fbOpenFile(sNetId := sAmsNetID, sPathName := sPath, nMode := 2, bExecute := TRUE, tTimeout := INT_TO_TIME(200), bBusy =>, bError => , nErrId =>, hFile => );
    IF fbOpenFile.bBusy THEN
        nStateP :=  2;
    END_IF
2:
    // write to file
    IF NOT fbOpenFile.bError THEN
        fbWriteFile(sNetId := sAmsNetID, hFile := fbOpenFile.hFile, sLine := sOutput, bExecute := TRUE, tTimeout := INT_TO_TIME(200), bBusy =>, bError =>, nErrId =>);
        fbOpenFile(bExecute := FALSE);
    END_IF  
    IF fbWriteFile.bBusy THEN
        nStateP :=  3;
    END_IF

3:
    // Close file
    IF NOT fbWriteFile.bBusy AND NOT fbWriteFile.bError THEN
        fbCloseFile(sNetId := sAmsNetID, hFile := fbOpenFile.hFile, bExecute := TRUE, tTimeout := INT_TO_TIME(200), bBusy =>, bError =>, nErrId =>);
    END_IF

    IF fbWriteFile.bBusy THEN
        nStateP :=  4;
    END_IF

4:
    IF NOT fbCloseFile.bBusy AND NOT fbCloseFile.bError THEN
        bDone   :=  TRUE;
        nStateP :=  1;
    ELSE
        bDone   :=  FALSE;
    END_IF
END_CASE

程序进入所有状态，但结果是一个空文本文件，我无法在控制面板上打开。（“访问\ Hard Disk2 \ foobar.txt时发生共享冲突”）

bBusy - 函数的变量（例如FB_FileOpen.bBusy）也不会变回'FALSE'。

如果有人能帮助我会很棒！谢谢:)）

Answer 1

一般而言： busy-flag告诉你的是功能块当前正忙于执行你请求FB执行的操作。这意味着您不应该在忙碌时更改状态机的状态，反之亦然。您还应该在进行下一步之前检查操作是否成功（通过查看bError-flag）。只要您正在调用的功能块忙（bBusy = true），就可以在bExecute-flag设置为低的情况下调用功能块。我通常做的是将其设置为两个单独的打开阶段，例如：

某种伪代码：

Step1_Open:
  FBOPENFILE(bExecute=TRUE)...
   GOTO STEP2_OPEN

Step2_Open:
  FBOPENFILE(bExecute=FALSE)
  IF NOT FBOPENFILE.bBusy AND NOT FBOPENFILE.bError THEN
     GOTO Step3_StartWrite
  END_IF

Step3_StartWrite
  FBWRITEFILE(bExecute=TRUE)
  GOTO STEP4_WRITEFILE

Step4_Writefile:
  FBWRITEFILEFILE(bExecute=FALSE)
  IF NOT FBWRITEFILEFILE.bBusy AND NOT FBWRITEFILEFILE.bError THEN
     NEXT STEP
  END_IF

......等等......

因此，在您的示例中，您的第2阶段非常关键。在写完成之前，你不应该关闭文件，只要bBusy为假，它就会立即关闭。你基本上做的是在文件仍在编写时关闭文件！此外，您可以删除“fbOpenFile（bExecute：= FALSE）;”在这个阶段，因为只要您（成功）打开文件并拥有文件句柄，就不需要再对该功能块进行任何调用了。

其他想法：

sAmsNetId是您当地的计算机吗？如果它是本地的，我认为你不需要提供它。

我已经编写了自己的文件编写器，我已经使用了很长时间，而且工作正常。它的代码是：

fbRisingEdge(CLK := bExecute);
CASE eFileWriteStep OF
    E_FileWriteStep.IDLE :
        IF fbRisingEdge.Q THEN
            nFileHandle := 0;
            bBusy := TRUE;
            eFileWriteStep := E_FileWriteStep.OPEN;
            nFileWriteSubStep := 0;
        END_IF

    E_FileWriteStep.OPEN :
        CASE nFileWriteSubStep OF
            0 :
                fbFileOpen(sPathName := sPathName, bExecute := FALSE);
                fbFileOpen(sPathName := sPathName, bExecute := TRUE);
                nFileWriteSubStep := nFileWriteSubStep + 1;
            1 :
                fbFileOpen(bExecute := FALSE);
                IF NOT fbFileOpen.bBusy THEN
                    IF fbFileOpen.bError THEN
                        bError := TRUE;
                        eFileWriteStep := E_FileWriteStep.CLEAN;
                        nFileWriteSubStep := 0;
                    ELSE
                        nFileHandle := fbFileOpen.hFile;
                        eFileWriteStep := E_FileWriteStep.WRITE;
                        nFileWriteSubStep := 0;
                    END_IF
                END_IF
            END_CASE

    E_FileWriteStep.WRITE :
        CASE nFileWriteSubStep OF
            0 :
                fbFileWrite(bExecute := FALSE);
                fbFileWrite(hFile := nFileHandle,
                            pWriteBuff := aFileData,
                            cbWriteLen := UDINT_TO_UINT(UPPER_BOUND(aFileData, 1)),
                            bExecute := TRUE);
                nFileWriteSubStep := nFileWriteSubStep + 1;
            1 :
                fbFileWrite(bExecute := FALSE);
                IF NOT fbFileWrite.bBusy THEN
                    IF fbFileWrite.bError THEN
                        bError := TRUE;
                        eFileWriteStep := E_FileWriteStep.CLEAN;
                    ELSE
                        eFileWriteStep := E_FileWriteStep.CLEAN;
                        nBytesWritten := fbFileWrite.cbWrite;
                    END_IF
                nFileWriteSubStep := 0;
                END_IF
        END_CASE

    E_FileWriteStep.CLOSE :
        CASE nFileWriteSubStep OF
            0 :
                fbFileClose(bExecute := FALSE);
                fbFileClose(hFile := nFileHandle, bExecute := TRUE);
                nFileWriteSubStep := 1;
            1 :
                fbFileClose(bExecute := FALSE);
                IF NOT fbFileClose.bBusy THEN
                    IF fbFileClose.bError THEN
                        bError := TRUE;
                    END_IF
                eFileWriteStep := E_FileWriteStep.CLEAN;
                nFileHandle := 0;
                nFileWriteSubStep := 0;
                END_IF
        END_CASE

    E_FileWriteStep.CLEAN :
        IF nFileHandle <> 0 THEN
            eFileWriteStep := E_FileWriteStep.CLOSE;
            nFileWriteSubStep := 0;
        ELSE
            eFileWriteStep := E_FileWriteStep.IDLE;
            bBusy := FALSE;
        END_IF
END_CASE

您可以通过开头的上升沿激活功能块。要写入的数据由字节数组（aFileData）提供。在此状态机的末尾，您还有一些清洁代码以及最终的错误处理。在此代码中，您还可以看到我在继续下一步之前如何确保上一步成功。

祝你好运！

Answer 2

程序中的主要问题是您只调用一次功能块，就好像它们是正常功能一样。您必须连续调用功能块，并检查它们何时完成其特定功能在连续调用它们时，应首先等待Busy标志变为高电平然后等待它变低（并且没有错误）。如果您有等待状态的状态并在两个状态中调用功能块，这将是最简单的请记住，这些文件操作功能块与Windows系统一起工作，可能需要一些时间才能完成工作。

顺便说一下，如果你添加一个＆＃39; NOT fbOpenFile.bBusy＆＃39;你的代码示例可能真的有效。状态2中第一个IF的标准。但是如果你使用两个状态来启动和完成每个FB，程序将更容易阅读/调试。

TwinCAT 3：写入档案

2 个答案: