Question

这是我的档案。

NAME|NUM|ADDR|AGE
abcd|02|abc|cd|12
jake|04|xy|zzb|12
 lau|92||xcx| 56

我想要的输出必须像这样

 NAME|NUM|ADDR|AGE
 abcd|02|abc#cd|12
 jake|04|xy#zzb|18 
  lau|92|#xcx| 56

我的文件有4个字段，第3个col在字符之间有一个管道分隔符，如＆＃34; ice | cream＆＃34;，我的要求是替换|第3个字段中的任何值，如（＃，*或任何其他）。由于这是管道分隔文件，我无法专门替换该文件的特定部分。任何帮助对我都非常有用..谢谢

Answer 1

awk 解决方案：

awk -F'|' 'NR==1;NR>1 && NF>4{ print $1,$2,$3"#"$4,$5 }' OFS='|' file

NR==1; - 按原样打印第一条记录
NR>1 && NF>4 - 检查记录是否包含过多字段
$3"#"$4 - 使用新的#

输出：

NAME|NUM|ADDR|AGE
abcd|02|abc#cd|12
jake|04|xy#zzb|12
 lau|92|#xcx| 56

Answer 2

或者如果你想要一个更传统的基于逻辑的解决方案，（并且无可否认地长得痛苦; - /）这里是另一个解决方案

awk -F\| 'BEGIN{OFS="|"}
  {
    #dbg print "#dbg:NF="NF;

    # if this record has an extra character
    if (NF>4){
      # loop over all fields
      for(i=1;i<=NF;i++){
        # if not the field of interest or last field on line, just print it
        if(i!=3 && i!=NF){
          printf("%s|",$i)
        }
        # else this is the problem field, add the # char
        else if (i==3){
          printf $3"#"
        }
        # else if last field on line, add LF char at end
        else if (i==NF){
          printf ("%s\n",$i)
       }
      }
    }
    # record has correct number of FS chars
    else {
      print $0
    }
  }' dat.txt

<强>输出

NAME|NUM|ADDR|AGE
abcd|02|abc#cd|12
jake|04|xy#zzb|12
 lau|92|#xcx| 56

我已经在代码中添加了注释来解释发生了什么。

这是一个非常重要的单行; - ＆gt;

awk -F\| '{if (NF>4){for(i=1;i<=NF;i++){if(i!=3 && i!=NF){printf("%s|",$i)}else if(i==3){printf $3"#"}else if(i==NF){printf ("%s\n",$i)}}}else{print $0}}' dat.txt

IHTH

Answer 3

只需将n设置为您希望与其后的字段合并的字段数：

$ cat tst.awk
BEGIN { FS=OFS="|" }
NR==1 { print; next }
{
    for (i=1;i<=NF;i++) {
        sep = (i==n ? "#" : OFS)
        printf "%s%s", $i, (i<NF ? sep : ORS)
    }
}

$ awk -v n=3 -f tst.awk file
NAME|NUM|ADDR|AGE
abcd|02|abc#cd|12
jake|04|xy#zzb|12
 lau|92|#xcx| 56

$ awk -v n=2 -f tst.awk file
NAME|NUM|ADDR|AGE
abcd|02#abc|cd|12
jake|04#xy|zzb|12
 lau|92#|xcx| 56

替换|具有管道分隔文件中的值的记录之间的字符

3 个答案: