Question

背景：我的工作地点有一个默认的RichText电子邮件格式。很多人都在为他们的电子邮件添加图片。带图像的RichText电子邮件比带有图像的HTML电子邮件要大得多。

我可以手动打开，编辑，更改格式为HTML，并保存以大大减少电子邮件的大小。转换过程中会保留格式。

但是，当我使用VBA打开邮件项目，更改格式并保存时，电子邮件不会被转换。

如何使用vba将一组Richtext电子邮件更改为格式正确的html电子邮件，实现与使用功能区手动编辑和保存相同的结果？

下面是我的示例代码，我可以看到运行此行的代码：

myMailItem.BodyFormat = olFormatHTML

的转换方式与功能区转换的方式不同。

Public Sub myConvertHTML()

    Dim mySelectedItems As Selection
    Dim myMailItem As MailItem
    Dim myRichText As String
    Dim myHtmlText As String


    ' Set reference to the Selection.
    Set mySelectedItems = ActiveExplorer.Selection

    ' Loop through each item in the selection.
    For Each myMailItem In mySelectedItems

        'if the current format is RichText proceed
        If myMailItem.BodyFormat = olFormatRichText Then

            myMailItem.Display

            'this line does not convert the RichText to Html properly
            'it seems to convert the images into an attached file ATT#### that is an ole object
            'instead of converting the image and using it in html format
            'when using the Ribbon and changing the format to HTML,
            'the email is converted and formatting maintained
            myMailItem.BodyFormat = olFormatHTML

            myMailItem.Save
            myMailItem.Close olSave


        Else
            MsgBox "Already in RichText Format: " & myMailItem.Subject, vbInformation

        End If

    Next

    MsgBox "All Done. Email converted to HTML.", vbOKOnly, "Message"

    Set mySelectedItems = Nothing
    Set myMailItem = Nothing

End Sub

我尝试从VBA内部操作功能区，但我无法弄清楚如何调用Ribbon元素

(Format Text/Format/HTML).

任何建议都表示赞赏。

感谢Niton，这是我最终的解决方案。

Public Sub myConvertHTML002()
'takes selected list of items in Outlook and converts all mailItems that are RichText into HTML Format

    Dim mySelectedObjects As Selection
    Dim myObject As Object
    Dim myMailItem As MailItem

    Dim objItem As Object

    ' Set reference to the Selection.
    Set mySelectedObjects = ActiveExplorer.Selection

    ' Loop through each item in the selection.
    For Each myObject In mySelectedObjects

        If myObject.Class = olMail Then

            Set myMailItem = myObject

            'if the current format is RichText proceed
            If myMailItem.BodyFormat = olFormatRichText Then

                'have to display the email so we can use the command bars
                myMailItem.Display

                'special code because we can't change the format of the item from within the item
                'we have to use the ActiveInspector
                On Error Resume Next
                Set objItem = ActiveInspector.CurrentItem
                On Error GoTo 0

                If Not objItem Is Nothing Then
                    If objItem.Class = olMail Then
                        ActiveInspector.CommandBars.ExecuteMso ("EditMessage")
                        ActiveInspector.CommandBars.ExecuteMso ("MessageFormatHtml")
                    End If
                End If

                myMailItem.Close olSave

            Else

                'MsgBox "Already in RichText Format: " & myMailItem.Subject, vbInformation

            End If

        End If

    Next

    MsgBox "All Done. Email converted to HTML.", vbOKOnly, "Message"

    Set mySelectedItems = Nothing
    Set myMailItem = Nothing

End Sub

Answer 1

您可以单击带有ExecuteMso的按钮。

CommandBars.ExecuteMso Method“适用于内置按钮的控件......”

Sub ChangeToHTML()
Dim objItem As Object
Dim objMail As mailitem

On Error Resume Next
Set objItem = ActiveInspector.currentItem
On Error GoTo 0

If Not objItem Is Nothing Then
    If objItem.Class = olMail Then
        ActiveInspector.CommandBars.ExecuteMso ("MessageFormatHtml")
    End If
End If

End Sub

当您为快速访问工具栏或功能区添加内置按钮时将鼠标悬停在选区上时，您可以看到MessageFormatHtml（IdMso）作为文本的最后一位。

如何将选择的电子邮件从RichText转换为HTML格式？

1 个答案: