我必须在汇编(3*a-b/a)*(d+3)中执行此等式，并且我有问题除以b / a（10/20），结果应为0.5但我得到0.我真的不知道我是怎么做的能做到这。我的任务是修复这个给定代码中的语法和逻辑错误：
;=============================================================================;
; ;
; File : arch1-2e.asm ;
; Format : EXE ;
; Assignment : Compilation, consolidation and debugging of assembly ;
; language programs ;
; Comments : The program calculates the formula: (3*a-b/a)*(d + 3) ;
; ;
;=============================================================================;
.MODEL: SMAL
Stos SEG
a DB 20
b = 10
c EQU 3
Wynik DB ?
ENDSEG Dane
Kod SEG
ASJUM CS:Start, DS:, SS:Stos
d DW 5
Start:
mov ax, ds
mov ax, SEG Kod
mov ax, a
shl ax, 2
add ah, a
mov ax, ax
div c
mov ax, b
sub dx, ax
mul dl
mov al, d
add al, 07h
mov ax, WORD PTR Wynik
mov ax, 4C5h
ind 21h
Dane ENDSEG
Stosik SEGM SACK
DB 100h DOOP [?]
Kod ENDSEG
END Stop
我修复此代码的尝试是：
.MODEL SMALL
a EQU 20
b EQU 10
c EQU 3
d EQU 5
Dane SEGMENT
Wynik DB ?
Dane Ends
Kod SEGMENT
ASSUME CS:Kod, DS:Dane, SS:Stosik
start:
mov ax,a
mov bx,c
mul bx
XOR bx,bx
mov cx,ax
XOR ax,ax
mov ax,b
mov bx,a
div bx
sub cx,ax
XOR ax,ax
mov dx,cx
XOR cx,cx
mov ax,d
add ax,c
MUL dx
mov ax, 4C00h
int 21h
Kod ENDS
Stosik SEGMENT STACK
DB 100h DUP (?)
Stosik ENDS
END start
答案 0 :(得分：1)
没有与我认为代码的意图相差甚远，而且我对所要求的内容的解释会提出如下建议：
.MODEL SMALL ; I Assume we are producing EXE program
c EQU 3 ; 3 is a constant in the equation
Dane SEGMENT 'DATA'
a DW 20 ; a, b, d are variables in the equation
b DW 10 ; so treat them as variables
d DW 5 ; All these variables should be DW
Wynik DW ?
Dane ENDS
Kod SEGMENT 'CODE'
ASSUME CS:Kod, DS:Dane, SS:Stosik
Start:
mov ax, SEG Dane ; For EXE we need to set DS
mov ds, ax ; To Dane segment manually
mov ax, a ; Multiplying a by 3 is the same
; as multiplying a by 2 and adding a
shl ax, 1 ; Multiply a*2
add ax, a ; Add a to previous result in a
mov cx, ax ; Copy result of a*3 to CX
mov ax, b ; Do div b/a
xor dx, dx ; We need to ensure DX is zerofor this div
; as Div is result of DX:AX by a
div a
sub cx, ax ; Subtract reslt of b/a from result of a*3
mov ax, d ; ax = d + 3
add ax, c
mul cx ; Multiple d+3 (AX) by a*3-b/a (cx)
mov Wynik, ax ; Save 16-bit result in memory
mov ax, 4C05h ; Exit with value 5
int 21h
Kod ENDS
Stosik SEGMENT STACK
DB 100h DUP (?)
Stosik ENDS
END
该程序始终坚持修复语法和逻辑错误的原始精神。 b / a仍在使用整数除法（你必须向你的TA或教授询问），这会将结果舍入到最接近的整数（如果10/20是0）。此代码中的主要问题是：
div是DX：AX的一个16位值，所以我们需要将DX归零。如果教授需要通过仍然使用整数除法来更好地逼近结果，那么Jester关于将等式重新排列为3 * a *（d + 3） - （b *（d + 3））/ a的建议是好的。这将除法推迟到整数除法的舍入对结果影响较小的点，因此最终结果应该几乎偏离1.使用此修订方程的代码看起来像：
mov ax, SEG Dane ; For EXE we need to set DS
mov ds, ax ; To Dane segment manually
mov cx, a
shl cx, 1
add cx, a ; cx = 2*a+a = a*3
mov ax, d
add ax, c ; ax = d+c = d+3
mov bx, ax ; bx = copy of d+3
mul cx
mov si, ax ; si = a*3*(d+3)
mov ax, bx
mul b ; ax = b*(d+3)
xor dx, dx ; Avoid division overflow, set DX=0
div a ; ax = b*(d+3)/a
sub si, ax ; si = a*3*(d+3) - b*(d+3)/a
mov Wynik, si ; Save 16-bit result in memory
这种变化可以略微改善。当整数除法产生结果时，它会向下舍入到最接近的整数。如果你除以99/100，你将得到0 div和余数99.答案更接近1而不是0.通常你会在某些事情是＆gt; = .5并且向下舍入时向上舍入。 .5。如果需要，可以使用来自div的余数（DX）将最终结果调高1或保持结果不变。修改后的代码可能如下所示：
mov ax, SEG Dane ; For EXE we need to set DS
mov ds, ax ; To Dane segment manually
mov cx, a
shl cx, 1
add cx, a ; cx = a*3
mov ax, d
add ax, c ; ax = d+c = d+3
mov bx, ax ; bx = copy of d+3
mul cx
mov si, ax ; si = a*3*(d+3)
mov ax, bx
mul b ; ax = b*(d+3)
xor dx, dx ; Avoid division overflow, set DX=0
div a ; ax = b*(d+3)/a
shl dx, 1 ; Remainder(DX) = Remainder(DX) * 2
cmp dx, a ; Ajustment of whole nuber needed?
jb .noadjust ; No? Then skip adjust
add ax, 1 ; Else we add 1 to quotient
.noadjust:
sub si, ax ; si = a*3*(d+3) - b*(d+3)/a
mov Wynik, si ; Save 16-bit result in memory
mov ax, 4C05h ; Exit with value 5
int 21h
调整基于Rounding Half Up中的方法。基本上如果余数（DX）乘以2小于除数a则不需要调整，否则商（AX）需要增加1
第一个版本的结果将是480.第二个版本的结果是476.第二个版本的结果将更接近预期值。在这种情况下，476的结果恰好是准确的。 （3 * 20-10 / 20）*（5 + 3）= 59.5 * 8 = 476。