Question

我正在尝试生成内联javascript，但我必须使用cl-who将parenscript代码放在(:script)和(str)标记内。 ps，ps*，ps-inline和ps-inline*似乎对生成的js没有太大影响。

是编写宏以避免代码重复的常用方法，还是有更好的方法？

这是我的计划：

(in-package #:ps-test)

(defmacro standard-page ((&key title) &body body)
  `(with-html-output-to-string (*standard-output* nil :prologue t :indent t)
     (:html 
      :lang "en"
      (:head 
       (:meta :http-equiv "Content-Type" 
          :content    "text/html;charset=utf-8")
       (:title ,title)
           (:link :type "text/css" 
              :rel "stylesheet"
              :href "/style.css"))
      (:body 
       ,@body))))     

(defun main ()
  (with-html-output (*standard-output* nil :indent t :prologue nil)
    (standard-page (:title "Parenscript test")
      (:div (str "Hello worldzors"))
        (:script :type "text/javascript"
             (str (ps (alert "Hello world as well")))))))

(define-easy-handler (docroot :uri "/") ()
  (main))

(defun start-ps-test ()
  (setf (html-mode) :html5)
  (setf *js-string-delimiter* #\")
  (start (make-instance 'hunchentoot:easy-acceptor :port 8080)))

(defun stop-ps-test ()
  (stop *server*))

(defvar *server* (start-ps-test))

Answer 1

在这个用例中，宏很好。诀窍是宏以特定顺序扩展。说你定义一个js宏：当宏扩展遇到 with-html-output，对您的宏(js (alert "Ho Ho Ho"))的内部调用看起来像一个函数调用，并在生成时保持原样码。如果您的js宏然后扩展为(:script ...)，那么系统会抱怨:script是一个未知函数（假设您并没有真正命名这样的功能）。你应该发射一个用(who:htm ...)表达式括起来解释代码 CL-WHO的代码助行器。

(defmacro js (code)
  `(who:htm
     (:script :type "text/javascript" (who:str (ps:ps ,code)))))

这仅适用于封闭with-html-output。

的上下文

对于内联Javascript，您不希望在其周围添加<script>标记，你通常可以简单地使用ps-inline：

(who:with-html-output (*standard-output*)
  (:a :href (ps:ps-inline (void 0))
    "A link where the usual HREF behavior is canceled."))

;; prints:
;; 
;; <a href='javascript:void(0)'>A link where the usual HREF behavior is canceled.</a>

但如果您经常做同样的事情，请随意使用宏：

(defmacro link (&body body)
  `(who:htm (:a :href #.(ps:ps-inline (void 0)) ,@body)))

(who:with-html-output (*standard-output*) (link "Link"))

;; prints:
;;
;; <a href='javascript:void(0)'>Link</a>

使用cl-who，parenscript和hunchentoot生成内联javascript

1 个答案: