读取变量的正确输入

Question

我希望有一个包含integer的变量，它来自用户的输入。它不能接受字符串既不是十进制数字。

我想帮助了解我在这里做错了什么。

我的代码到现在为止：

我很感激帮助。

(format t "~%Enter a number: ")
(loop (defvar numb (read))
(cond (((rationalp numb)1)
        (print "No decimal numbers are allowed, please enter an integer"))
      (((stringp numb)1)
        (print "No strings are allowed, please enter an integer"))
)
(when ((integerp numb)1) (return numb))
)

Answer 1

工作代码

我将如何做到这一点：

(defun ask-and-read (prompt)
  "Prompt the user and read his input."
  (princ prompt *query-io*)
  (force-output *query-io*)  ; flush the buffers
  (let ((*read-eval* nil))   ; close the security hole
    (read *query-io*)))

(defun request-object (prompt predicate)
  "Ask the user for an object using prompt.
Only accept data which satisfies the predicate."
  (loop
    for object = (ask-and-read prompt)
    when (funcall predicate object)
    return object
    do (format *query-io* "Alas, ~S (~S) does not satisfy ~S, please try again~%"
               object (type-of object) predicate)))

示例：

> (request-object "Enter an integer: " #'integerp)
Enter an integer: 4.6
Alas, 4.6 (SINGLE-FLOAT) does not satisfy #<SYSTEM-FUNCTION INTEGERP>, please try again
Enter an integer: 5/7
Alas, 5/7 (RATIO) does not satisfy #<SYSTEM-FUNCTION INTEGERP>, please try again
Enter an integer: asdf
Alas, ASDF (SYMBOL) does not satisfy #<SYSTEM-FUNCTION INTEGERP>, please try again
Enter an integer: 7
==> 7
> (request-object "Enter a real: " #'realp)
Enter a real: 4.5
==> 4.5
> (request-object "Enter a real: " #'realp)
Enter a real: 5/8
==> 5/8
> (request-object "Enter a real: " #'realp)
Enter a real: "sdf"
Alas, "sdf" ((SIMPLE-BASE-STRING 3)) does not satisfy #<SYSTEM-FUNCTION REALP>, please try again
Enter a real: 8
==> 8

请参阅我使用的设施的文档：

• princ
• force-output
• *query-io*
• read
• *read-eval*
• loop：
  • for
  • when
  • return
  • do
• format

你的错误

代码格式

您的代码无法读取，因为您的缩进不正确。 Lispers不计算parens - 这是编译器和编辑的工作。 我们看一下缩进。 请帮个忙，并使用Emacs - 它会为您缩进代码，您经常会自己看错。

Defvar是顶级形式

首先，defvar是一个顶级表单，用于定义全局变量，而不是设置它们。 后续调用不更改值：

(defvar *abc* 1)
*abc*
==> 1
(defvar *abc* 10)
*abc*
==> 1   ; not 10!

使用setq设置变量。

首选局部变量为全局变量

虽然Lisp确实允许全局变量，但主要的编程 Lisp中的style是功能风格：每个函数都接收它 “输入”数据作为参数，并将其“输出”数据作为值返回。 要实现功能样式，首选本地变量到全局变量。 您可以通过let or let*创建局部变量，或者在loop中查看 Local Variable Initializations

Cond和何时有非常具体的语法

您的cond和when表单中有额外的parens和1（？！）。

请记住，parens are meaningful in Lisp。

安全第一！

将*read-eval*绑定到nil 在需要read之前 如果用户输入#.(launch-nuclear-missiles)，请避免核战争 响应您的提示，因为通常read会评估任何内容 在#.之后。