Question

所以我一直在尝试学习CMake并将其与C ++一起使用。我想创建一个在Windows上使用 Direct3D 12 的便携式游戏引擎。

目前，我的项目有以下CMakeLists.txt：

cmake_minimum_required(VERSION 3.0 FATAL_ERROR)

project(PsychoEngineCore)

set(SRCS_CXX ${CMAKE_CURRENT_LIST_DIR})

include(${CMAKE_CURRENT_SOURCE_DIR}/src/dir_src.cmake)

set(LIB_TYPE "STATIC" CACHE STRING "Static or Dynamic Linking")

if(${CMAKE_CXX_COMPILER_ID} STREQUAL GNU OR
${CMAKE_CXX_COMPILER_ID} STREQUAL Clang)
    set(warnings "-Wall -Wextra -Werror")
elseif(${CMAKE_CXX_COMPILER_ID} STREQUAL MSVC)
    set(warnings "/W4 /WX /EHsc")
endif()

if(NOT CONFIGURED_ONCE)
    set(CMAKE_CXX_FLAGS "${warnings}"
        CACHE STRING "Flags used by the compiler during all build types." FORCE)
endif()

include_directories(${CMAKE_CURRENT_SOURCE_DIR}/include)

# Do we want static libraries?
# When STATIC_LINKING is TRUE, then cmake looks for binaries ending in ".a".
# THIS IS FOR LINUX ONLY!
if(LIB_TYPE EQUAL STATIC)
    if (UNIX AND NOT APPLE)
        set(CMAKE_FIND_LIBRARY_SUFFIXES(".a"))
    endif(UNIX AND NOT APPLE)

    set(CMAKE_EXE_LINKER_FLAGS "-static")
    set_target_properties(surface PROPERTIES LINK_SEARCH_END_STATIC 1)
endif(LIB_TYPE EQUAL STATIC)

include_directories(${CMAKE_CURRENT_SOURCE_DIR}/include)
include(GenerateExportHeader)
add_library(${PROJECT_NAME} ${LIB_TYPE} ${SRCS_CXX})
GENERATE_EXPORT_HEADER(
    ${PROJECT_NAME}
    EXPORT_MACRO_NAME PE_API
    EXPORT_FILE_NAME ${CMAKE_CURRENT_SOURCE_DIR}/include/Engine/API/${PROJECT_NAME}Export.hpp
    DEPRECATED_MACRO_NAME PE_API_DEP
    STATIC_DEFINE PE_STATIC
)

目前我的d3d12.lib文件位于以下位置：

C:\Program Files (x86)\Windows Kits\10\Libs\10.0.16299.0\um\x64

有没有办法让路径保持动态，如果所说的系统上有更新的版本，最好是“更新”？

谢谢！

Answer 1

将我的评论转化为答案

一般来说，只需添加一个

target_link_libraries((${PROJECT_NAME} d3d12.lib)

Windows SDK（其中the Direct3D SDK is now part of）位于标准搜索路径中，例如库的链接器。因此，MSVC编译器和链接器会自动找到它。

我并不认为自动升级到更新（但未知）的API版本是一个好主意。您正在为特定的API版本编写程序。

工作示例

这是一个最小的工作示例（经过测试的VS2017 15.5.5，CMake 3.9.0）：

cmake_minimum_required(VERSION 3.0)

project(Direct3DExample)

find_package(Git REQUIRED)

set(_path "${CMAKE_BINARY_DIR}/DirectX-Graphics-Samples/Samples/Desktop/D3D12HelloWorld/src/HelloTriangle")
if (NOT EXISTS "${_path}")
    execute_process(
        COMMAND "${GIT_EXECUTABLE}" clone https://github.com/Microsoft/DirectX-Graphics-Samples.git
    )
endif()

file(GLOB _files "${_path}/*")
list(APPEND _shader ${_files})
list(FILTER _files EXCLUDE REGEX "\\.vcxproj|\\.hlsl")
list(FILTER _shader INCLUDE REGEX "\\.hlsl")

get_filename_component(_name "${_path}" NAME)

add_executable(${_name} WIN32 ${_files})
target_compile_definitions(${_name} PRIVATE "UNICODE" "_UNICODE")
target_link_libraries(${_name} PRIVATE "d3d12.lib" "dxgi.lib" "d3dcompiler.lib")

add_custom_command(
    TARGET ${_name}
    POST_BUILD
    COMMAND "${CMAKE_COMMAND}" -E copy ${_shader} $<TARGET_FILE_DIR:${_name}>
)

如果您需要更多（编译器/链接器没有自动找到Windows SDK），您可能需要查看以下find_package()配置代码：

https://github.com/Microsoft/DirectXShaderCompiler/blob/master/cmake/modules/FindD3D12.cmake

使用CMake查找Direct3D 12

1 个答案: