Question

我试图在调试x86-16 dosbox汇编程序中做一个fibonnachi序列但是我遇到了麻烦，我一直得到这个奇怪的打印输出：

我试图一点一点地分解它，但这是我到目前为止所拥有的

mov cx, 15
mov al, 01
mov bl, 00
cmp cl, 1
je  010B     ;next line with mov ah, 2
mov ah, 2
int 21
inc cl
cmp cl,2
je  0115     ;next line with mov ah, 2
mov ah, 2
int 21
inc cl
add al, bl
mov bl, al
mov cl, bl
mov ah,2
int 21
loop (inc cl line)
rcx 
4A
w
q

我不确定它是否正确但它应该打印斐波纳契序列中的前20个数字，如果可以的话请帮助

编辑：我用

打印01

mov cx, 15
dec cx
mov al, 30
mov bl, 31
mov cl, 31
cmp cl, 31
je 010F
mov dl, al
mov ah, 2
int 21
dec cx
inc cl
cmp cl, 32
je 011c
mov dl, bl
mov ah, 2
dec cx
inc cl
int 21
int 20

现在我只需要ax = bl + al，al = bl，bl = ax，对于如何做到这一点有什么想法？

Answer 1

INT 21h, AH = 02h应该向标准输出输出一个字节，其中该字节将在DL寄存器中传递。您的代码甚至从未初始化DL，因此输出垃圾并不奇怪。

你还有其他一些问题。如果你想要可读输出，你必须进行二进制到十进制转换，然后转换为ASCII;你的代码似乎甚至没有尝试这样做。此外，您在8位AL，BL寄存器中进行所有算术运算，但第20个Fibonacci数大于8位，因此在某些时候它会溢出而您将无法得到正确的答案。

最后，如果你想用汇编语言编写一个真正的程序，那么DEBUG是一种非常不方便的方法。它已经有近40年的历史了。获得真正的文本编辑器和真正的汇编器，以及真正的调试器。

Answer 2

现在我只需要ax = bl + al，al = bl，bl = ax，对于如何做到这一点有什么想法？

对于al = bl和bl = al，您可以使用交换指令：

        xchg    al,bl

除了你需要使用16位寄存器才能达到fib（24）（46368），所以这将是：

        add     ax,bx
        xchg    ax,bx

或者，你可以先做xchg。

        xchg    ax,bx
        add     ax,bx

你需要使用ax以外的寄存器，因为需要将二进制转换为十进制和int 21调用。

如果你还没有这样做，你可以使用debug.com作为原始汇编程序，重定向其输入以从文本文件中读取它的命令。命令将输入指令和数据，然后使用“n”给出要写入的程序的名称，“rcx”将cx设置为要写入的字节数，然后使用“w”命令写入程序。 “q”退出调试。

这使您可以编辑文本文件，直到程序生效，而不是直接使用debug输入命令。以下是Fibonacci程序的示例输入文件，名为fib16.in：

a100
sub  sp,+10
mov  bp,sp
mov  byte ptr [bp+05],0d
mov  byte ptr [bp+06],0a
mov  byte ptr [bp+07],24
mov  di,ffff
mov  si,0001
mov  cx,0019
mov  bx,000a
xchg si,di
add  si,di
mov  bp,sp
add  bp,+05
mov  ax,si
dec  bp
xor  dx,dx
div  bx
or   dl,30
mov  [bp+00],dl
cmp  bp,sp
jnz  0128
mov  ah,09
mov  dx,sp
int  21
loop 011d
add  sp,+10
mov  ax,4c00
int  21

nfib16.com
rcx
47
w
q

要“汇编”此文件，请输入命令：

debug <fib16.in

这将创建一个名为fib16.com的程序，然后您可以使用或不使用debug运行。

以下是同一程序的常规程序集版本：

;       Fibonacci
        .model  tiny,c
        .code
        org     0100h
main    proc    far
        sub     sp,16                   ;allocate space for string
        mov     bp,sp
        mov     byte ptr 5[bp],00dh     ;bp[5] = 00d,00a,'$'
        mov     byte ptr 6[bp],00ah
        mov     byte ptr 7[bp],024h
        mov     di,0ffffh               ;fib(-2)
        mov     si,00001h               ;fib(-1)
        mov     cx,25                   ;loop: fib(0) to fib(24)
        mov     bx,10                   ;used to convert to string
main0:  xchg    si,di                   ;fib step
        add     si,di
        mov     bp,sp                   ;display si
        add     bp,5
        mov     ax,si
main1:  dec     bp
        xor     dx,dx
        div     bx
        or      dl,030h
        mov     [bp],dl
        cmp     bp,sp
        jne     main1
        mov     ah,009h
        mov     dx,sp
        int     21h
        loop    main0                   ;loop till done
        add     sp,16                   ;restore sp
        mov     ax,04c00h               ;exit
        int     21h
main    endp
        end     main

斐波那契x86-16汇编

2 个答案: