Question

我需要比较两个 TStream 后代是否具有相同的内容。对我来说唯一有趣的结果是布尔值是/否。

我要编写一个简单循环来检查流内容的字节后的字节。

但我好奇知道是否有现有的功能。我没有在DelphiXE或JCL / JVCL库中找到任何内容。

当然，这两个流的大小相同！

Answer 1

正如Nickolay O.所说，你应该用块读取你的流并使用CompareMem。这是一个例子（包括尺寸测试）......

function IsIdenticalStreams(Source, Destination: TStream): boolean;
const Block_Size = 4096;

var Buffer_1: array[0..Block_Size-1] of byte;
    Buffer_2: array[0..Block_Size-1] of byte;
    Buffer_Length: integer;

begin
  Result := False;

  if Source.Size <> Destination.Size then
    Exit;

  while Source.Position < Source.Size do
    begin
      Buffer_Length := Source.Read(Buffer_1, Block_Size);
      Destination.Read(Buffer_2, Block_Size);

      if not CompareMem(@Buffer_1, @Buffer_2, Buffer_Length) then
        Exit;
    end;

  Result := True;
end;

Answer 2

daemon_x发布的 IsIdenticalStreams 功能非常出色 - 但需要一次调整才能正常工作。（Uwe Raabe已经发现了这个问题。）在启动循环之前重置流位置至关重要< - >如果在此函数之外已经访问过两个流，则此过程可能会返回错误的TRUE。

这是每次都有效的最终解决方案。我刚刚重命名该函数以适合我的命名约定。感谢daemon_x提供优雅的解决方案。

function StreamsAreIdentical(Stream1, Stream2: TStream): boolean; const Block_Size = 4096; var Buffer_1: array[0..Block_Size-1] of byte; Buffer_2: array[0..Block_Size-1] of byte; Buffer_Length: integer; begin Result := False; if Stream1.Size <> Stream2.Size then exit; // These two added lines are critical for proper operation Stream1.Position := 0; Stream2.Position := 0; while Stream1.Position < Stream1.Size do begin Buffer_Length := Stream1.Read(Buffer_1, Block_Size); Stream2.Read(Buffer_2, Block_Size); if not CompareMem(@Buffer_1, @Buffer_2, Buffer_Length) then exit; end; Result := True; end;

Answer 3

没有这样的内置功能。我只能推荐一件事 - 不是逐字节读取，而是使用16-64字节的块，这样会快得多。

Answer 4

user532231 和 Mike 的答案在99％的情况下有效，但需要进行其他检查！

TStream的后代几乎可以是任何东西，所以不能保证Stream.Read会返回相同数量的数据，即使流的长度相同（流后代也可以下载数据，所以可能会返回readed = 0字节，同时等待下一个块）。流也可以在完全不同的媒体上，并且流读取错误可能只发生在一个上。

对于100％工作代码，应进行所有这些检查。我修改了Mike的功能。

如果此函数用于重写流2（如果与Stream1不相同），则应检查所有错误。当函数结果为True时，everthing是可以的，但是如果它是False，那么检查Streams是否实际上是不同的或者只是发生了一些错误是非常聪明的。

编辑：添加了一些额外的检查，基于StreamsAreIdentical和使用示例的FilesAreIdentical函数。

// Usage example

var lError: Integer;
...
 if FilesAreIdentical(lError, 'file1.ext', 'file2.ext')
    then Memo1.Lines.Append('Files are identical.')
    else case lError of
           0: Memo1.Lines.Append('Files are NOT identical!');
           1: Memo1.Lines.Append('Files opened, stream read exception raised!');
           2: Memo1.Lines.Append('File does not exist!');
           3: Memo1.Lines.Append('File open exception raised!');
         end; // case
...

// StreamAreIdentical

function StreamsAreIdentical(var aError: Integer;
                             const aStream1, aStream2: TStream;
                             const aBlockSize: Integer = 4096): Boolean;

var
  lBuffer1: array of byte;
  lBuffer2: array of byte;
  lBuffer1Readed,
  lBuffer2Readed,
  lBlockSize: integer;

begin
  Result:=False;
  aError:=0;
  try
    if aStream1.Size <> aStream2.Size
       then Exit;

    aStream1.Position:=0;
    aStream2.Position:=0;

    if aBlockSize>0
       then lBlockSize:=aBlockSize
       else lBlockSize:=4096;

    SetLength(lBuffer1, lBlockSize);
    SetLength(lBuffer2, lBlockSize);

    lBuffer1Readed:=1; // just for entering while

    while (lBuffer1Readed > 0) and (aStream1.Position < aStream1.Size) do
    begin
      lBuffer1Readed := aStream1.Read(lBuffer1[0], lBlockSize);
      lBuffer2Readed := aStream2.Read(lBuffer2[0], lBlockSize);

      if (lBuffer1Readed <> lBuffer2Readed) or ((lBuffer1Readed <> lBlockSize) and (aStream1.Position < aStream1.Size))
         then Exit;

      if not CompareMem(@lBuffer1[0], @lBuffer2[0], lBuffer1Readed)
         then Exit;
    end; // while

    Result:=True;
  except
    aError:=1; // stream read exception
  end;
end;


// FilesAreIdentical using function StreamsAreIdentical

function FilesAreIdentical(var aError: Integer;
                           const aFileName1, aFileName2: String;
                           const aBlockSize: Integer = 4096): Boolean;

var lFileStream1,
    lFilestream2: TFileStream;

begin
 Result:=False;
 try
   if not (FileExists(aFileName1) and FileExists(aFileName2))
      then begin
        aError:=2; // file not found
        Exit;
      end;

   lFileStream1:=nil;
   lFileStream2:=nil;
   try
     lFileStream1:=TfileStream.Create(aFileName1, fmOpenRead or fmShareDenyNone);
     lFileStream2:=TFileStream.Create(aFileName2, fmOpenRead or fmShareDenyNone);
     result:=StreamsAreIdentical(aError, lFileStream1, lFileStream2, aBlockSize);
   finally
     if lFileStream2<>nil
        then lFileStream2.Free;

     if lFileStream1<>nil
        then lFileStream1.Free;
   end; // finally
 except
   aError:=3; // file open exception
 end; // except
end;

Delphi函数比较两个TStream的内容？

4 个答案: