Question

我有这个插入标记：

<cfquery name="aoi_results" datasource="buyerhero"  >
    INSERT INTO polygons(tract, user, name, type, center, radius, north, south, east, west, verticies)
    VALUES('#url.tract#', '#url.user#', '#url.name#', '#url.type#','#url.center#', '#url.radius#', '#url.north#', '#url.south#', '#url.east#', '#url.west#', '#url.verticies#');
</cfquery>

对于此查询，并非使用所有字段。有些记录有center and radius，有些记录有north, south, east, and west，有些记录有verticies。任何未使用的字段都是null。

如何编写语句，以便类型后的每个字段都是可选的？

由于

Answer 1

如果他们未被传入，您可以使用cfparam将您的网址参数默认设为空白。然后，在您的查询中，您可以使用cfqueryparam的null属性。 null属性是布尔值，如果为true，则传递给null。

<cfparam name="URL.tract" default="" />
<cfparam name="URL.user" default="" />
<cfparam name="URL.name" default="" />
<cfparam name="URL.type" default="" />
<cfparam name="URL.center" default="" />
<cfparam name="URL.radius" default="" />
<cfparam name="URL.north" default="" />
<cfparam name="URL.south" default="" />
<cfparam name="URL.east" default="" />
<cfparam name="URL.west" default="" />
<cfparam name="URL.verticies" default="" />

<cfquery name="aoi_results" datasource="buyerhero"  >
    INSERT INTO polygons(tract, user, name, type, center, radius, north, south, east, west, verticies)
    VALUES(
        <cfqueryparam value="#URL.tract#" cfsqltype="cf_sql_integer" />
        ,<cfqueryparam value="#URL.user#" cfsqltype="cf_sql_varchar" />
        ,<cfqueryparam value="#URL.name#" cfsqltype="cf_sql_varchar" />
        ,<cfqueryparam value="#URL.type#" cfsqltype="cf_sql_integer" />
        ,<cfqueryparam value="#URL.center#" cfsqltype="cf_sql_float" null="#len(URL.center) EQ 0#" />
        ,<cfqueryparam value="#URL.radius#" cfsqltype="cf_sql_float" null="#len(URL.radius) EQ 0#" />
        ,<cfqueryparam value="#URL.north#" cfsqltype="cf_sql_float" null="#len(URL.north) EQ 0#" />
        ,<cfqueryparam value="#URL.south#" cfsqltype="cf_sql_float" null="#len(URL.south) EQ 0#" />
        ,<cfqueryparam value="#URL.east#" cfsqltype="cf_sql_float" null="#len(URL.east) EQ 0#" />
        ,<cfqueryparam value="#URL.west#" cfsqltype="cf_sql_float" null="#len(URL.west) EQ 0#" />
        ,<cfqueryparam value="#URL.verticies#" cfsqltype="cf_sql_float" null="#len(URL.verticies) EQ 0#" />
    );
</cfquery>

我猜到了cfsqltype，你必须自己验证这些。如果len（）为0，则null属性将列设置为null，并且使用cfparam将所有URL参数默认为空白

最重要的是，您应该始终使用cfqueryparam。将URL变量传递给查询只是要求使用SQL注入攻击进行攻击。 Read the query param section on learncfinaweek了解更多相关信息。

coldfusion cfinsert失败，如何提交带有可选字段的查询

1 个答案: